Collecting data from the 'tran' analysis for specific time

Aarthy,

No problem with being on this forum. Anyway, the value() function will cope with a family - it produces a waveform of the results versus the swept variable.

You can't do it on multiple instances though, because these are separate waveforms. Potentially you could group them, using a calculator function such as this, but not sure if that's really your main problem here.

/* abGroup.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Feb 13, 2008 
Modified   
By         

Calculator function to group waveforms into a family so
that they can be conveniently processed together.

Can be registered as a special function in the calculator
by using:

abRegGroupSpecialFunction()

Also, can directly call abGroup(v("1") v("2") v("3")...) to
create the family.

If used as a special function, you need to ensure there is one
waveform in the buffer, and the remainder of entries on the 
stack, and you get prompted for the number of expressions to
make a group (aka family) from.

***************************************************

SCCS Info: @(#) abGroup.il 02/13/08.14:03:12 1.1

*/

/***************************************************************
*                                                              *
*                     (abCreateGroupForm)                      *
*                                                              *
*           Create the form for the special function           *
*                                                              *
***************************************************************/
(procedure (abCreateGroupForm)
  (let (nitems)
       (setq nitems (ahiCreateIntField
                    ?name 'nitems
                    ?prompt "Number of Expressions"
                    ?value 1
                    ))
       (calCreateSpecialFunctionsForm
        'abGroupForm
        (list (list nitems 0:0 200:20 160)
              ))
       ))

/***************************************************************
*                                                              *
*                  (abGroupSpecialFunctionCB)                  *
*                                                              *
*          Callback for the abGroup special function           *
*                                                              *
***************************************************************/
(procedure (abGroupSpecialFunctionCB)
  (calCreateSpecialFunction
   ?formSym 'abGroupForm
   ?formInitProc 'abCreateGroupForm
   ?formTitle "Group Expressions"
   ?formCallback 
   "(abGroupCalSpecialFunctionInput)"
   ))

/*************************************************************************
*                                                                        *
*                    (abGroupCalSpecialFunctionInput)                    *
*                                                                        *
*   Create the expression from the form. This has to build an argument   *
* with a list of STACK symbols - one less than the number of expressions *
*         asked for, since one is coming from the input buffer.          *
*                                                                        *
*************************************************************************/
(procedure (abGroupCalSpecialFunctionInput)
  (let (form nitems stackargs)
    (setq form (hiGetCurrentForm))
    (setq nitems (getq (getq form nitems) value))
    ;--------------------------------------------------------------------
    ; Need one less than nitems because the top entry on stack
    ; is always included
    ;--------------------------------------------------------------------
    (for i 2 nitems
         (setq stackargs (cons 'STACK stackargs)))
    (calSpecialFunctionInput 
      'abGroup 
      stackargs
      )
    )
  )

/***************************************************************
*                                                              *
*                 (abRegGroupSpecialFunction)                  *
*                                                              *
*  Register the abGroup special function with the calculator   *
*                                                              *
***************************************************************/
(procedure (abRegGroupSpecialFunction)
  (calRegisterSpecialFunction
   (list "abGroup..." 'abGroupSpecialFunctionCB))
  t
  )

/*************************************************************************
*                                                                        *
*              (abGroup @key (name 'index) @rest waveforms)              *
*                                                                        *
* The function that does the work. Takes a variable number of arguments, *
*  each of which is a waveform to add to the family. The sweep variable  *
*   for the family is specified by the ?name arg if desired, otherwise   *
*                         it defaults to 'index.                         *
*                                                                        *
*************************************************************************/
(procedure (abGroup @key (name 'index) @rest waveforms)
  (let (family (count 1))
    (setq family (famCreateFamily name 'double))
    (foreach wave waveforms
             (famAddValue family (postincrement count) wave)
             )
    family
    )
  ) ; procedure

Regards,

Andrew.