How can I make this code to work in CDB database

/* abGetHierPathTransform.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Apr 27, 2014 
Modified   
By         

IC61X has a function dbGetHierPathTransform which takes one of the 
outputs from dbGetOverlaps and gives you the overall transformation.
This function did not exist in IC5141. So this code provides an
equivalent function which handles mosaics (i.e. when the fifth
argument to dbGetOverlaps is t, which returns the mosaic index information)

Note that the code assumes the rotation semantics for IC5141 for
mosaics; if dbGetHierPathTransform is available, it uses that.

Also contains an implementation of a function to return the leaf shape
itself - abGetHierPathShape. A combination of these can be used to
copy a figure to the top level coordinate space, or transform points
or bBox to the top level.

Test functions are at the bottom of the code (I have layouts with
lots of "F" shapes with different orientations, in mosaics or not, at
different levels of hierarchy).

***************************************************

SCCS Info: @(#) abGetHierPathTransform.il 04/27/14.07:24:39 1.1

*/


/********************************************************************
*                                                                   *
*                 (abGetHierPathTransform overlap)                  *
*                                                                   *
*     An equivalent of the IC61 dbGetHierPathTransform function     *
* which also works in IC5141 and earlier. If dbGetHierPathTransform *
*   is available, it uses that - otherwise it does the same thing   *
*              itself, making sure it handles mosaics.              *
*                                                                   *
********************************************************************/

(defun abGetHierPathTransform (overlap)
  (if (isCallable 'dbGetHierPathTransform)
    (dbGetHierPathTransform overlap)
    (if (listp overlap)
      (dbConcatTransform
        (abGetHierPathTransform (cadr overlap))
        (if (listp (car overlap))
          (let (mosaic xy row col)
            (setq mosaic (dbGetq (caar overlap) mosaic))
            (setq row (cadar overlap))
            (setq col (caddar overlap))
            (setq xy
                  (list
                    (plus (xCoord (dbGetq mosaic xy))
                          (times col (dbGetq mosaic uX)))
                    (plus (yCoord (dbGetq mosaic xy))
                          (times row (dbGetq mosaic uY)))
                    ))
            (list xy (car (dbGetq mosaic tileArray)) 1.0)
            )
          (if (equal (dbGetq (car overlap) objType) "mosaicInst")
            (error "Encountered mosaicInst %L - should have used t as 5th arg of dbGetOverlaps"
                   (car overlap))
            (dbGetq (car overlap) transform)
            )
          )
        )
      (list 0:0 "R0" 1.0)
      )
    )
  )

/***************************************************************
*                                                              *
*                 abGetHierPathShape (overlap)                 *
*                                                              *
*             Find the leaf shape from an overlap              *
*                                                              *
***************************************************************/

(defun abGetHierPathShape (overlap)
  (if (listp overlap)
    (abGetHierPathShape (cadr overlap))
    overlap))

/***************************************************************
*                                                              *
*            (abTestHierPathTransformCB wid points)            *
*                                                              *
*   addPointProc for the test function. Finds an overlapping   *
* shape at the clicked point (on Metal2) and copies it to top  *
*                       level on Metal3.                       *
*                                                              *
***************************************************************/

(defun abTestHierPathTransformCB (wid points)
  (let (newPoint newFig)
    (setq newPoint (car (last points)))
    (foreach overlap 
             (dbGetOverlaps (geGetEditCellView wid) (list newPoint newPoint)
                            "Metal2" 32 t)
             (setq newFig
                   (dbCopyFig (abGetHierPathShape overlap)
                              (geGetEditCellView wid)
                              (abGetHierPathTransform overlap)))
             (dbSetq newFig "Metal3" layerName)
             )
    )
  )

/***************************************************************
*                                                              *
*                  (abTestHierPathTransform)                   *
*                                                              *
*             Interactive test for this function.              *
*                                                              *
***************************************************************/

(defun abTestHierPathTransform ()
  (enterPoints
    ?prompts (list "Click on a shape")
    ?addPointProc "abTestHierPathTransformCB"
    )
  )