Print output to cursor in the layout window?

 IMHO it is possible only if u will use ROD objects and stratch hadles.

In IC61 (e.g. IC614, IC615) you can do Options->Dynamic Display and turn on "info balloons" (there's a toolbar icon for this) which will show the width as you hover over a path or pathSeg. It's also possible to show other info, and even write your own SKILL function to show additional information. Hit the Help button on the Dynamic Display options form and there are links to doing the SKILL customization.

So this is possible already with the standard tools.

Regards,

Andrew.

Thanks Andrew & Slayer, I forgot to mention im on Cadence 5.10.41. Is it possible with this version also?

Not really. There is Options->Display and turn on "Shape Information", but there's only limited information shown here. Similarly the Dynamic Measurement doesn't show this.

I've an idea as to how to write a bit of SKILL code that might do something like this. Let me play, and I'll come back...

Andrew.

OK, here's some code. It's not polished, not fully tested, but might give you a starting point...

/* abDynamicDisplay.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Apr 28, 2011 
Modified   
By         

Example of dynamic display in IC5141. Uses leRegUserObjectSelectionFilter
to track what the user is over - and then builds a message to display.
The highlight label is displayed at the cursor location.

Call abDynamicDisplay(t) to enable (pass nil to disable).

; can set these properties to alter how the highlight labels are drawn
abDynamicDisplay.lpp='("y0" "drawing")
abDynamicDisplay.height=0.2
abDynamicDisplay.font="stick"
abDynamicDisplay.orient="R0"
abDynamicDisplay.justify="lowerLeft"

The code is not polished, not thoroughly tested. It just illustrates
the idea.

In IC61 this is completely obsoleted by the Info Balloon capability.

IC5141 also has "Shape Information" which gives some of this kind of 
display, but what is displayed is hardcoded.

***************************************************

SCCS Info: @(#) abDynamicDisplay.il 04/28/11.13:36:35 1.1

*/

/***************************************************************
*                                                              *
*              abDynamicDisplaySelectFilter(fig)               *
*                                                              *
*          Filter function to do the dynamic display.          *
*                                                              *
***************************************************************/

procedure(abDynamicDisplaySelectFilter(fig)
let((win hs message point)
    win=geGetEditCellViewWindow(fig~>cellView)
    ;--------------------------------------------------------------------
    ; If the object is the same as last time, don't re-generate
    ;--------------------------------------------------------------------
    unless(fig==abDynamicDisplay.lastObject
	hs=win~>abDynDisplayHS
	when(geIsValidHilightSet(hs) geDeleteHilightSet(hs))
	;----------------------------------------------------------------
	; Customize this bit to reflect what is shown for each object
	;----------------------------------------------------------------
	case(fig~>objType
	    ("path"
		sprintf(message "Layer: %s Width: %g" fig~>layerName fig~>width)
		)
	)
	when(message
	    abDynamicDisplay.lastObject=fig
	    point=hiGetPoint(win)
	    when(point
		hs=geCreateHilightSet(fig~>cellView 
		    abDynamicDisplay.lpp || '("y0" "drawing"))
		win~>abDynDisplayHS=hs
		geAddHilightLabel(
		    hs
		    geWindowToEditPoint(win point)
		    message
		    abDynamicDisplay.justify || "lowerLeft"
		    abDynamicDisplay.orient || "R0"
		    abDynamicDisplay.font || "stick"
		    abDynamicDisplay.height || 0.2
		    nil
		)
		hs->enable=t
		geRefresh()
	    )
	)
    )
    ;--------------------------------------------------------------------
    ; Always return t because don't want to do any actual filtering
    ;--------------------------------------------------------------------
    t
))

/***************************************************************
*                                                              *
*                   abDynamicDisplay(enable)                   *
*                                                              *
*            Enable or display the dynamic display             *
*                                                              *
***************************************************************/

procedure(abDynamicDisplay(enable)
    if(enable then
	leRegUserObjectSelectionFilter("abDynamicDisplaySelectFilter")
    else
	leUnregUserObjectSelectionFilter()
    )
)

Andrew many thanks! That does the job perfectly.

Another application type I was hoping to use it for was while creating a contact cell with leHiCreateContact(). Can the code be set up to output the name of the selected contact type next to the mouse cursor and contact shape outline during user entry? Appologies if a straight forward solution, still only learning the basics here. Thanks again!

Not during creation (not sure quite why you'd do that), but when you hover over it after creation you could get it to display the contact name by changing the case statement to:

	case(fig~>objType
	    ("path"
		sprintf(message "Layer: %s Width: %g" fig~>layerName fig~>width)
		)
	    ("inst"
		sprintf(message "%s: %s" if(leIsContact(fig) "Cont" "Inst") fig~>cellName)
		)
	)

Note, I did not test this...

Andrew.

Ah I see. What I was hoping to do was call leHiCreateContact() and automatically enter the information into the form, and then hide the form, but have the contact info displayed next to the cursor, as I thought this a more fluent approach if it was possible. The code I attempted is below. Note for some reason on first call of leHiCreateContact() it doesnt enter the contact information (colums:2 type:met2_met1_b) or hide the form, it requires the bindkey to be executed again.
But this is ok, I can work with this. Thanks again for your help.

procedure(BSaddcontact1()
        if( hiGetCurrentCmd(hiGetCurrentWindow()) == "Contact"
                then    when( hiIsFormDisplayed(le0ContactForm) == t
                              hiiToggleEnterForm(le0ContactForm)
                            )
                        le0ContactForm->contactType->value = "met2_met1_b"
                        le0ContactForm->columns->value=2
                        ?prompts        `("met2_met1_b")
                else    leHiCreateContact()
                         wait( hiIsFormDisplayed(le0ContactForm)==t)
                        hiiToggleEnterForm(le0ContactForm) == t
                        le0ContactForm->contactType->value = "met2_met1_b"
                        le0ContactForm->columns->value=2
                        ?prompts        `("met2_met1_b")
        )
)

hiSetBindKey("Layout" "Shift<key>1" "BSaddcontact1()")

procedure(BSaddcontact2()
        if( hiGetCurrentCmd(hiGetCurrentWindow()) == "Contact"
                then    when( hiIsFormDisplayed(le0ContactForm) == t
                              hiiToggleEnterForm(le0ContactForm)
                            )
                        le0ContactForm->contactType->value = "met3_met2_b"
                        le0ContactForm->columns->value=2
                        ?prompts        `("met3_met2_b")
                else    leHiCreateContact()
                        wait( hiIsFormDisplayed(le0ContactForm)==t)
                        hiiToggleEnterForm(le0ContactForm) == t
                        le0ContactForm->contactType->value = "met3_met2_b"
                        le0ContactForm->columns->value=2
                        ?prompts        `("met3_met2_b")
        )
)

hiSetBindKey("Layout" "Shift<key>2" "BSaddcontact2()")

One way to do this is to use the hiRegTimer command. When you invoke the form, the skill code waits for the form to close before it proceeds to the following commands where you are populating the form. The hiRegTimer command allows you to call some skill code some amount of time in the future which allows the form to come up first and then the skill to be executed.

hiRegTimer("le0contactForm->contactType->value = \"met2_met1_b\"" 1) ;Run 1/10th of a second from now
leHiCreateContact()

Derek