getAsciiWave

Zfeng,

You should be able to adapt this code to meet your requirements:

Note: a newer version (June 2020) has been added in this post which allows the maximum number of rows to be read to be specified.

/* abTable.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Jan 11, 1999 
Modified   
By         

Read a waveform from a file of numbers, and return
it as a waveform object

e.g.

myWave=abTable("data.asc")
myWave2=abTable("withheader.asc" ?skip 1 ?xCol 2 ?yCol 3)

***************************************************

SCCS Info: @(#) abTable.il 01/11/99.13:03:34 1.1

*/

/**********************************************************************
*                                                                     *
*         (abTable fileName @key (xCol 1) (yCol 2) (skip 0))          *
*                                                                     *
*      Reads a tabulated file of numbers from file specified in       *
*    fileName, and the remain arguments are keyword. xCol and yCol    *
*    are the column numbers of the x and y axis (starting from 1).    *
* skip is the number of lines to skip at the beginning (for headers). *
*                   A waveform object is returned.                    *
*                                                                     *
**********************************************************************/

(procedure (abTable fileName @key (xCol 1) (yCol 2) (skip 0))
  (let (prt line wave xVec yVec xVal yVal)
       (unless
	(setq prt (infile fileName))
	(error "Could not read waveform from file %s\n" fileName)
	)
       /* skip header lines */
       (for count 1 skip
	    (gets line prt))
       /* create the empty vectors */
       (setq xVec (drCreateVec 'double 1))
       (setq yVec (drCreateVec 'double 1))
       /* these want to be zero indexed */
       (postdecrement xCol)
       (postdecrement yCol)
       (while (setq line (lineread prt))
	      /* ignore blank lines */
	      (unless (equal line t)
		      (setq xVal (nth xCol line))
		      (setq yVal (nth yCol line))
		      (unless (and (numberp xVal) (numberp yVal))
			      (error "Invalid data %L\n" line)
			      )
		      (drAddElem xVec xVal)
		      (drAddElem yVec yVal)
		      )
	      )
       /* create the waveform object and return it */
       (setq wave (drCreateEmptyWaveform))
       (drPutWaveformXVec wave xVec)
       (drPutWaveformYVec wave yVec)
       wave
       ))

Regards,

Andrew.

 Hi Andrew,

     i will try it as soon as possible, thanks very much!

Regards,

zfeng

 Hi,

   i changed it a little, it works very well , thanks

Best regards,

zfeng