Adding menu entries to ADE L window

Chris,

That never was the ADE window. That's the viewType of the schematic corresponding to the ADE window - i.e. the window you launched ADE from. That should still work - in fact I just tried it using this (very old) code:

/* abAddArtMenus.il

Author     A.D.Beckett
Group      Structured Custom, Cadence Design Systems Ltd.
Machine    SUN
Date       Dec 09, 1996 
Modified   
By         

Method to add menus to artist simulation environment
in 4.4

***************************************************

SCCS Info: @(#) abAddArtMenus.il 11/20/08.15:26:09 1.1

*/


/***************************************************************
*                                                              *
*                  (abAddArtMenusCreateMenu)                   *
*                                                              *
*       Create a dummy menu, just to show the principle        *
*                                                              *
***************************************************************/

(procedure (abAddArtMenusCreateMenu)
  (let (item1 item2)
       (setq item1 
             (hiCreateMenuItem
              ?name 'item1
              ?itemText "Item 1"
              ?callback "printf(\"Item1\n\")"))
       (setq item2 
             (hiCreateMenuItem
              ?name 'item2
              ?itemText "Item 2"
              ?callback "printf(\"Item2\n\")"))
       (hiCreatePulldownMenu
        'abArtMenu
        "Test"
        (list item1 item2)
        )))

/***********************************************************************
*                                                                      *
*                     (abAddArtMenusTrigger args)                      *
*                                                                      *
*  Define a post-install trigger function for analogArtist-schematic   *
* to install user defined menus in the artist simulation encapsulation *
*                               window.                                *
*                                                                      *
***********************************************************************/

(procedure (abAddArtMenusTrigger args)
  (let (session sevWindow)
       /* get hold of the session - note sevSession is undocumented */
       (setq session (sevSession (getq args window)))
       /* and then the simulation window associated with the session */
       (setq sevWindow (getq session window))
       /* when there is a window associated, and the action is to install */
       (when (and sevWindow (equal (getq args action) 'install))
             /* create menu if it doesn't exist */
             (unless (boundp 'abArtMenu) (abAddArtMenusCreateMenu))
             /* unless the menu is already there */
             (unless (member 'abArtMenu
                             (hiGetBannerMenus sevWindow))
                     /* insert it in right most place */
                     (hiInsertBannerMenu sevWindow abArtMenu
                                         (length (hiGetBannerMenus sevWindow)))
                     )
             )
       ))


/* 
Need to install as a post install function

deRegUserTriggers("analogArtist-schematic" nil nil 'abAddArtMenusTrigger)

*/

;------------------------------------------------------------------------
; Load the standard menus file
;------------------------------------------------------------------------
load(prependInstallPath("etc/tools/menus/spectre.menus"))

;------------------------------------------------------------------------
; Identical to the IC614/IC615 menus files, but with "Custom" added.
; Note that the & in the names indicates the following char is the 
; accelerator key
;------------------------------------------------------------------------
(sevSetMainWindowPulldownMenus
  (let (menu)
   menu = `(
                "S&ession"
                "Set&up"
                "&Analyses"
                "&Variables"
                "&Outputs"
                "&Simulation"
                "&Results"
                "&Tools"
                "&Custom"
                "&Help"
    )
    when( envGetVal("adexl.launchFromTest" "showMenu")
        menu = cons("&Launch" menu)
    )
    menu
  )
)

;------------------------------------------------------------------------
; Add to the existing menus, rather than "setting". Better than making this
; a copy of the built-in default menus and then hacking - much more likely
; to stay in sync this way.
;------------------------------------------------------------------------
(sevAddMenuItemLists
  (lambda
   (session name)
   (case
    name
    ;--------------------------------------------------------------------
    ; Define Custom menu
    ;--------------------------------------------------------------------
    ("&Custom"
     `(
       ("item&A" ?callback (fnA ',session))
       ("item&B" ?callback (fnB ',session))
       ("item&C" ?subMenu t)
      ))
    ("item&C"
     `(
       ("itemC&1" ?callback (fnC1 ',session))
       ("itemC&2" ?callback (fnC2 ',session))
      ))
    )
   )
  )

Hopefully that gives you a clue as to alternative ways. This second approach also works when ADE is launched directly from the CIW, or by double-clicking a state cellView (which the other deRegUserTriggers way did not, even in IC5141, because it's really a schematic sub-app trigger).

Regards,

Andrew.

I knew about the menu files. However, I wasn't really sure about which of the two is the cleaner way. Will go for the menu file now.

 Thanks for the swift reply. Chris.

I'm feeling a bit uneasy about the menu file solution. What happens if there are other parties manipulating the menu file, especially when distribution the solution to a customer. I'm afraid this may clash somehow. Especially since the menu is not just added to the end, but the whole list of menu entries is specified literally. Isn't there another non-interfering solution?

 Chris

Chris, 

You potentially could use the

asimenv.startup sessInitTrigFunc  string  ""

.cdsenv setting, but again, that can only be a single function.

There's a long-standing request for a trigger-based mechanism to do this - it can be done right now, but uses private functions (although that approach won't work with ADE XL).

Best to contact customer support over this to come up with a more extensible way of doing this.

Andrew.