Cadence IC5.1.41 libInit.il

This isn't entirely trivial due to a bug in one of the "FirstAccessLib" triggers which means that it doesn't return t (in some cases) and prevents subsequent triggers from running.

Put this in a file with a ".ils" suffix, and load it:

 let(((libTable makeTable('libTable nil)))
    procedure(doSomethingAfter(libName function)
        libTable[libName]=function
    )
    procedure(doSomethingAfterTrigger(@optional libId)
        when(isCallable('hiRegTimer)
            hiRegTimer(sprintf(nil "abDoSomethingAfterLibInitDeferredTrigger(%L)" libId~>name) 0)
        )
    )
    procedure(deferredDoSomethingAfterTrigger(libName)
        let((function)
            function=libTable[libName]
            when(function
                errset(funcall(function libName) t)
            )
        ;----------------------------------------------------------------
        ; this is so that the trigger always returns t
        ; so that subsequent triggers get called, just in
        ; case the user forgets in their code
        ;----------------------------------------------------------------
        t
        )
    )
    ;--------------------------------------------------------------------
    ; Make all the functions global. Can't use defglobalfun or globalProc since
    ; this is for IC5141
    ;--------------------------------------------------------------------
    abDoSomethingAfterLibInit=doSomethingAfter
    abDoSomethingAfterLibInitTrigger=doSomethingAfterTrigger
    abDoSomethingAfterLibInitDeferredTrigger=deferredDoSomethingAfterTrigger
    ;--------------------------------------------------------------------
    ; because there's an issue with one of the existing triggers not
    ; returning t in IC5141, can't omit the third argument and have the
    ; trigger called last, because it never gets called. So instead call it
    ; first (or at least early), but use hiRegTimer to call the real
    ; function once the UI returns
    ;--------------------------------------------------------------------
    ddRegTrigger("FirstAccessLib" 'abDoSomethingAfterLibInitTrigger 1)
)

Then you'd use it like this:

procedure(myDoSomethingAfter(libName)
  printf("DO MY STUFF for lib %L\n" libName)
)
abDoSomethingAfterLibInit("gpdk090" 'myDoSomethingAfter)

Note that the code will only work in interactive virtuoso sessions (non-graphical too) - but not things like the stream interfaces or "dbAccess". That's because it relies on using hiRegTimer to get around the issue with the built-in trigger not returning t (I forget which one it is; it's been fixed in IC61X though).

Regards,

Andrew.

This isn't entirely trivial due to a bug in one of the "FirstAccessLib" triggers which means that it doesn't return t (in some cases) and prevents subsequent triggers from running.

Put this in a file with a ".ils" suffix, and load it:

 let(((libTable makeTable('libTable nil)))
    procedure(doSomethingAfter(libName function)
        libTable[libName]=function
    )
    procedure(doSomethingAfterTrigger(@optional libId)
        when(isCallable('hiRegTimer)
            hiRegTimer(sprintf(nil "abDoSomethingAfterLibInitDeferredTrigger(%L)" libId~>name) 0)
        )
    )
    procedure(deferredDoSomethingAfterTrigger(libName)
        let((function)
            function=libTable[libName]
            when(function
                errset(funcall(function libName) t)
            )
        ;----------------------------------------------------------------
        ; this is so that the trigger always returns t
        ; so that subsequent triggers get called, just in
        ; case the user forgets in their code
        ;----------------------------------------------------------------
        t
        )
    )
    ;--------------------------------------------------------------------
    ; Make all the functions global. Can't use defglobalfun or globalProc since
    ; this is for IC5141
    ;--------------------------------------------------------------------
    abDoSomethingAfterLibInit=doSomethingAfter
    abDoSomethingAfterLibInitTrigger=doSomethingAfterTrigger
    abDoSomethingAfterLibInitDeferredTrigger=deferredDoSomethingAfterTrigger
    ;--------------------------------------------------------------------
    ; because there's an issue with one of the existing triggers not
    ; returning t in IC5141, can't omit the third argument and have the
    ; trigger called last, because it never gets called. So instead call it
    ; first (or at least early), but use hiRegTimer to call the real
    ; function once the UI returns
    ;--------------------------------------------------------------------
    ddRegTrigger("FirstAccessLib" 'abDoSomethingAfterLibInitTrigger 1)
)

Then you'd use it like this:

procedure(myDoSomethingAfter(libName)
  printf("DO MY STUFF for lib %L\n" libName)
)
abDoSomethingAfterLibInit("gpdk090" 'myDoSomethingAfter)

Note that the code will only work in interactive virtuoso sessions (non-graphical too) - but not things like the stream interfaces or "dbAccess". That's because it relies on using hiRegTimer to get around the issue with the built-in trigger not returning t (I forget which one it is; it's been fixed in IC61X though).

Regards,

Andrew.