can multiple functionality's assigned to same bindkey

Hi Raghu,

I'm guessing you want something like this:

procedure(RNgetOverlapShape(overlap)
  if(listp(overlap) then
    RNgetOverlapShape(cadr(overlap))
  else
    overlap
  )
)

procedure(RNconnectivity(@optional pt (cv geGetEditCellView()))
  let((overlaps shape layerTable layers
      ; change this list to the metals in your technology
      (metalLayers list("Metal1" "Metal2" "Metal3" "Metal4" "Metal5" "Metal6"))
      stopMetals)
    unless(pt
      pt=hiGetCommandPoint()
    )
    overlaps=dbGetOverlaps(cv list(pt pt) t 20)
    ; collect the layers that appear at the point
    ; does this by flattening the overaps and finding
    ; the layer name of the final shape, then making a 
    ; unique list
    layerTable=makeTable('layerTable nil)
    foreach(elem overlaps
      shape=RNgetOverlapShape(elem)
      when(shape~>objType!="inst" && shape~>layerName
        layerTable[shape~>layerName]=t
      )
    )
    layers=layerTable->?
    foreach(layer layers
      remainingMetal=member(layer metalLayers)
      when(cdr(remainingMetal)
        ; not convinced this is really what you want...
        stopMetals=outfile("./stoplayers" "w")
        fprintf(stopMetals "stopLayers(\n %L" list(cadr(remainingMetal) "drawing"))
        when(cddr(remainingMetal)
          fprintf(stopMetals " %L" list(caddr(remainingMetal) "drawing"))
        )
        fprintf(stopMetals " t)\n")
        close(stopMetals)
        leMarkNet(
          pt
          ?stopLevel 20
          ?optionFile "./stoplayers"
          ?thickLine t
          ?markNetColor "y1"
        )
      )
    )
  )
)

procedure(RNconnectivityEFaddPoint(wid points)
  RNconnectivity(car(last(points)))
)

procedure(RNconnectivityEF()
  enterPoints(
    ?prompts list("Click at point to mark")
    ?addPointProc "RNconnectivityEFaddPoint"
  )
)

Note that I don't think using the stop layers like this is quite what you want. This code is trying to set the stop layers two above the metal layer the shape under the cursor. You can also call it from RNconnectivityEF() which uses enterPoints to prompt you to click, and then escape will end the prompting.

Anyway, hopefully this gives you enough of a framework for you to adapt to your needs.

Regards,

Andrew.