ISO 8601 timestamp

I just wrote this - it uses the pcre (Perl Compatible Regular Expression) functions (in IC61) to parse the ISO 8601 format date string, and then the "tm" functions to convert to and from a time structure - and then to a SKILL date string. May need some further work because I just threw this together...

/* abISO8601.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Aug 08, 2012 
Modified   
By         

Functions to convert dates in ISO8601 format to either "tm"
structures or a SKILL date string.

Note that this doesn't handle time zones - so may need some
adjustment for timezones / daylight saving time (not sure).

***************************************************

SCCS Info: @(#) abISO8601.il 08/08/12.06:36:34 1.1

*/

/***************************************************************
*                                                              *
*                  (abISO8601toTm dateString)                  *
*                                                              *
* Attempts to convert an ISO8601 formatted date string into a  *
*                       "tm" structure.                        *
*                                                              *
***************************************************************/

(defun abISO8601toTm (dateString)
  (let (pattern tm slot)
    ;--------------------------------------------------------------------
    ; Note ignores anything after decimal point in seconds, as time
    ; functions in SKILL do not support finer granularity. Also the
    ; time zone is ignored. The pattern below should support both
    ; basic and extended format
    ;--------------------------------------------------------------------
    (setq pattern (pcreCompile
                    "(\\d{4})-?(\\d{2})-?(\\d{2})[T ]?(\\d{2}):?(\\d{2}):?(\\d{2})"
                    ))
    (when
      (pcreExecute pattern dateString)
      ;------------------------------------------------------------------
      ; Create an "empty" tm structure
      ;------------------------------------------------------------------
      (setq tm (timeToTm 0))
      (setq slot 1)
      (foreach (field correction) 
               '(tm_year tm_mon tm_mday tm_hour tm_min tm_sec)
               '(1900 1 0 0 0 0)
               ;---------------------------------------------------------
               ; Pull out each field from the pattern, convert to
               ; integer, and apply a correction (subtraction) 
               ; and then store in the correct field in the tm
               ; structure
               ;---------------------------------------------------------
               (putprop tm (difference
                             (atoi (pcreSubstitute
                                     pattern 
                                     (sprintf nil "\\%d" (postincrement slot))))
                             correction)
                        field)
               )
      ;------------------------------------------------------------------
      ; could do timeToTm(tmToTime(tm)) here to fill in other fields
      ; but doesn't seem really necessary
      ;------------------------------------------------------------------
      tm
      )
    )
  )

/****************************************************************
*                                                               *
*                (abISO8601toString dateString)                 *
*                                                               *
* Convert an ISO8601 date string into SKILL's usual date format *
*                                                               *
****************************************************************/

(defun abISO8601toString (dateString)
  (timeToString (tmToTime (abISO8601toTm dateString)))
  )

Hi Andrew, thanks for your wonderful code, it works great! There's one minor issue with the code in the pcreSubstitute section, the "pattern" needs to be removed to prevent "only 1 argument expected" error.

Somehow the time string returned is off by one hour, e.g. 21:53:13 in the input date string becomes 22:53:13 in the output time string. What I did is manually turn on DST in the tm structure:

tm->tm_isdst = 1
tm ; return

For the pcreSubstitute() issue, my guess is that you're using IC614 or earlier. In that version you could only specify the string. From IC615 the definition is:

pcreSubstitute(
[o_pcreObject]
t_string
)
=> t_result | nil

If o_pcreObject is not provided, pcreSubstitute copies the input
string and substitutes all pattern tags in it using the corresponding
matched strings from the last pcreExecute/pcreMatch* operation.

So I was passing in the optional pattern object. So missing it out is OK - it will work in both IC614 and IC615.

As for the daylight saving time - you could initialize the tm structure using timeToTm(stringToTime(getCurrentTime())) rather than timeToTm(0) which should give the current DST setting - but whether that's right for the time in question is another matter...

I wasn't really sure what the "right" thing to do was here...

Andrew.