how to create pin(pinname<1:10>) using skill scripting.

Leela,

Is this in a schematic, a symbol, or a layout (where probably you'd want 10 individual pins)?

In general you'd do:

net=dbMakeNet(cvId "pinname<1:10>")
pinMaster=dbOpenCellViewByType("basic" "ipin" "symbol")
pinFig=dbCreateInst(cvId pinMaster "" 0:0 "R0")
pin=dbCreatePin(net pinFig)

Or you could use:

pinMaster=dbOpenCellViewByType("basic" "ipin" "symbol")
schCreatePin(cvId pinMaster "pinname<1:10>" "input" nil 0:0 "R0")

Something like that.

Andrew.

*Error* eval: unbound variable - cvId

I tried this for generating schematic pin list and I have the following error 

If you have the schematic window open, do:

cvId=geGetEditCellView()

first to store the database object of the cellView you're hoping to update into the variable cvId.

Regards,

Andrew.

Thank you for your reply,
I have one more quick question.
I want to create multiple buffers with different i/p and o/p. Is there a way to do it in skill? 

I'm sure "it" can be done in SKILL - I just don't know what it is you're asking for!

Andrew

I want to create 71 buffers with 71 input pins and 71 output pins all the buffers are of same size.

Well, you can definitely do that in SKILL.

Regards,

Andrew.

Thanks, 
Can you help me out?I am very new to SKILL 

cv=dbOpenCellViewByType("dd" "bufd" "schematic" nil "a")
cv1=dbOpenCellViewByType("metric" "inv" "symbol")
schinst=dbCreateInst(cv cv1 nil list(0 0) "R0" 1)
I used the following to get one instances, not sure how to list the name and create 71 of them 

The first question should always be "do you need to do this in SKILL"? You could just create an instance called "MYINV<70:0>" and then have an input pin "MYINP<70:0>" and output pin "MYOUT<70:0>" and then  you're done.

Evening assuming I had the time to write this for you (which I probably don't this week as I'm on vacation for much of the week), it would need a much clearer description of precisely what you want (and why you need to do this in SKILL). How do you want the inputs to be named? How do you want the outputs to be named? Can it be a bus?

Regards,

Andrew.

Thank you for your reply,

Yes, I need to do this in SKILL, I have to create a block with input output pins, each pin has a name such as 
i_adc o_adc
There are 71 different pin names, with output pin being labelled just as o instead of i for each inverter. It shouldnt be a bus, and this is my first time on cadence SKILL and I wanted try this. 

Something like this. If you have a list of the names you want:

names=list("adc" "a" "b" "c" "d" "e")
CCFplaceInverters(names)

The code will need adapting for your own inverters, but hopefully you get the idea. I use some sch functions as they are higher level and make it easier to create pins, wires etc:

procedure(CCFplaceInverters(listOfNames @optional (cv geGetEditCellView()))
    let((master iPinMaster oPinMaster deltaY currentY Apos Ypos 
	    wireStart wireEnd wireLength inst snapSpacing)
	deltaY=0.8
	currentY=0.0
	snapSpacing=0.0625
	wireLength=0.25
	master=dbOpenCellViewByType("sample" "inv" "symbol")
	iPinMaster=dbOpenCellViewByType("basic" "ipin" "symbol")
	oPinMaster=dbOpenCellViewByType("basic" "opin" "symbol")
	;----------------------------------------------------------------
	; Find locations of pins on the symbol - will need to adapt
	; if pins called something else
	;----------------------------------------------------------------
	Apos=centerBox(car(car(dbFindTermByName(master "A")~>pins)~>figs)~>bBox)
	Ypos=centerBox(car(car(dbFindTermByName(master "Y")~>pins)~>figs)~>bBox)
	foreach(name listOfNames
	    inst=dbCreateInst(cv master sprintf(nil "I_%s" name) 
		0:currentY "R0"
	    )
	    currentY=currentY+deltaY
	    ;------------------------------------------------------------
	    ; Add input pin and wire to pin
	    ;------------------------------------------------------------
	    wireStart=dbTransformPoint(Apos inst~>transform)
	    wireEnd=xCoord(wireStart)-wireLength:yCoord(wireStart)
	    schCreateWire(cv "draw" "direct" list(wireStart wireEnd)
		snapSpacing snapSpacing 0
	    )
	    schCreatePin(cv iPinMaster sprintf(nil "i_%s" name) 
		"input" nil wireEnd "R0"
	    )
	    ;------------------------------------------------------------
	    ; Add output pin and wire to pin
	    ;------------------------------------------------------------
	    wireStart=dbTransformPoint(Ypos inst~>transform)
	    wireEnd=xCoord(wireStart)+wireLength:yCoord(wireStart)
	    schCreateWire(cv "draw" "direct" list(wireStart wireEnd)
		snapSpacing snapSpacing 0
	    )
	    schCreatePin(cv oPinMaster sprintf(nil "o_%s" name) 
		"output" nil wireEnd "R0"
	    )
	)
	schCheck(cv)
	dbSave(cv)
    )
)

Something like this. If you have a list of the names you want:

names=list("adc" "a" "b" "c" "d" "e")
CCFplaceInverters(names)

The code will need adapting for your own inverters, but hopefully you get the idea. I use some sch functions as they are higher level and make it easier to create pins, wires etc:

procedure(CCFplaceInverters(listOfNames @optional (cv geGetEditCellView()))
    let((master iPinMaster oPinMaster deltaY currentY Apos Ypos 
	    wireStart wireEnd wireLength inst snapSpacing)
	deltaY=0.8
	currentY=0.0
	snapSpacing=0.0625
	wireLength=0.25
	master=dbOpenCellViewByType("sample" "inv" "symbol")
	iPinMaster=dbOpenCellViewByType("basic" "ipin" "symbol")
	oPinMaster=dbOpenCellViewByType("basic" "opin" "symbol")
	;----------------------------------------------------------------
	; Find locations of pins on the symbol - will need to adapt
	; if pins called something else
	;----------------------------------------------------------------
	Apos=centerBox(car(car(dbFindTermByName(master "A")~>pins)~>figs)~>bBox)
	Ypos=centerBox(car(car(dbFindTermByName(master "Y")~>pins)~>figs)~>bBox)
	foreach(name listOfNames
	    inst=dbCreateInst(cv master sprintf(nil "I_%s" name) 
		0:currentY "R0"
	    )
	    currentY=currentY+deltaY
	    ;------------------------------------------------------------
	    ; Add input pin and wire to pin
	    ;------------------------------------------------------------
	    wireStart=dbTransformPoint(Apos inst~>transform)
	    wireEnd=xCoord(wireStart)-wireLength:yCoord(wireStart)
	    schCreateWire(cv "draw" "direct" list(wireStart wireEnd)
		snapSpacing snapSpacing 0
	    )
	    schCreatePin(cv iPinMaster sprintf(nil "i_%s" name) 
		"input" nil wireEnd "R0"
	    )
	    ;------------------------------------------------------------
	    ; Add output pin and wire to pin
	    ;------------------------------------------------------------
	    wireStart=dbTransformPoint(Ypos inst~>transform)
	    wireEnd=xCoord(wireStart)+wireLength:yCoord(wireStart)
	    schCreateWire(cv "draw" "direct" list(wireStart wireEnd)
		snapSpacing snapSpacing 0
	    )
	    schCreatePin(cv oPinMaster sprintf(nil "o_%s" name) 
		"output" nil wireEnd "R0"
	    )
	)
	schCheck(cv)
	dbSave(cv)
    )
)