I am facing the following error: get/getq: first arg must be either symbol, list, defstruct or user type - 0.0

You can't use pinBoundary~>llx (I've no idea why you thought you could - strangely enough there was another post recently which did the same thing here). A bounding box is a list of two lists, each of which is a number. So none of the ~>llx, lly, urx, ury will work on these (similarly in your previous, now deleted, post where you were trying to index lists using array syntax - lists are not arrays).

I rewrote this slightly to use destructuringBind to pull out the llx, lly etc, plus to optionally use the prBoundary if present (worked better in my case). I also indented it (debugging unindented code is rather hard)

procedure(CCSfindPinsOnBorder()
  let((cv allPins count incorrectPins layoutBoundary pinBoundary)
    cv = geGetWindowCellView()
    if(cv then
      allPins = setof(x cv~>shapes x~>pin)
      count = 0
      incorrectPins = 0
      ; use prBoundary (assume rectangle here for simplicity) or use
      ; cellView bBox if not found. Note that the bBox may not be 
      ; correct if you have labels protuding outside of the shapes
      layoutBoundary = cv~>prBoundary~>bBox || cv~>bBox

      destructuringBind(((lbLLX lbLLY) (lbURX lbURY)) layoutBoundary
        foreach(pin allPins
          pinBoundary = pin~>bBox
          ; shapes always have a bBox, so no need to check
          destructuringBind(((llx lly) (urx ury)) pinBoundary
            if(not(
              (llx == lbLLX) ||
              (lly == lbLLY) ||
              (urx == lbURX) ||
              (ury == lbURY)
              ) ;not
            then
              geSelectFig(pin)
              incorrectPins++
              printf("Incorrectly placed pin with net %s found at %L\n"
              pin~>net~>name centerBox(pinBoundary))
            ) ;if
            count++
          ) ;destructuringBind
        ) ;foreach
      )

      printf("%d pin(s) checked in cell %s\n"
      count cv~>cellName)
      printf("%d incorrectly placed pin(s) highlighted\n"
      incorrectPins)
    ) ;if
  ) ;let
) ;procedure

Regards,

Andrew

Thank you, Andrew! I will correct my mistakes as I am quite new to scripting.

Thank you, Andrew! I will correct my mistakes as I am quite new to scripting.