How do I properly format a imported properties file into SKILL to create shapes

In general I would recommend writing the file in a format that is easy to parse - using things like lineread() can make it very easy to parse text which is in a SKILL-like syntax. 

Assuming you're stuck with what you have though, how about this:

layerPairPattern=pcreCompile("^LayerPair:(.*)$")
when(pcreExecute(layerPairPattern line)
  data=car(linereadstring(pcreSubstitute(layerPairPattern "\\1")))
)

Assuming your line to process is in a variable line then data would contain ("m2" "drawing") (i.e. a list).

If you're using IC5141, you'd have to use rex functions rather than pcre functions, but pattern matching is still your friend. Just a little less powerful in general:

rexCompile("^LayerPair:\\(.*\\)$")
when(rexExecute(line)
  data=car(linereadstring(rexSubstitute("\\1")))
)

Note that the pattern syntax is slightly different for the "registers" (i.e. remembering parts of a pattern) with rex than pcre.

Regards,

Andrew.

Hi Andrew,

The oldest version is IC615.

I have some flexibility on the file to parse. I created the first part of the script but later learned the user wanted to Re-Create modified versions of the shapes.

I would appreciate suggestions on the format of the file.

I still have the limitation of labeling the items for the user to know the information. The properties and coordinates is what they'll likely modify.

Thanks for responding,

Julia 

Hi Julia,

For example, missing out the colons would make it much easier as you could then read each line using linereadstring or even just lineread from the original file. I also changed the coordinates to be as lists, and removed the exclamation mark from the EndShape statement. So:

LayerPair ("m1" "drawing")
ShapePts ((0.0 0.0) (100.0 100.0))
PropertyName Name PropertyValue "p3"
LxLyCoor (0.000000 0.000000)
DxDy (100.000000 100.000000)
EndShape

Doesn't lose much in terms of readability, but you can then do:

prt=infile("data.txt")
while(data=lineread(prt)
  when(listp(data)
    case(car(data)
      (LayerPair  printf("LayerPair is %L\n" cadr(data)))
      (ShapePts  printf("Points: %L\n" cadr(data)))
      (PropertyName printf("Create a property %s with value %s\n" cadr(data) cadddr(data)))
      (LxLyCoor printf("LxLy is at %L\n" cadr(data)))
      (DxDy printf("DxDy is at %L\n" cadr(data)))
      (EndShape printf("The end of the shape as we know it!\n"))
    )
  )
)
close(prt)

This then displays:

Points: ((0.0 0.0) (100.0 100.0))
Create a property Name with value p3
LxLy is at (0.0 0.0)
DxDy is at (100.0 100.0)
The end of the shape as we know it!

Now you could go a lot further and make it even more machine readable - but maybe this ends up being less human readable:

(Shape
 LayerPair ("m1" "drawing")
 ShapePts ((0.0 0.0) (100.0 100.0))
 PropertyName Name PropertyValue "p3"
 LxLyCoor (0.000000 0.000000)
 DxDy (100.000000 100.000000)
)

Then you could use:

prt=infile("data.txt")
data=car(lineread(prt))
close(prt)
data->LayerPair  => ("m1" "drawing")
data->PropertyValue => "p3"

In other words, it's a disembodied property list, and you just slurped it all back into a DPL.

Anyway, either approach is pretty reasonable and avoids complex parsing.

Regards,

Andrew.

Working extremely well. I'm able to manipulate and move forward with the next requirements. THANKS!!