leLayerSize didn't work for pcell, is there any way around it?

 Hi Kathy,

You cannot use le prefix functions in a PCell (or sch, ge etc. for that matter - check the documentation for a full list of what you can use).  However, you have at least a couple of ways to achieve this functionality: use the dbLayerSize() function, or use the ?size and ?fromObj arguments to a command such as rodCreateRect().

  dbLayerSize( 

    d_cellViewId

    t_layerName

    l_dbIdList1

    n_value

    [ x_numVertices ]

  ) 

  => l_dbIdList

 If using the rod approach and the original shape was not created as a rod object, then you can use the rodNameShape() command to make a db object into a rod object.  Again, check the documentation for more details, but I believe that the above should answer your questions.

Best regards,

Lawrence.

Thanks Lawrence!

I've tried dbLayerSize command as suggested, but I guess I didn't understand how to get m1Rect as listed example.

m3out = dbLayerSize(cv "metal3" m1Rect 0.5)

But, I tried dbCreateRect command as mentioned for another way around it.

cv=geGetEditCellView()

dbCreateRect(cv list("OD" "drawing") list(9.08:2.28 9.75:3.28))

dbCreateRect created an OD layer over a line of pmos'.

Then I used leLayerSize(cv list("OD" "drawing") 1.5 list("NW" "drawing")) command.   Yes, it created an extra large NW layer outward base on OD layer as I wanted.

Here come another question: 

How am I going to find out (which command) the lower and upper coord of OD layer in a pcell?

I've zoomed in and find out the far left lower corner coord of OD and far right upper corner coord of the OD in order to make dbCreateRect command work for me.

Thanks,

Kathy

Hi Kathy,

If you want to size shapes within the pcell instance, then neither dbLayerSize nor leLayerSize are going to help. They both only work on "level 0" shapes - i.e. shapes in the cellView you're editing, rather than shapes one level down (inside the pcell). 

If using IC613/4 and with access to VLS GXL, you could rteGeomSize() to do this, but otherwise you'd need to do something like:

; assume that cv is the cellView you're editing, and inst is the id of the pcell instance
master=inst~>master
; find the LPP object within the pcell instance
OD=car(exists(lpp master~>lpps lpp~>layerName=="OD" && lpp~>purpose=="drawing"))
ODshapes=foreach(mapcar shape OD~>shapes
  dbCopyFig(shape cv inst~>transform)
)
dbLayerSize(cv "NW" ODshapes 1.5)
; remove the temporary copy of OD shapes into the cellView
foreach(shape ODshapes dbDeleteObject(shape))

Note this is completely untested and off the top of my head. So there may be errors in the code. Caveat Emptor.

Andrew.

Thanks Andrew!

 Please correct me if I'm wrong here.   I've test it out, but all I got are (db:xxxxx), no NW layer has been add.

Here is what I have:

cv=geGetEditCellView()

inst=cv->instances

OD=car(exists(lpp cv->lpps lpp->layerName=="OD" && lpp->purpose=="drawing"))

ODshapes=foreach(mapcar shape OD->shapes dbCopyFig(shape cv inst->transform))

dbLayerSize(cv "NW" ODshapes 1.5)

foreach(shape ODshapes dbDeleteObject(shape))

In this particular cellview, I've two pmos pcell instant in there.

best regards,

Kathy

Kathy,

I think it would be wise to go on a SKILL course - you've managed to significantly change my suggestion so that it wouldn't work...

Various things you've done wrong:

1. inst in your case is a list of instances, rather than a single instance in my case
2. You are looking for the OD layer purpose pair object in the top level cellView, rather than in the master for the pcell instance
3. It probably therefore doesn't find any OD shapes.
4. And hence no NW gets created
5. Not sure why you changed it the way you did. It suggests you really don't understand what an instance is.

If you want to process all the instances, you could do:

cv=geGetEditCellView()
foreach(inst cv~>instances
  master=inst~>master
  ; find the LPP object within the pcell instance
  OD=car(exists(lpp master~>lpps lpp~>layerName=="OD" && lpp~>purpose=="drawing"))
  ODshapes=foreach(mapcar shape OD~>shapes
    dbCopyFig(shape cv inst~>transform)
  )
  dbLayerSize(cv "NW" ODshapes 1.5)
  ; remove the temporary copy of OD shapes into the cellView
  foreach(shape ODshapes dbDeleteObject(shape))
) ; foreach inst

Regards,

Andrew.

Again, thank you very much Andrew.

It works perfectly this time.

I didn't intent to change the script; it's just at first time when I tried master=inst->master and it came back nil.   I was just trying to figure out how to get the master to work out.

 Anyway, it works for me.

best regards,

Kathy