Finding the area of a rectilinear layout block

Hi Sri,

Google the topic "Area of Polygon" or "shoelace formula", it will point you to the right direction.

In theory, Any shape in a cartesian plane, given the coordinates of all vertices, The area can be calculated.

regards, lrlsk

This function can be used to find the area of a polygon or rectangle. Not sure if that's exactly what is wanted here though:

/***************************************************************
*                                                              *
*                       (abArea object)                        *
*                                                              *
*               Calculate the area of an object.               *
*      Currently only works with polygons and rectangles.      *
*                                                              *
***************************************************************/

(procedure (abArea object)
  (let (sum crd lastPt firstPt crdList area corners ll ur dx dy objType)
        (setq objType (dbGetq object objType))
        (if (equal objType "polygon") 
            (progn
             (setq crdList (dbGetq object points))
             (setq sum 0)
             (setq firstPt (setq lastPt (car crdList)))
             (setq crdList (cdr crdList))
             (foreach crd crdList
                      (setq dx (difference (xCoord crd) (xCoord lastPt)))
                      (setq sum (plus sum (times dx (plus (yCoord crd) (yCoord lastPt)))))
                      (setq lastPt crd))
             (setq sum (plus sum
                             (times (difference (xCoord firstPt) (xCoord lastPt))
                                    (plus (yCoord firstPt) (yCoord lastPt)))))
             (setq area (times 0.5 (abs sum))))
            (when (equal objType "rect") 
                  (setq corners (dbGetq object bBox))
                  (setq ll (car corners))
                  (setq ur (cadr corners))
                  (setq dx (difference (xCoord ll) (xCoord ur)))
                  (setq dy (difference (yCoord ll) (yCoord ur)))
                  (setq area (abs (times dx dy))))
            )
       area))

Thank you guys.

Andrew this code is working in the manner i wanted to. I tried a lot with all the possible ways i knew to convert the obtained values into microns but i can't get it. Is there a possiblity to convert the values to microns?

Thanks in advance for any help

I assume you don't really mean microns, given that area can't be in microns. You either mean square microns or maybe square metres?

Assuming that your user units in the layout are in microns (which would usually be the case) - the coordinate display in the tool should read out 1um as 1 - then the result of abArea will be in square microns. If you want it in square metres, you'd just multiply the result by 1e-12.

Regards,

Andrew.

As I said, unless something is unusual, the user units in your layout would typically be in microns (that's certainly the default, and I've not come across many people changing that default), and hence the area returned by abArea will be in square microns, and so would not need any multiplication.

Even if you wanted it in some other units, what's so difficult about doing the multiplication? It's a programming language after all - all you would need to do is:

procedure(abAreaInSquareMetres(obj)
  abArea(obj)*1e-12
)

and then use abAreaInSquareMetres instead. Or change the abArea code to include the multiplication.

I don't understand why that's a problem for you?

Andrew.

Thank You very much Andrew. I got the result as though i wanted. Really your code was very helpful to acheive my goal.

Regards,