XML in SKILL

In case anyone is interested, I just put together an XSLT stylesheet which will convert XML into a format that is easily parsable in SKILL.

You need to do: xsltproc xmlToSKILL.xsl yourXML.xml > skillFriendly.txt

Then the resulting file can be read by doing:

prt=infile("skillFriendly.txt")
data=lineread(prt)
close(prt)
data=car(data)

You'll find that the head of each list is the name of the element, and the cadr() is a DPL containing any attribute-value pairs, and the rest of each list is all the text contents or sub-elements.

And finally here's the XSLT stylesheet (xmlToSKILL.xsl). Hopefully I can get this to display OK on the forum! Note, this has mangled some of the quotation marks, so it's for viewing only. Please download the attachment.

<?xml version="1.0"?>
<!--
Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   XSLT
Date       Jul 16, 2009 
Modified   
By         

XSLT stylesheet to transform XML into a format that can easily be
parsed by SKILL.

Use: xsltproc thisStyleSheet.xsl xmlFile

and the resulting file should be easily readable with lineread in SKILL.

***************************************************

SCCS Info: @(#) xmlToSKILL.xsl 07/16/09.14:13:25 1.1

-->
<xsl:stylesheet xmlns:xsl="">www.w3.org/.../Transform" version="1.0">

<xsl:output method="text"/>

<!-- Match all top level nodes -->
<xsl:template match="*">
  <xsl:text>(</xsl:text><xsl:value-of select="name()"/><xsl:text> </xsl:text>
  <!-- output a DPL of all attributes -->
  <xsl:text>(nil </xsl:text><xsl:apply-templates select="@*"/><xsl:text>) </xsl:text>
  <!-- next any text nodes -->
  <xsl:apply-templates select="text()"/>
  <!-- and finally call recursively to find descendents -->
  <xsl:apply-templates select="*"/>
  <xsl:text>)
</xsl:text>
</xsl:template>

<!-- Match and format attributes -->
<xsl:template match="@*">
  <xsl:value-of select="name()"/>
  <xsl:text> "</xsl:text>
  <xsl:call-template name="translateDoubleQuotes">
    <xsl:with-param name="string" select="."/>
  </xsl:call-template>
  <xsl:text>" </xsl:text>
</xsl:template>

<!-- Match and format text nodes -->
<xsl:template match="text()">
  <!-- check to see if text node is non-empty -->
  <xsl:if test="string-length(normalize-space(.))">
    <xsl:text>"</xsl:text>
    <xsl:call-template name="translateDoubleQuotes">
      <xsl:with-param name="string" select="."/>
    </xsl:call-template>
    <xsl:text>" </xsl:text>
  </xsl:if>
</xsl:template>

<!-- escape any double quotes -->
<xsl:template name="translateDoubleQuotes">
  <xsl:param name="string" select="''" />
  <xsl:choose>
    <xsl:when test="contains($string, '"')">
      <xsl:value-of select="substring-before($string, '"')" />
      <xsl:text>\"</xsl:text>
      <xsl:call-template name="translateDoubleQuotes">
	<xsl:with-param name="string" select="substring-after($string, '"')" />
      </xsl:call-template><xsl:text />
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$string" />
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

</xsl:stylesheet>

Regards,

Andrew.

https://community.cadence.com/cfs-file/__key/communityserver-discussions-components-files/48/xmlToSKILL.xsl

Hi

Where can I find  "xsltproc" ? Is it a build-in function ?

Thanks,

ManChak 

Hi

Where can I find  "xsltproc" ? Is it a build-in function ?

Thanks,

ManChak 

It's a UNIX command in /usr/bin/xlstproc and it is provided by the "libxslt" RPM.

Regards,

Andrew.

Hi Andrew,

Thank you for your info. I guess IT does not install libxslt, so I cannot test it.

ls /usr/bin/xlstproc
ls: cannot access /usr/bin/xlstproc: No such file or directory

Thanks,

ManChak