How to Calculate Hysteresis using OCEAN/SKILL script

This might  help:

/* abWaveToList.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Nov 17, 2003 
Modified   
By         

Convert a waveform to a list

***************************************************

SCCS Info: @(#) abWaveToList.il 11/17/03.15:08:15 1.1

*/

/************************************************************************
*                                                                       *
*                  (abWaveToList wave @key transpose)                   *
*                                                                       *
*    Take a waveform object, and return it as a list of xy pairs. Or    *
* if transpose is set, it returns a list of x values followed by a list *
*                             of y values.                              *
*                                                                       *
************************************************************************/

(procedure (abWaveToList wave @key transpose)
  (let (xList yList xyList len
	(xVec (drGetWaveformXVec wave))
	(yVec (drGetWaveformYVec wave))
	)
       (setq len (drVectorLength xVec))
       ;-----------------------------------------------------------------
       ; Return value of this if is the list
       ;-----------------------------------------------------------------
       (if transpose
	   (progn
	    (for i 0 (sub1 len)
		 (setq xList (tconc xList (drGetElem xVec i)))
		 (setq yList (tconc yList (drGetElem yVec i)))
		 )
	    (list (car xList) (car yList))
	    )
	   ; else
	   (progn
	    (for i 0 (sub1 len)
		 (setq xyList (tconc xyList (list (drGetElem xVec i)
						  (drGetElem yVec i))))
		 )
	    (car xyList)
	    )
	   ) ; if
       ) ; let
  ) ; procedure 

Kishore, 

There's nothing wrong with the syntax. There's no missing "then".

The if function can be used without then and else - e.g. if you do if(condition thenExpression elseExpression) (i.e. if there's a single expression). In my code I'm using progn() to group multiple expressions into one). This is more of the LISP way of doing things.

Regards,

Andrew.

Hi Andrew,

Thanks for this reply. Although I have been using OCEAN and Skill for a few weeks, I didn't realize that an if statement doesn't execute multiple statements inside the if start and end braces unless you provide a then   e.g. if(condn  exp1 exp2 exp3) would only execute exp1 not exp2 and exp3. But if exp2 and exp3 are simple assignment statements it doesn't show an error, it just doesn't execute them. Today when I used a print() and/or an outfile() statement for exp2/exp3 it started giving errors. This post clarifies the problem. One question if I use if(condn then exp1 exp2 exp3), it should be fine, I do not need to use the else unless I want to, right? 

Actually, if does give an error if you have more than 3 arguments without a then statement:

> if(t 1 2 3)
*Error* if: too many arguments (missing then?) - (t 1 2 3)

You can specify an if() with a then without an else (but I would generally recommend using when() instead). Similarly if you only really need the else part, rather than inverting the condition, use unless().

The behaviour is quite consistent - I didn't understand what you meant about giving errors when there are print() or outfile() - it either executes the statements or it doesn't....

Regards,

Andrew.

Thanks!  I tested with 2 statements only. e.g 

idx=10
if(idx==10
k=5
j=40
)

this didn't give an error but j was not 40, it was unbound or retained any previously assigned value. My third statement was an outfile() in the original prog, I thought the extra parentheses in outfile or print was what caused error to be diagnosed. But I guess any third statement would display the error.

Regards