Width dependent rows of subrectangels for rodCreatePath

Bernd,

There's a PCR asking for this, but for now you have to create the multiple rows yourself.

Regards,

Andrew.

Andrew,

I knew about the PCR, but I thought someone out there
could already have a solution for this, but it seems not.

I'm close to be ready with my solution for it, if it's done
I'll attach the code to this thread.

Cheers Bernd

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;; Disclaimer : NO WARRANTY, this SKILL function(s) is(are) released
;; without any warranty. The Author does not warrant,
;; guarantee, or make any representations regarding the
;; use, or the results of use of this SKILL function(s).
;; The entire risk of the use of this SKILL function(s)
;; is with you.
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;; File Name : createSubRectList.il
;;
;; Function(s) : BFcreateSubRectList
;;
;; Author : Bernd Fischer
;;
;; Date : Tue. 4. June 2006
;;
;; Version : 1.0
;;
;; Application : Virtuoso/Virtuoso XL
;;
;; SW Release : 5.1.41 and higher
;;
;; SKILL Lint : PASSed
;;
;; Global Variable(s) : None
;;
;; Synopsis : BFcreateSubRectList(
;; ?layer l_layerPurposePair
;; ?masterPathWidth n_masterPathWidth
;; ?subRectWidth n_subRectWidth
;; ?subRectSpace n_subRectSpace
;; ?beginOffset n_beginOffset
;; ?endOffset n_endOffset
;; ?sideOffset n_sideOffset
;; )
;;
;; Description : This function creates a list or lists of subrectangle
;; arguments for the 'rodCreatePath' function.
;; It gives the rodCreatePath function the ability to create
;; multiple rows of subrectangels depending on the with of
;; the master path.
;; It can be called directly as value for l_subRect of
;; rodCreatePath or used in context with a variable which
;; holds the l_subRect value.
;;
;; Arguments : txl_layer Text string, integer, or list
;; specifying the layer or layer
;; purpose pair for the sub
;; rectangles.
;; n_masterPathWidth Positive integer or floating
;; point number specifying the
;; width of the master path.
;; n_subRectWidth Positive integer or floating
;; point number specifying the
;; width of the sub rectangles.
;; n_subRectSpace Positive integer or floating
;; point number specifying the
;; spacing between the sub
;; rectangles.
;; n_beginOffset Signed integer or floating
;; point number specifying the
;; offset of the edge of the first
;; subrectangle from the starting
;; edge of the master path.
;; n_endOffset Signed integer or floating
;; point number specifying the
;; offset of the edge of the first
;; subrectangle from the starting
;; edge of the master path.
;; n_sideOffset Signed integer or floating
;; point number specifying the
;; offset along the edges of the
;; master path to edges of the
;; most right and left subrectangle
;; row.
;;
;; Return Value : l_subRectList
;;
;; Example : rodCreatePath(
;; ...
;; ?subRect BFcreateSubRectList(...)
;; )
;; or
;; l_subRect = BFcreateSubRectList(...)
;; rodCreatePath(
;; ...
;; ?subRect l_subRect
;; )
;; Modification : None
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

procedure( BFcreateSubRectList(
@key
layer
masterPathWidth
subRectWidth
subRectSpace
beginOffset
endOffset
sideOffset
)
let( ( l_subRectList f_numOfRows x_numOfRows
f_variableSubRectSpace f_separation
)


;; differentiation if one or more than one contact can be placed
;; then calculate number of rows as float
if( masterPathWidth <= ( 2 * sideOffset + subRectWidth ) then
f_numOfRows = ( masterPathWidth - ( 2 * sideOffset ) ) / subRectWidth
else
f_numOfRows = ( masterPathWidth - ( 2 * sideOffset ) + subRectSpace ) /
( subRectWidth + subRectSpace )
)

;; conversion of number of rows form float to integer
if( ( ( round( f_numOfRows ) - f_numOfRows ) < 0.001 ) then
x_numOfRows = round( f_numOfRows )
else
x_numOfRows = fix( f_numOfRows )
)

;; algorithm to calculate variable subrectangle spacing
;; to align subrectangels fix on enclosure with variable spacing
unless( onep( x_numOfRows )
f_variableSubRectSpace = ( masterPathWidth - ( 2 * sideOffset ) -
( x_numOfRows * subRectWidth ) ) /
( x_numOfRows - 1 )
)

;; create list of subrectangle arguments
cond(
( onep( x_numOfRows )
l_subRectList = cons(
list(
?layer layer
?width subRectWidth
?length subRectWidth
?space subRectSpace
?beginOffset beginOffset
?endOffset endOffset
?justification 'center
)
l_subRectList
) ;; close cons
)
( t
for( j 1 x_numOfRows
f_separation = ( ( j - 1 ) * ( f_variableSubRectSpace + subRectWidth ) ) +
( subRectWidth * 0.5 ) + sideOffset -
( masterPathWidth * 0.5 )
l_subRectList = cons(
list(
?layer layer
?width subRectWidth
?length subRectWidth
?space subRectSpace
?beginOffset beginOffset
?endOffset endOffset
?sep -f_separation
?justification 'center
)
l_subRectList
) ;; close cons
) ;; close for
)
) ;; close cond


l_subRectList

) ;; close let

) ;; close BFcreateSubRectList

It seems that somehow the formatting get lost while posting code, worse option?
Some idea why?

Bernd