How to create dockable form in skill

Rushang,

Try this modification of your code:

 procedure( popupform()
    let( (fileLocation loadFileButton )
        fileLocation = hiCreateFileSelectorField(
                ?name           'fileLocation
                ?mode           'existingFile
                ?prompt         "Choose a file"
                ?editable       t)

        loadFileButton = hiCreateButton(
                ?name           'loadFileButton
                ?buttonText     "Load File"
                ?callback       "printf(\"Loading file from popup form %s\n\" myForm->fileLocation->value)")

        myForm = hiCreateAppForm(
                ?name           'myForm
                ?formTitle      "My Form which should be popup"
                ?buttonLayout   'Close
        ?dontBlock t    ; with this your previous code would have failed
                ?fields         list( list(fileLocation 10:10 400:20 100)
                                        list(loadFileButton 415:10 80:30))
                ?unmapAfterCB           t)

        hiDisplayForm(myForm)
    ); let
)

procedure( dockform()
    let( (fileLocation loadFileButton swin dockForm myDock)
        fileLocation = hiCreateFileSelectorField(
                ?name           'fileLocation
                ?mode           'existingFile
                ?prompt         "Choose a file"
                ?editable       t)

        loadFileButton = hiCreateButton(
                ?name           'loadFileButton
                ?buttonText     "Load File"
                ?callback       "printf(\"Loading file from docked form %s\n\" myForm2->fileLocation->value)")
        ; or this
                ;?callback       "printf(\"Loading file from docked form %s\n\" hiGetCurrentForm()->fileLocation->value)")

        swin = hiGetSessionWindow(hiGetCurrentWindow())
        myForm2 = hiCreateAppForm(
                ?name           'myForm2
                ?formTitle      "My Form which should be docked"
                ?buttonLayout   'Close
                ?fields         list( list(fileLocation 10:10 400:20 100)
                                        list(loadFileButton 415:10 80:30))
                ?unmapAfterCB           t)
        dockForm = hiCreateDockWindow(
                ?appType        "Docked Form"
                ?widgetType     "form"
                ?handle         'dockedForm
                ?title          "Docked Form"
                ?form           myForm2)
        myDock = hiDockWindow(
                ?window         dockForm
                ?session        swin
                ?side           'right)
    ); let
)

The key parts are that I've taken out myForm and myForm2 from the let() in each function, and changed the callback to either do:

myForm->fileLocation->value

or 

hiGetCurrentForm()->fileLocation->value

Either would be OK.

In general top level user interface elements (e.g. forms, menus) must be in global variables. This is because the interactions with them must be accessible out of scope - particularly if they are non-blocking. There is no need for the form fields, or the dock window to be global.

In your original popupform() function, it worked because the form was defined as being blocking - so the call to hiDisplayForm() meant that it was still within the scope of the popupform function. If you'd made the form non-blocking (as I've done in the modification above), or if the call to hiDisplayForm() had been outside of the function that created it, it also would not have worked. By ensuring the myForm and myForm2 are global - they are accessible everywhere. They also have to be global so that the CDS.log can record the updates to the form - so they are replayable.

In the case of the dockform, it's always non-blocking - so you have to do this anyway.

Provided you start from the global handle (or use hiGetCurrentForm()), you can retrieve the fields of anything on the form.

Hope that helps!

Regards,

Andrew.

Rushang,

Try this modification of your code:

 procedure( popupform()
    let( (fileLocation loadFileButton )
        fileLocation = hiCreateFileSelectorField(
                ?name           'fileLocation
                ?mode           'existingFile
                ?prompt         "Choose a file"
                ?editable       t)

        loadFileButton = hiCreateButton(
                ?name           'loadFileButton
                ?buttonText     "Load File"
                ?callback       "printf(\"Loading file from popup form %s\n\" myForm->fileLocation->value)")

        myForm = hiCreateAppForm(
                ?name           'myForm
                ?formTitle      "My Form which should be popup"
                ?buttonLayout   'Close
        ?dontBlock t    ; with this your previous code would have failed
                ?fields         list( list(fileLocation 10:10 400:20 100)
                                        list(loadFileButton 415:10 80:30))
                ?unmapAfterCB           t)

        hiDisplayForm(myForm)
    ); let
)

procedure( dockform()
    let( (fileLocation loadFileButton swin dockForm myDock)
        fileLocation = hiCreateFileSelectorField(
                ?name           'fileLocation
                ?mode           'existingFile
                ?prompt         "Choose a file"
                ?editable       t)

        loadFileButton = hiCreateButton(
                ?name           'loadFileButton
                ?buttonText     "Load File"
                ?callback       "printf(\"Loading file from docked form %s\n\" myForm2->fileLocation->value)")
        ; or this
                ;?callback       "printf(\"Loading file from docked form %s\n\" hiGetCurrentForm()->fileLocation->value)")

        swin = hiGetSessionWindow(hiGetCurrentWindow())
        myForm2 = hiCreateAppForm(
                ?name           'myForm2
                ?formTitle      "My Form which should be docked"
                ?buttonLayout   'Close
                ?fields         list( list(fileLocation 10:10 400:20 100)
                                        list(loadFileButton 415:10 80:30))
                ?unmapAfterCB           t)
        dockForm = hiCreateDockWindow(
                ?appType        "Docked Form"
                ?widgetType     "form"
                ?handle         'dockedForm
                ?title          "Docked Form"
                ?form           myForm2)
        myDock = hiDockWindow(
                ?window         dockForm
                ?session        swin
                ?side           'right)
    ); let
)

The key parts are that I've taken out myForm and myForm2 from the let() in each function, and changed the callback to either do:

myForm->fileLocation->value

or 

hiGetCurrentForm()->fileLocation->value

Either would be OK.

In general top level user interface elements (e.g. forms, menus) must be in global variables. This is because the interactions with them must be accessible out of scope - particularly if they are non-blocking. There is no need for the form fields, or the dock window to be global.

In your original popupform() function, it worked because the form was defined as being blocking - so the call to hiDisplayForm() meant that it was still within the scope of the popupform function. If you'd made the form non-blocking (as I've done in the modification above), or if the call to hiDisplayForm() had been outside of the function that created it, it also would not have worked. By ensuring the myForm and myForm2 are global - they are accessible everywhere. They also have to be global so that the CDS.log can record the updates to the form - so they are replayable.

In the case of the dockform, it's always non-blocking - so you have to do this anyway.

Provided you start from the global handle (or use hiGetCurrentForm()), you can retrieve the fields of anything on the form.

Hope that helps!

Regards,

Andrew.