Drop-down menu disappears from schematic window, moving into layout window when VXL is launched

Danny,

Two problems:

1. Menus should be added via user menu trigger, not the user post-install trigger. This is the second argument to deRegUserTriggers. The idea is that the user menu trigger returns a list of pulldown menus, and "DE" takes care of adding them into the window. This is far more reliable than doing it via the post-install trigger
2. You didn't provide the code for UtilitiesMenu() or schUtilitiesMenu(), and this is highly likely to be where the problem is. My guess is that these functions use hiGetCurrentWindow() to determine the window to insert the menus into - and that may not be the correct window when you are starting XL - because it is opening a second editor window. Again, this wouldn't be a problem if it was done using the user menu trigger approach (or even if the window was retrieved from args->window - although you really should use the user menu trigger approach)

Regards,

Andrew.

Hi Andrew,  

Thanks for the advice.  Below please find the code for the UtilitiesMenu() and schUtilitiesMenu(). Both code modules are loading few skill files. You are correct. In both scripts there is a use of hiGetCurrentWindow()  function.

Could you please provide a short example of better usage of the Trigger function? 'deRegUserTriggers("maskLayout" nil nil 'DRSetups)' so this issue will be solved?

Thanks for your time and help!

Danny

---------------------------------------

; Description
; SKILL utilities

; Loading sub-programs

; Load Triggers
; LAYOUT an d Schematic
load "/home/skill/Triggers.il"
printf("Loading: Layout and Schematic Triggers...\n")

; Zoom to Coordinates
load "/home/skill/zoomToCoords.il"
printf("Loading: zoomToCoords...\n")

; Put on GRID
load "/home/skill/putOnGrid.il"
printf("Loading: putOnGrid...\n")

;----------------------

; Loading Schematic Menu
;
load "/home/skill/schMenu.il"
printf("Loading: Schematic Menu...\n")

;----------------------

procedure( UtilitiesMenu()

graphicsWin=hiGetCurrentWindow()

; If pull down menu does not exist, create it

; PullDown menu Creation
;-----------------------

utilMenuItemOne=hiCreateMenuItem(
        ?name           'utilMenuItemOne
        ?itemText       "Zoom to Coords"
        ?callback       "zoomToPoint()"
        )
utilMenuItemTwo=hiCreateMenuItem(
        ?name           'utilMenuItemTwo
        ?itemText       "Mark Coords"
        ?callback       "zoomGUI()"
        )

utilMenuItemThree=hiCreateMenuItem(
        ?name           'utilMenuItemThree
        ?itemText       "Put on GRID"
        ?callback       "CCSputOnGrid()"
        )


hiCreatePulldownMenu(
        'utilitiesPulldownMenu
        "Utilities"
           list(
            hiCreateSliderMenuItem(
                    ?name 'CCSsliderMenuItem1
                    ?itemText "28nm"
                    ?subMenu

                hiCreatePulldownMenu(
                        'CCSsubMenu
                        ""
              list(
                util28SubMenuOne
                util28SubMenuTwo
                util28SubMenuThree
                  )
               ) ; CreatePullDownMenu of Sub Menu
            ) ; Slider

            hiCreateSliderMenuItem(
                    ?name 'CCSsliderMenuItem2
                    ?itemText "180nm"
                    ?subMenu

                hiCreatePulldownMenu(
                        'CCSsubMenu
                        ""
              list(
                util180SubMenuOne
                util180SubMenuTwo
                  )
               ) ; CreatePullDownMenu of Sub Menu
            ) ; Slider


                 utilMenuItemOne
                 utilMenuItemTwo
                 utilMenuItemThree
                
                        )
        )

          hiInsertBannerMenu( graphicsWin utilitiesPulldownMenu hiGetNumMenus(graphicsWin))


 ; ) ; End of if exist 'utilitiesPulldownMenu


) ; End of procedure( UtilitiesMenu()

------------------------------------------------------------------------

schMenu.il

=========

; Loading sub-programs

; NET Hierarchy
load "/home/skill/schHierNetinfo.il"
printf("Loading: NET Hierarchy...\n")

; Specific NET
load "/home/skill/schNetInfo.il"
printf("Loading: Specific NET information...\n")

; Hierarchy Tree
load "/home/skill/schTree.il"
printf("Loading: Hierarchy Tree...\n")
procedure( schUtilitiesMenu()

graphicsWin=hiGetCurrentWindow()

; If pull down menu does not exist, create it

; PullDown menu Creation
;-----------------------

SCHutilMenuItemOne=hiCreateMenuItem(
        ?name           'SCHutilMenuItemOne
        ?itemText       "NET Information"
        ?callback       "schSpecificNetApp()"
        )


SCHutilMenuItemTwo=hiCreateMenuItem(
        ?name           'SCHutilMenuItemTwo
        ?itemText       "NET Hierarchical Information"
        ?callback       "schNetApp()"
        )

sep1=hiCreateSeparatorMenuItem(?name 'sep1)

SCHutilMenuItemThree=hiCreateMenuItem(
        ?name           'SCHutilMenuItemThree
        ?itemText       "Hierarchy Tree"
        ?callback       "CCShiSchTree()"
        )

hiCreatePulldownMenu(
        'SCHutilitiesPulldownMenu
        "Schematic Utilities"
              list(
                 SCHutilMenuItemOne
                 SCHutilMenuItemTwo
                 sep1
                 SCHutilMenuItemThree
            
                )
        )

          hiInsertBannerMenu( graphicsWin SCHutilitiesPulldownMenu hiGetNumMenus(graphicsWin))


 ; ) ; End of if exist 'SCHutilitiesPulldownMenu


) ; End of procedure( schUtilitiesMenu()

Hi Andrew,

I found an example that you provided here which helped me solving the issue. Everything seems to work OK since I cancelled the menu insertion as you suggested. (The Design Editor infrastructure takes care of this topic.)

Yet, there is still one more question please: (For the perfectionism's sake...)

If I start by reading schematic and then launching XL from within that schematic window, it creates all menus OK in the schematic and layout windows, but gives me this one message in the CIW:

*WARNING* __deMakeBannerMenus ("schematicXL"), duplicate menu(s) removed

I assume that this is due to the fact that the Drop-Down menu is already exist in the initial schematic window.

Is there any way to identify the menu's existence and avoid this warning?

Thanks!

Danny

Danny,

Please post your code. I tried a simple example and don't see this behaviour.

Regards,

Andrew.

Hi Andrew,

Here is the code. Based on your example, I removed the use of  hiGetCurrentWindow() and everything is working fine. The menus do not duplicate anymore and properly show on the schematic and layout windows.

The only question is when I start with opening a schematic window and then launch VXL from it, it gives me this one line in the CIW:

*WARNING* __deMakeBannerMenus ("schematicXL"), duplicate menu(s) removed.

And I was wondering if I can prevent this line.

Thanks!

Danny

----------------------------------------------------------------------------------

; Load Triggers
; LAYOUT an d Schematic
load "/home/skill/Triggers.il"
printf("Loading: Layout and Schematic Triggers...\n")
 
; Zoom to Coordinates
load "/home/skill/zoomToCoords.il"
printf("Loading: zoomToCoords...\n")

; Mark Coords
load "/home/skill/markCoords.il"
printf("Loading: markCoords...\n")

; Put on GRID
load "/home/skill/DRputOnGrid.il"
printf("Loading: DRputOnGrid...\n")

;----------------------

; Loading Schematic Menu
;
load "/home/skill/schMenu.il"
printf("Loading: Schematic Menu...\n")

;----------------------

procedure( UtilitiesMenu(args)

; If pull down menu does not exist, create it

; PullDown menu Creation
;-----------------------

utilMenuItemOne=hiCreateMenuItem(
 ?name  'utilMenuItemOne
 ?itemText "Zoom to Coords"
 ?callback "zoomToPoint()"
 )
utilMenuItemTwo=hiCreateMenuItem(
 ?name  'utilMenuItemTwo
 ?itemText "Mark Coords"
 ?callback "zoomGUI()"
 )

utilMenuItemThree=hiCreateMenuItem(
        ?name           'utilMenuItemThree
        ?itemText       "Put on GRID"
        ?callback       "CCSputOnGrid()"
        )

list(hiCreatePulldownMenu(
 'utilitiesPulldownMenu
 "Layout Utilities"
    list(
            hiCreateSliderMenuItem(
                    ?name 'CCSsliderMenuItem1
                    ?itemText "28nm"
                    ?subMenu

                hiCreatePulldownMenu(
                        'CCSsubMenu
                        ""
              list(
                util28SubMenuOne
                util28SubMenuTwo
                util28SubMenuThree
                  )
               ) ; CreatePullDownMenu of Sub Menu
            ) ; Slider

            hiCreateSliderMenuItem(
                    ?name 'CCSsliderMenuItem2
                    ?itemText "180nm"
                    ?subMenu

                hiCreatePulldownMenu(
                        'CCSsubMenu
                        ""
              list(
                util180SubMenuOne
                util180SubMenuTwo
                  )
               ) ; CreatePullDownMenu of Sub Menu
            ) ; Slider

 
                 utilMenuItemOne
                 utilMenuItemTwo
                 utilMenuItemThree
                 
               
         )
      )
  ) 

) ; End of procedure - UtilitiesMenu()

deRegUserTriggers("maskLayout" nil 'UtilitiesMenu)
deRegUserTriggers("maskLayoutXL" nil 'UtilitiesMenu)
deRegUserTriggers("maskLayoutGXL" nil 'UtilitiesMenu)

---------------------------------------------------------------------------------------------

schMenu.il

========

; NET Hierarchy
load "/home/skill/schHierNetinfo.il"
printf("Loading: NET Hierarchy...\n")

; Specific NET
load "/home/skill/schNetInfo.il"
printf("Loading: Specific NET information...\n")

; Hierarchy Tree
load "/home/skill/schTree.il"
printf("Loading: Hierarchy Tree...\n")

procedure( schUtilitiesMenu(args)

; If pull down menu does not exist, create it

; PullDown menu Creation
;-----------------------

SCHutilMenuItemOne=hiCreateMenuItem(
 ?name  'SCHutilMenuItemOne
 ?itemText "NET Information"
 ?callback "schSpecificNetApp()"
 )

SCHutilMenuItemTwo=hiCreateMenuItem(
        ?name           'SCHutilMenuItemTwo
        ?itemText       "NET Hierarchical Information"
        ?callback       "schNetApp()"
        )

SCHutilMenuItemThree=hiCreateMenuItem(
        ?name           'SCHutilMenuItemThree
        ?itemText       "Hierarchy Tree"
        ?callback       "CCShiSchTree()"
        )

 list(hiCreatePulldownMenu(
 'SCHutilitiesPulldownMenu
 "Schematic Utilities"
              list(
                 SCHutilMenuItemOne
                 SCHutilMenuItemTwo
                 SCHutilMenuItemThree
                 
          )
       )
   ) 

) ; End of procedure( schUtilitiesMenu()

deRegUserTriggers("schematic" nil 'schUtilitiesMenu)
deRegUserTriggers("schematicXL" nil 'schUtilitiesMenu)

---------------------------------------------------------

Danny,

I've worked out the problem. First of all, it seems that registering the trigger for Schematic XL isn't strictly necessary - it calls the Schematic L trigger anyway and retrieves the menus for that. So the function to retrieve the schematic menus gets called twice.

Now this in itself isn't a major problem, unless you always redefine the menu. In my case I had code around it to prevent it unnecessarily recreating the menu if it had already been created - and that stops the problem from occurring too. So changing your code to:

procedure( schUtilitiesMenu(args)

; changed to only create it the first time
unless(boundp('SCHutilitiesPulldownMenu)
; If pull down menu does not exist, create it

; PullDown menu Creation
;-----------------------

SCHutilMenuItemOne=hiCreateMenuItem(
 ?name  'SCHutilMenuItemOne
 ?itemText "NET Information"
 ?callback "schSpecificNetApp()"
 )


SCHutilMenuItemTwo=hiCreateMenuItem(
        ?name           'SCHutilMenuItemTwo
        ?itemText       "NET Hierarchical Information"
        ?callback       "schNetApp()"
        )

SCHutilMenuItemThree=hiCreateMenuItem(
        ?name           'SCHutilMenuItemThree
        ?itemText       "Hierarchy Tree"
        ?callback       "CCShiSchTree()"
        )

hiCreatePulldownMenu(
 'SCHutilitiesPulldownMenu
 "Schematic Utilities"
              list(
                 SCHutilMenuItemOne
                 SCHutilMenuItemTwo
                 SCHutilMenuItemThree
                 
          )
       )
)

list(SCHutilitiesPulldownMenu)

) ; End of procedure( schUtilitiesMenu()

This should fix it too.

Andrew.

Problem solved...

I appreciate your prompt help Andrew!

Many Thanks,

Danny