Creating a Form to create libraries, import GDS

It may be something in the tcLoadTechFile evaluation. Put a print statement before and after the line to see if the function completes. You can also set your stacktrace to a number greater than 0 and the error will print out with more information.

Try editing the function in the SKILL IDE, it will stop at the line giving you an error.

The error may be in your technology file. Try loading the techfile manually to see if it is valid.

Hi theopaone,

Thank you for the reply. The tcLoadTechFile evaluation is working fine. The problem was with the names of the logFile and summaryFile. I hardcoded both of them as below and it worked fine.

procedure(abImportGDS()
    let((libName libPath techName tfId tfId1 tfId2 GDSName maskLib maskStrLib template ipcId logFile summaryFile)
        libName = abInputForm->inpLibName->value
        libPath = "./"
        techName = abInputForm->techFile->value
        template = "./xstreamInp.temp"
        GDSName = abInputForm->inpGds->value
        maskLib = abInputForm->maskLibName->value
        maskStrLib = abInputForm->maskStrLibName->value
       
        when( ddCreateLib(libName libPath)
            tfId = techOpenTechFile(libName techGetDefaultTechName() "w")
            ;;printf("Tech file is loading")
            tcLoadTechFile(tfId techName)
            ;;printf("TechFile is loaded")
            techSaveTechFile(tfId)
            techCloseTechFile(tfId)
            
            xstInSetField("templateFile" template)
            xstInSetField("techFile" techName)
            xstInSetField("library" libName)
            xstInSetField("strmFile" GDSName)
            xstInSetField("logFile" "libName.log")
            xstInSetField("summaryFile" "libName.sum")
            xstInDoTranslate()
                     
            procedure(xstInOnCompletion(libName)
                    printf ("The GDS has been translated")

                )
            );when
   

But I want to pass the library name to the logFile and summaryFile so that it gets saved as the libName.log and libName.sum. How can I do that?

Thanks & Regards,

Abhishek

Hi Abhishek,

Since you already have the library name in a variable, something like the following should work:

            xstInSetField("logFile" strcat(libName ".log"))
            xstInSetField("summaryFile" strcat(libName ".sum"))

You probably should first check that the the field is not empty (using !blankstrp(libName), for example).

Hope this helps!

Lawrence.

Thanks Lawrence! I did figure out after going through some documentation and made following changes. :)

procedure(abImportGDS()
    let((libName libPath techName tfId tfId1 tfId2 GDSName maskLib maskStrLib template ipcId logFile summaryFile)
        libName = abInputForm->inpLibName->value
        libPath = "./"
        techName = abInputForm->techFile->value
        template = "./xstreamInp.temp"
        GDSName = abInputForm->inpGds->value
        maskLib = abInputForm->maskLibName->value
        maskStrLib = abInputForm->maskStrLibName->value
        logFile = strcat(libName ".log")
        summaryFile = strcat(libName ".sum")
        when( ddCreateLib(libName libPath)
            tfId = techOpenTechFile(libName techGetDefaultTechName() "w")
            tcLoadTechFile(tfId techName)
            techSaveTechFile(tfId)
            techCloseTechFile(tfId)
            
            xstInSetField("templateFile" template)
            xstInSetField("techFile" techName)
            xstInSetField("library" libName)
            xstInSetField("strmFile" GDSName)
            xstInSetField("logFile" logFile)
            xstInSetField("summaryFile" summaryFile)
            xstInDoTranslate()
          

Thanks for your help. I will come back if I face more issues.

By the way, I would advise you not to use the prefix "ab" for your code. The recommendation is for customer code to use an uppercase prefix (to avoid clashing with anything that Cadence produces). I tend to use "ab" for my code (the initials of my first and last name) for long and historical reasons, and so using "ab" as a prefix is likely to confuse people into thinking the code came from me - which in this case it didn't).

Regards,

Andrew.

Dear Andrew,

Thank you... I will keep that in mind.

I still have one question. Callback is executed everytime I enter the maskStrLibName or destViewName. But nothing happens when I press "Apply" or "Ok" button in the form.

Below is the code:

/***************************************************************
*                                                              *
*                       avCreateForm()                         *
*                                                              *
*                     Create the main form                     *
*                                                              *
***************************************************************/
procedure(avCreateForm()
    let((techFile browsetf tfView inpLibName inpGds browseInp sep1 maskLibName maskStrLibName sep2 
     destLibName destCellName destViewName sourceLibName sourceCellName sourceViewName sourceBrowse rotation)
 
 ; techfile browsing and viewing
 
 techFile=hiCreateStringField(
  ?name 'techFile
  ?prompt "Tech File"
  ;;?callback "avImportGDS()"
  )
 
 browsetf=hiCreateButton(
  ?name 'browsetf
  ?buttonText "Browse"
  ?callback "avTechfileBrowseCB()"
  )
 
 tfView=hiCreateButton(
  ?name 'tfView
  ?buttonText "View"
  ?callback "avViewTech()"
  )
 
 ;Input Library and streaming Input GDS
 
 inpLibName=hiCreateStringField(
  ?name 'inpLibName
  ?prompt "Input GDS Library Name"
  ;;?callback "avImportGDS()"
  )
 
 inpGds=hiCreateStringField(
  ?name 'inpGds
  ?prompt "Input GDS to stream"
  ;;?callback "avImportGDS()"
  )
 
 browseInp=hiCreateButton(
  ?name 'browseInp
  ?buttonText "Browse"
  ?callback "avGDSFileBrowseCB()"
  )
 
 sep1=hiCreateSeparatorField(?name 'sep1)
 
 ;Mask Design Library and Mask Structures Library
 
 maskLibName=hiCreateStringField(
  ?name 'maskLibName
  ?prompt "Mask Library Name"
  ;;?callback "avImportGDS()"
  )
 
 maskStrLibName=hiCreateStringField(
  ?name 'maskStrLibName
  ?prompt "Mask Structures Library Name"
  ?callback "avImportGDS()"
  )
 
 sep2=hiCreateSeparatorField(?name 'sep2)
 
 ;Cellview creation and browsing an instance from source library
 
 destLibName=hiCreateStringField(
  ?name 'destLibName
  ?prompt "Enter Library Name"
  ;;?callback "avCreateInst()"
  )
  
 destCellName=hiCreateStringField(
  ?name 'destCellName
  ?prompt "Enter Cell Name"
  ;;?callback "avCreateInst()"
  )
  
 destViewName=hiCreateStringField(
  ?name 'destViewName
  ?prompt "Enter View Name"
  ?callback "avCreateInst()"
  )
 
 sourceLibName=hiCreateStringField(
  ?name 'sourceLibName
  ?prompt "Source Library Name"
  ?callback "ddsUpdateSyncWithForm()"
  )
  
 sourceCellName=hiCreateStringField(
  ?name 'sourceCellName
  ?prompt "Source Cell Name"
  ?callback "ddsUpdateSyncWithForm()"
  )
  
 sourceViewName=hiCreateStringField(
  ?name 'sourceViewName
  ?prompt "Source View Name"
  ?callback "ddsUpdateSyncWithForm()"
  )
  
 sourceBrowse=hiCreateButton(
  ?name 'sourceBrowse
  ?buttonText "Browse"
  ?callback "avSyncBrowser()"
  )
  
 rotation=hiCreateRadioField(
  ?name 'rotation
  ?prompt "Rotation"
  ?choices list("R0" "R90" "R180" "R270" "MY" "MYR90" "MX" "MXR90")
  ?value "R0"
  ;;?callback list("avRotationButtonCB()")
  )
  
 hiCreateAppForm(
  ?name 'avInputForm
  ?formTitle "Input Information Form"
  ?fields
   list(
    list(techFile 0:0 450:30 200)
    list(browsetf 450:5 60:25)
    list(tfView 520:5 50:25)
    list(inpLibName 0:30 500:30 200)
    list(inpGds 0:60 500:30 200)
    list(browseInp 500:65 60:25)
    list(sep1 0:95 600:0)
    list(maskLibName 0:100 600:30 200)
    list(maskStrLibName 0:130 600:30 200)
    list(sep2 0:165 600:0)
    list(destLibName 0:170 600:30 200)
    list(destCellName 0:200 600:30 200)
    list(destViewName 0:230 600:30 200)
    list(sourceLibName 0:260 600:30 200)
    list(sourceCellName 0:290 600:30 200)
    list(sourceViewName 0:320 600:30 200)
    list(sourceBrowse 200:350 60:25)
    list(rotation 0:380 600:0 200)
    )
   )
  
  );let
 );procedure

/***************************************************************
*                                                              *
*                      avTechfileBrowseCB()                    *
*                                                              *
*                     Browsing the Tech File                   *
*                                                              *
***************************************************************/
procedure(avTechfileBrowseCB()
    ddsFileBrowseCB(
 avInputForm
 'techFile
 "*.tf"
 'browsetf
 )
    );procedure
   
   
/***************************************************************
*                                                              *
*                         avViewTech()                         *
*                                                              *
*                     Viewing the Tech File                    *
*                                                              *
***************************************************************/
procedure(avViewTech()
    view(
 avInputForm->techFile->value
 )
    );procedure
   

/***************************************************************
*                                                              *
*                      avGDSFileBrowseCB()                     *
*                                                              *
*                     Browsing the Input GDS                   *
*                                                              *
***************************************************************/
procedure(avGDSFileBrowseCB()
    ddsFileBrowseCB(
 avInputForm
 'inpGds
 "*.gds"
 'browseInp
 )
    );procedure

/***************************************************************
*                                                              *
*                      avSyncBrowser()                         *
*                                                              *
*                 Synchronise with the browser                 *
*                                                              *
***************************************************************/
procedure(avSyncBrowser()
    ddsSyncWithForm(
 avInputForm
 'sourceBrowse
 'sourceLibName
 'sourceCellName
 'sourceViewName
 )
    );procedure

/***************************************************************
*                                                              *
*                        avImportGDS()                         *
*                                                              *
*                  Import the GDS into Library                 *
*                                                              *
***************************************************************/
procedure(avImportGDS()
 let((libName libPath techName tfId tfId1 tfId2 GDSName maskLib maskStrLib template ipcId logFile summaryFile)
  ;avInputForm->inCallback = t
  libName = avInputForm->inpLibName->value
  libPath = "./"
  techName = avInputForm->techFile->value
  template = "./xstreamInp.temp"
  GDSName = avInputForm->inpGds->value
  maskLib = avInputForm->maskLibName->value
  maskStrLib = avInputForm->maskStrLibName->value
  logFile = strcat(libName ".log")
  summaryFile = strcat(libName ".sum")
  when( ddCreateLib(libName libPath)
   tfId = techOpenTechFile(libName techGetDefaultTechName() "w")
   tcLoadTechFile(tfId techName)
   techSaveTechFile(tfId)
   techCloseTechFile(tfId)
   
   xstInSetField("templateFile" template)
   xstInSetField("techFile" techName)
   xstInSetField("library" libName)
   xstInSetField("strmFile" GDSName)
   xstInSetField("logFile" logFile)
   xstInSetField("summaryFile" summaryFile)
   xstInDoTranslate()
   ;;ipcId = ipcBeginProcess(xstInDoTranslate())
   ;;ipcWait(ipcId)
   
   
   procedure(xstInOnCompletion(libName)
        printf ("The GDS has been translated")

    )
   );when
  when( ddCreateLib(maskLib libPath)
   tfId1 = techOpenTechFile(maskLib techGetDefaultTechName() "w")
   tcLoadTechFile(tfId1 techName)
   techSaveTechFile(tfId1)
   techCloseTechFile(tfId1)
   
   );when
   
  when( ddCreateLib(maskStrLib libPath)
   tfId2 = techOpenTechFile(maskStrLib techGetDefaultTechName() "w")
   tcLoadTechFile(tfId2 techName)
   techSaveTechFile(tfId2)
   techCloseTechFile(tfId2)
   
   );when
  ;avInputForm->inCallback = nil 
  ;t 
  );let
);procedure

/***************************************************************
*                                                              *
*                        avCreateInst()                        *
*                                                              *
*                  Create Instance and Export GDS              *
*                                                              *
***************************************************************/
procedure(avCreateInst()
 let((sourceLib sourceCell sourceView destLib destCell destView rotate cv cv1 template techName)
  ;avInputForm->inCallback = t
  sourceLib = avInputForm->sourceLibName->value
  sourceCell = avInputForm->sourceCellName->value
  sourceView = avInputForm->sourceViewName->value
  destLib = avInputForm->destLibName->value
  destCell = avInputForm->destCellName->value
  destView = avInputForm->destViewName->value
  rotate = avInputForm->rotation->value
  template = "./xstreamOut.temp"
  techName = avInputForm->techFile->value
  
  cv = dbOpenCellViewByType(destLib destCell destView "maskLayout" "w")
  cv1 = dbOpenCellViewByType(sourceLib sourceCell sourceView)
  dbCreateInst( cv cv1 "I0" 0:0 rotate)
  dbClose(cv1)
  dbSave(cv)
  
  xstSetField("templateFile" template)
  xstSetField("techFile" techName)
  xstSetField("library" destLib)
  xstSetField("topCell" destCell)
  xstSetField("viewName" destView)
  xstSetField("strmFile" strcat("../cd_ws/" destCell ".gds"))
  xstSetField("logFile" strcat("../cd_ws/" destCell ".log"))
  xstSetField("summaryFile" strcat("../cd_ws/" destCell ".sum"))
  xstOutDoTranslate()
  dbClose(cv)
  ;avInputForm->inCallback = nil
  ;t
  );let
 );procedure

/***************************************************************
*                                                              *
*                        avInput()                             *
*                                                              *
*                       Main entry point                       *
*                                                              *
***************************************************************/

procedure(avInput()
    unless(boundp('avInputForm)
 avCreateForm()
 )
 
    hiDisplayForm(avInputForm)
    t
  
    );procedure

Best Regards,

Abhishek

Abhishek,

Abhishek Verma said:

I still have one question. Callback is executed everytime I enter the maskStrLibName or destViewName. But nothing happens when I press "Apply" or "Ok" button in the form.

Now you're using "av" which is the prefix used for Assura! As I said, you should use an uppercase prefix (so "AV" or "Av" would be fine).

The reason why you have no action on OK or Apply is that you have not specified ?callback in the hiCreateAppForm call - this defines the form callback. Instead, you have added field callbacks on some of the fields which is executing the avImportGDS function, which I rather doubt is the behaviour you want. Field callbacks get triggered each time you move the focus out of the field - and are usually used to either validate the field, or set the value of one field dependent upon another - they're not normally used to trigger the functionality which would normally fire on OK or Apply...

Regards,

Andrew.

Dear Andrew,

I have corrected the prefix to uppercase now.

Also the callback is corrected in the hiCreateAppForm call. Thank you for the help.

Best Regards,

Abhishek