Objects selected in schematic, but car(selectedSet()) returns Nil

selectedSet() works on the active window. Does hiGetCurrentWindow return the window id of the window containing the selection? It is possible that your Window manager (KDE/gnome) makes windows active as the cursor moves across the screen and it may be that the Cadence window containing the selection is no longer the active window.

Derek

 I'm pretty sure it's not a problem with active window.  When I select any other type of object, car(selectedSet()) works -- but when the instance pins are selected, the result is nil.  Also, I don't have any other windows open. 

 Hi Jason,

The instance terminal (pin) is a representation of the instance masters' pin, and so I think this is why it gives 'nil' when queried.  I think that we are allowed to select these for convenience.  However, it sounds like you want to create pins from the selected instance (although you said selected pins, so it might not be all pins of that symbol?) and as luck would have it, I just wrote exactly this SKILL code the other day, here it is:

procedure(CCSpromotePins(inst "d")
  let( (transform pinpoint pininfo pinmaster)
    ;; if the passed in object is not an instance provide a warning
    ;; otherwise use the instance object to gather information for
    ;; creating pins in the current cellview
    if(inst~>objType=="inst" then
      ;; store the instances' transform
      transform = inst~>transform
      ;; iterate over the pins in the master of this instance
      foreach(term inst~>master~>terminals
	;; foreach pin of this terminal (typically only one)
	;; find the pin figure location and translate that into
	;; the coordinates of the cellview where this instance is
	foreach(pin term~>pins
	  pinpoint = geTransformUserPoint(centerBox(pin~>fig~>bBox)
		      transform)
	  ;; when a pin master can be found for this terminal direction
	  when(pininfo = caddr(assoc(term~>direction schPinMasters))
	    ;; use the pin information to open the pin master
	    ;; and use that to create a pin in this cellview
	    ;; using the same name, direction and location
	    when(pinmaster = apply('dbOpenCellViewByType pininfo)
	      schCreatePin(inst~>cellView pinmaster term~>name 
		term~>direction nil pinpoint "R0")
	    ); when the pin master can be opened
	  ); when the pin direction matches one of the schPinMasters
	); foreach pin
      ); foreach terminal
    else
      warn("CCSpromotePins: object should be an instance")
    ); if
  ); let
); procedure CCSpromotePins


procedure(CCShiPromotePins()
  let( ((selSet geGetSelectedSet()))
    ;; when there is somthing selected, invoke the CCSpromotePins
    ;; function on the first (perhaps the only?) object selected
    when(selSet
      forall(obj CCSpromotePins(car(selSet)) obj)
    ); when
  ); let
); procedure CCShiPromotePins

Basically we go to the instance's master (the symbol master) and find the figures associated with the pins associated with the terminals (the figures are the selectable objects, the pins and terminals are logical), we transform the center point of the figure into the top level coordinate system and then the code creates a schematic pin for each of the symbol pins, using the center of the instance pin as the location for the created pin origin.

Please give this a try and let me know if it helps you.

Regards,

Lawrence.

Thanks a lot for the suggestion -- i'll try that out and let you know how it goes.

 --Jason

 Lawrence -- that ended up being very useful.  I needed to make a few changes, because for some reason term~>pins was returning nil, but I was able to make good use of geTransformUserPoint function, which I did not know about, and really was key in getting everything to work.  So, thanks again!

--Jason

Jason,

Glad to hear it!  There is a geTransformUserBBox() function too, but in this case I just wanted a point, so rather than transforming the box and then finding the centre, I found the centre and transformed the point, but it's probably 6 of one and sqrt(36) of the other.

Best regards,

Lawrence.

Hi, i face the same problem with you. I have the script to create all pins and nets from the the selected instance. But sometimes I still have the need to create net or pin from the selected pins belonging to an instance. I go through the "skdfref" documents,  and I find the function geGetObjectSelectedSet() meets our requirements well.  I think "edit properties" form use this function too.

I believe those "dots" around an instance in a schematic are actually markers - markers that are child objects of the instance...inst~>children returns them. However clicking on them hilights but doesn't select them...I don't know whether there's any way to do that in a schematic editor - I'am not a schematic editor specialist though. You could select them in SKILL of course:

(geSelectFigs (setof child inst~>children child~>objType=="marker"))

I have used the setof function because I'am not sure whether an instance may have any other kind of (non marker) child objects

The pin related information can be found in the marker's msg attribute.