Skill form to browse text file, select and view

Hi Sandeep,

The key to this could be the ddsFileBrowseCB() function, but here's a fully working example:

procedure(CCFviewFile()
  let( (fileName selectFile viewFile form)
    fileName = hiCreateStringField(
      ?name             'fileName
      ?prompt           "File to View"
    )
    selectFile = hiCreateButton(
      ?name             'selectFile
      ?buttonText       "Select File"
      ?callback         "ddsFileBrowseCB(hiGetCurrentForm() 'fileName)"
    )
    viewFile = hiCreateButton(
      ?name             'viewFile
      ?buttonText       "View File"
      ?callback         "view(hiGetCurrentForm()->fileName->value)"
    )
    form = hiCreateAppForm(
      ?name             'CCFviewFileForm
      ?formTitle        "Select file to view"
      ?buttonLayout     'OKCancel
      ?fields           list(
        list(fileName   0:0 400:hicLineHeight   100)
        list(selectFile 100:hicLineHeight 100:hicLineHeight)
        list(viewFile   100:hicLineHeight*2 100:hicLineHeight)
      )
    )
    hiDisplayForm(form)
  ); let
); procedure CCFviewFile

Load the code and invoke using "CCFviewFile()"

Hopefully this is what you were looking for?

Best regards,

Lawrence.

Hi Sandeep,

Ok, here's a different approach, "one button to do it all" - reminds me of Lord Of The Rings ;-)

procedure(CCFviewFile()
  let( (selectFile form)
    selectFile = hiCreateButton(
      ?name             'selectFile
      ?buttonText       "Select File"
      ?callback         strcat("hiDisplayFileDialog(?dialogName 'CCFselectFile"
        " ?mode 'existingFiles ?caption \"Select one or more files\""
        " ?callback \"CCFviewFileCB\")")
    )
    selectFile->hiToolTip = "Browse for file(s) to view"
    form = hiCreateAppForm(
      ?name             'CCFviewFileForm
      ?formTitle        "Select files to view"
      ?buttonLayout     'OKCancel
      ?fields           list(list(selectFile 0:0 100:hicLineHeight))
    )
    hiDisplayForm(form)
  ); let
); procedure CCFviewFile

procedure(CCFviewFileCB(dialog event)
  when(event=='done
    foreach(file hiFileDialogSelection(dialog)
      when(isFile(buildString(file "/")) view(buildString(file "/")) )
    ); foreach
  ); when
); procedure CCFviewFileCB

This uses the hiDisplayFileDialog() function to allow one or more files to be selected and the callback is invoked from the file selection dialog Open button - the callback handles the viewing of each file.

Best regards,

Lawrence.