Is there a way to change cellViewType?

Hi How,

It's the viewSubType property that controls this. You don't actually want to change the cellViewType (and in fact you can't) - that's the major part of the viewType. Here's some old code I wrote (13 years ago!) to do this (it's this long because it has a form as well):

/* abResetViewType.il

Author     A.D.Beckett
Group      Structured Custom, Cadence Design Systems Ltd.
Machine    SUN
Date       Jan 14, 1997 
Modified   
By         

Main entry points are abResetViewType or abHiResetViewType

These allow easy removal of the viewSubType cellView property
which controls which application is used (e.g. cell3 or virtuoso).

This code is for 4.4 and onwards

***************************************************

SCCS Info: @(#) abResetViewType.il 11/20/08.15:26:19 1.2

*/

/***************************************************************
*                                                              *
*         (abResetViewType libName cellName viewName)          *
*                                                              *
*  Reset the viewType by removing the viewSubType property on  *
*                         a cellView.                          *
*                                                              *
***************************************************************/

(procedure (abResetViewType libName cellName viewName)
  (let (cv)
       (setq cv (dbOpenCellViewByType libName cellName viewName "" "a"))
       (when cv
	     (dbDeletePropByName cv "viewSubType")
	     (dbSave cv)
	     (dbClose cv)
	     )))

/***************************************************************
*                                                              *
*                 (abCreateResetViewTypeForm)                  *
*                                                              *
*    Create the form for the HI version of abResetViewType     *
*                                                              *
***************************************************************/

(procedure (abCreateResetViewTypeForm)
  (let (libName cellName viewName browse)
       (setq libName 
	     (hiCreateStringField 
	      ?name 'libName 
	      ?prompt "Library Name"
	      ?callback "ddsUpdateSyncWithForm()"))
       (setq cellName 
	     (hiCreateStringField
	      ?name 'cellName
	      ?prompt "Cell Name"
	      ?callback "ddsUpdateSyncWithForm()"))
       (setq viewName 
	     (hiCreateStringField
	      ?name 'viewName 
	      ?prompt "View Name"
	      ?callback "ddsUpdateSyncWithForm()"))
       /* create browser button */
       (setq browse 
	     (hiCreateButton 
	      ?name 'browse 
	      ?buttonText "Browse" 
	      ?callback "abResetViewTypeSyncWithForm()"))
       /* build the form */
       (setq abResetViewTypeForm 
	     (hiCreateAppForm 
	      ?name 'abResetViewTypeForm 
	      ?fields (list
		       (list libName 0:0 400:35 105)
		       (list cellName 0:35 400:35 105)
		       (list viewName 0:70 400:35 105)
		       (list browse 105:105 90:30)
		       )
	      ?formTitle "Reset View Type"
	      /* cancel callback is to break the link with the browser */
	      ?callback '(abResetViewTypeCB "ddsEndSyncWithForm()")))
       ))

/***************************************************************
*                                                              *
*                (abResetViewTypeSyncWithForm)                 *
*                                                              *
*            Sync the form with the library browser            *
*                                                              *
***************************************************************/

(procedure (abResetViewTypeSyncWithForm)
  (ddsSyncWithForm abResetViewTypeForm
		   'browse
		   'libName 'cellName 'viewName))

/***************************************************************
*                                                              *
*                   (abResetViewTypeCB form)                   *
*                                                              *
*      OK callback for the form. This resets the viewType      *
*                  on the specified cellView.                  *
*                                                              *
***************************************************************/

(procedure (abResetViewTypeCB form)
  /* break the link to the browser */
  (ddsEndSyncWithForm)
  (abResetViewType 
   (getq (getq form libName) value)
   (getq (getq form cellName) value)
   (getq (getq form viewName) value)
   ))

/***************************************************************
*                                                              *
*                     (abHiResetViewType)                      *
*                                                              *
*            Main entry point - brings up the form             *
*                                                              *
***************************************************************/

(procedure (abHiResetViewType)
  (unless (boundp 'abResetViewTypeForm)
	  (abCreateResetViewTypeForm))
  (hiDisplayForm abResetViewTypeForm))

 Regards,

Andrew.

Hi Andrew,

Thanks. This is what i'm looking for and its works. Didn't know that its so simple by just deleting the property. I had struggle for a day in finding out a way to convert it.

Anyway, thanks a lot man. :)

--How