Help on skill code for stretching of rectangle on 3 sides for many cells

Something like this should work.

procedure(loopCells(libName @optional (viewList list("layout")))
  let((libId cvId)
    libId = ddGetObj(libName)
    foreach(cell libId~>cells
        foreach(viewName cell~>views~>name
            when(member(viewName viewList)
                when(cvId = dbOpenCellViewByType(libId cell~>name viewName nil "a")
                    stretchDNW(cvId)
                )
            )
        )
    )
    t
  ) ;let
) ;proc

procedure(stretchDNW(@optional (cv geGetEditCellView()))
  let((lpp grow shapes bBox pt1 pt2)
    lpp = list("DNW" "drawing")
    grow = 2.0
    printf("Working on: %s %s\n" cv~>cellName cv~>viewName)
    shapes = setof(x cv~>shapes x~>lpp==lpp)
    foreach(shape shapes
        when(shape~>objType=="rect"
            bBox = shape~>bBox
            pt1 = list(leftEdge(bBox)-grow bottomEdge(bBox)-grow)
            pt2 = list(rightEdge(bBox)+grow topEdge(bBox))
            shape~>bBox = list(pt1 pt2)
        )
    )
    when(cv~>modifiedButNotSaved
        dbSave(cv)
        dbPurge(cv)
    )
  ) ;let
) ;proc

Set the layer name and the value to grow by in the second procedure. Call the first procedure by passing it your library name:
loopCells("mystdcells")

If you need to handle more than layout views you could do this:
loopCells("mystdcells" list("layout" "abstract"))

Derek