how to search for specific devices/models into spectre netlist?

Hi Marcel,

Not sure SKILL is really the right way to do it for a spectre netlist. You can do this directly in spectre though using spectre's assert statement. For example:

//
// example of showing an assert statement to range check
// a transistor size

model nch bsim4 type=n
model pch bsim4 type=p

subckt block1 (a y vdd vss)
MP1 (y a vdd vdd) pch w=0.4u l=0.2u
MN1 (y a vss vss) nch w=0.5u l=0.2u
ends block1

subckt block2 (a y vdd vss)
I1 (a b vdd vss) block1
I2 (b y vdd vss) block1
ends block2

top (n1 n2 vdd 0) block2
v1 (n1 0) vsource type=pulse val0=0 val1=1 rise=1n period=20n width=10n
vdd (vdd 0) vsource dc=1

// here's the check
smallMos assert mod=pch param=w min=0.5u message="nch transistor too small"
// in this case I've told it to write to a file; if this is not given, it
// will write in the simulation log file (see spectre -h options for other check options)
myOptions options checklimitfile="asserts.out"

tran tran stop=1u

Regards,

Andrew.

 Hi Andrew,

The assert and checklimit statements solved a part of my problem: I can find the small devices.

But I'll need one more thing: I want to not allow some specific devices in the netlist, or at least to provide a warning if they exists.

The problem is that those devices are defined as "inline subckt.."

E.g.

inline subckt phx (d g s b)
parameters
*
+ w             = 1
+ l             = 1
...

ends  phx

And I want to warn the designer if the the netlist I have at least one phx `device'.

I've try to use something like:

// check for unwanted devices

// 0.01u is below minimum allowed by technology

notAllowedModel assert mod=phx param=w max=0.01u message="model phvt not allowed"

But I get next warning in the log: Specified model `phx' was not found. Assert is ignored.

Of course I can write a script in any other languge and parse the ascii file,but we have the include statements.Files that include other files that include other files that... and so on. I guess that if there is a buitin command in spectre it will be much faster.

Best Regards,

Marcel

Hi Marcel,

For a subckt (or inline subckt) model, you can't use mod=... - you need to use sub= or subs=. For example, one of these:

 badMos assert sub=phx param=w max=0.01u message="not allowed to use phx"

or

 badMos assert subs=[phx] param=w max=0.01u message="not allowed to use phx"

The subs option allows you to give a list of subckt masters instead.

I tried this using this netlist:

//
// example of showing an assert statement to range check
// a transistor size

model nch bsim4 type=n
model pch bsim4 type=p

inline subckt nchbad (d g s b)
parameters w=1u l=1u
nchbad (d g s b) nch w=w l=l
ends nchbad

subckt block1 (a y vdd vss)
MP1 (y a vdd vdd) pch w=0.4u l=0.2u
MN1 (y a vss vss) nchbad w=0.5u l=0.2u
ends block1

subckt block2 (a y vdd vss)
I1 (a b vdd vss) block1
I2 (b y vdd vss) block1
ends block2

top (n1 n2 vdd 0) block2
v1 (n1 0) vsource type=pulse val0=0 val1=1 rise=1n period=20n width=10n
vdd (vdd 0) vsource dc=1

// here's the check
smallMos assert mod=pch param=w min=0.5u message="nch transistor too small"
//badMos assert subs=[nchbad] param=w max=0.01u message="not allowed to use nchbad"
badMos assert sub=nchbad param=w max=0.01u message="not allowed to use nchbad"
// in this case I've told it to write to a file; if this is not given, it
// will write in the simulation log file (see spectre -h options for other check options)
myOptions options checklimitfile="asserts.out"

tran tran stop=1u

Regards,

Andrew.

 Hi Andrew,

"subs" is exactly what I want.

Started to read Spectre Circuit Simulator User Guide :D, it seems to be extreamly powerful.

BR,

Marcel