Regarding Close & Purge Data using Skill

Fazul,

dbGetOpenCellViews() and dbGetOpenBags() - also techGetOpenTechFiles() for completeness. Here's a rather elderly example:

/* abPurgeLib.il

Author     A.D.Beckett
Group      Structured Custom, Cadence Design Systems Ltd.
Machine    SUN
Date       May 16, 1996 
Modified   
By         

A method of implementing the equivalent of dmPurgeLib in 4.4

Two entry points:

abPurgeLib(libName)
abHiPurgeLib()

***************************************************

SCCS Info: @(#) abPurgeLib.il 11/20/08.15:26:19 1.3

*/

/***************************************************************
*                                                              *
*                     (abPurgeLib libName)                     *
*                                                              *
*            Purge everything to do with a library             *
*                                                              *
***************************************************************/

(procedure (abPurgeLib libName)
  /* close all the cellViews from this library name */
  (foreach cellView (dbGetOpenCellViews)
	   (when (equal (dbGetq cellView libName) libName)
		 (dbPurge cellView)))
  /* close any (?) tech files associated with the library */
  (foreach techFile (techGetOpenTechFiles)
	   (when (equal (dbGetq techFile libName) libName)
		 (techPurgeTechFile techFile)))
  /* close any property bags associated with the library */
  (foreach bag (dbGetOpenBags)
	   (when (equal (dbGetq (dbGetq (dbGetq bag ownerObj) lib) name)
			libName)
		 (dbPurgeBag bag)))
  t)

/***************************************************************
*                                                              *
*                (abCreatePurgeLibForm choices)                *
*                                                              *
*                       Create the form                        *
*                                                              *
***************************************************************/

(procedure (abCreatePurgeLibForm choices)
  (let (libName)
       (setq libName (hiCreateCyclicField
		      ?name 'libName
		      ?choices choices
		      ?prompt "Library Name"
		      ?value (car choices)
		      ))
       (setq abPurgeLibForm 
	     (hiCreateAppForm
	      ?formTitle "Purge Library"
	      ?name 'abPurgeLibForm
	      ?fields (list (list libName 0:0 350:35 105))
	      ?callback 'abPurgeLibCB
	      ))
       ))

/***************************************************************
*                                                              *
*                        (abHiPurgeLib)                        *
*                                                              *
*        Human interface version of the library purger         *
*                                                              *
***************************************************************/

(procedure (abHiPurgeLib)
  (let (choices)
       (setq choices (dbGetq (ddGetLibList) name))
  (unless (boundp 'abPurgeLibForm) (abCreatePurgeLibForm choices))
  (putpropq (getq abPurgeLibForm libName) choices choices)
  (hiDisplayForm abPurgeLibForm)
  t))

/***************************************************************
*                                                              *
*                     (abPurgeLibCB form)                      *
*                                                              *
*            Interface from the form to abPurgeLib             *
*                                                              *
***************************************************************/

(procedure (abPurgeLibCB form)
  (abPurgeLib (getq (getq abPurgeLibForm libName) value))) 

Andrew.

Thanks Adrew for your quick response always.

This should be enough :)  

Regards,

Fazul