Adding new item to already created custom menu (for all Layout Editor windows)

By the way, this is what I tried, and it kind of works:

;;; Procedure for the SSM Macro! This will always be there.
procedure( sstSSMAddLayoutEditorMacroMenuItem( _args )
     let( ( item1 item2 )
        ;;; create a couple of menu items
        item1 = hiCreateMenuItem(
                ?name 'item1
                ?itemText "My First Item"
                ?callback "printf( \"%L\n\" geGetWindowCellView( hiGetCurrentWindow() ) )"
            )
        item2 = hiCreateMenuItem(
                ?name 'item2
                ?itemText "My Second Item"
                ?callback "printf( \"Option 2 clicked...\n\" )"
            )
        
        ;;; create a menu that includes the menu items and returns a list of the pulldown menus
        list( hiCreatePulldownMenu( 'sstMacroMenu "SST Macro Menu" list( item1 item2 ) ) )
    ) ;;; end of let
) ;;; end of procedure sstSSMAddLayoutEditorMacroMenuItem

;; create a userMenuTrigger trigger that automatically adds the menu
deRegUserTriggers( "maskLayout" nil 'sstSSMAddLayoutEditorMacroMenuItem )

;;; Procedure for the STM Macro! This is for optional macro's.
procedure( sstSTMAddLayoutEditorMacroMenuItem( _args )
     let( (    item
        item3
        ( newItemList nil ) )
        when( boundp( 'sstMacroMenu )
            ;;; Get the current items of the menu and put them in a list
            foreach( item sstMacroMenu~>_menuItemList
                newItemList = tconc( newItemList get( sstMacroMenu item ) )
            ) ;;; end of foreach
        
            ;;; Add the new item to the back of the list.
            newItemList = tconc( newItemList hiCreateMenuItem(
                        ?name 'item3
                        ?itemText "My Third Item"
                        ?callback "printf( \"Option 3 clicked...\n\" )"
                    ) )
            
            newItemList = car( newItemList )
            
            ;;; create a menu that includes the menu items and returns a list of the pulldown menus
            list( hiCreatePulldownMenu( 'sstMacroMenu "SST Macro Menu" newItemList ) )
        ) ;;; end of when
    ) ;;; end of let
) ;;; end of procedure sstSTMAddLayoutEditorMacroMenuItem

deRegUserTriggers( "maskLayout" nil 'sstSTMAddLayoutEditorMacroMenuItem )

What is the problem with this approach?

It generates a second pull-down menu. The first menu contains two items, and the second menu contains all three items. So the part of adding an item works, but the updating part of the existing menu does not work. How do I get this to work properly?

Thanks in advance.

With kind regards,

Sjoerd

Hi Sjoerd,

There are several ways that this could be done, but I would probably do your second function as a userPostInstallTrigger rather than a userMenuTrigger (this is the fourth argument for deRegUserTriggers()). The code would not create and return a new pulldown menu, but instead modify the existing pulldown menu. So something like this (note this is just typed in and not tested at all):

;;; Procedure for the STM Macro! This is for optional macros.
procedure( sstSTMAddLayoutEditorMacroMenuItem( _args )
     let( ( item3 )
        ; only add the new item if it is not there already
        when( boundp( 'sstMacroMenu ) && !sstMacroMenu->item3
            item3=hiCreateMenuItem(
                        ?name 'item3
                        ?itemText "My Third Item"
                        ?callback "printf( \"Option 3 clicked...\n\" )"
                    )           
            hiAddMenuItem(sstMacroMenu item3)           
        ) ;;; end of when
    ) ;;; end of let
) ;;; end of procedure sstSTMAddLayoutEditorMacroMenuItem

deRegUserTriggers( "maskLayout" nil nil 'sstSTMAddLayoutEditorMacroMenuItem )

Regards,

Andrew.

Hi Andrew,

Thank you for the quick response. And thank you for the perfect answer. It works like a charm. Bit embarrassing though that I did not find that procedure myself (the hiAddMenuItem one). And the code you wrote (without testing it yourself) worked straight out of the box.

With kind regards,

Sjoerd

ps: I assigned a bind-key to the same call-back procedure and the menu item gets this bind-key printed next to it, automatically. Very neat!