How to get the schematic(TestBench) details associated with a adexl

Hi Manikandan,

This code will do it (the first function). It returns a list of lists, one per test in the ADE XL view (because they could have different testbenches):

/* abGetADEXLReferences.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Nov 21, 2012 
Modified   A.D.Beckett 
By         Nov 22, 2012 

Return a list of all the references in an ADE XL view.
Also provide a function to check if the ADE XL view
only references testbenches from the same library.

***************************************************

SCCS Info: @(#) abGetADEXLReferences.il 11/22/12.11:18:56 1.2

*/

/***************************************************************
*                                                              *
*             abGetADEXLReferences(lib cell view)              *
*                                                              *
*  Return a list of lib/cell/view lists. Each one corresponds  *
*     to the lib/cell/view used in the tests in the adexl      *
*  view. It doesn't try to uniquify the list, so if the same   *
*   testbench is used in multiple tests, it will be returned   *
*                       multiple times.                        *
*                                                              *
***************************************************************/

procedure(abGetADEXLReferences(lib cell view)
    let((sess sdb references toolArgs)
        sess=axlCreateSession(strcat("refs" getCurrentTime()))
        sdb=axlSetMainSetupDBLCV(sess lib cell view)
        when(sdb
            references=
                foreach(mapcar testName cadr(axlGetTests(sdb))
                    toolArgs=axlGetTestToolArgs(axlGetTest(sdb testName))
                    list(
                        cadr(assoc("lib" toolArgs))
                        cadr(assoc("cell" toolArgs))
                        cadr(assoc("view" toolArgs))
                    )
                )
            axlCloseSetupDB(sdb)
        )
        axlCloseSession(sess)
        references
    )
)

/***************************************************************
*                                                              *
*         abAreADEXLReferencesToSameLib(lib cell view)         *
*                                                              *
*    Simple check on an ADE XL view to return t if all the     *
*  testbenches come from the same library as the ADE XL view   *
*                           itself.                            *
*                                                              *
***************************************************************/

procedure(abAreADEXLReferencesToSameLib(lib cell view)
    forall(lcv abGetADEXLReferences(lib cell view)
        car(lcv)==lib
    )
)

/***************************************************************
*                                                              *
* abCheckADEXLReferencesToSameLibForLib(lib @optional verbose) *
*                                                              *
*       Check all the ADE XL views in the library to see       *
*        if they have references outside this library.         *
*                                                              *
***************************************************************/

procedure(abCheckADEXLReferencesToSameLibForLib(lib @optional verbose)
    let((fileObj references popups (nullport outfile("/dev/null")))
        ;----------------------------------------------------------------
        ; Suppress the convert state popups
        ;----------------------------------------------------------------
        popups=envGetVal("asimenv" "showConvertNotifyDialog")
        envSetVal("asimenv" "showConvertNotifyDialog" 'boolean nil)
        ;----------------------------------------------------------------
        ; attempt to swallow warnings and errors by redirecting
        ; using dynamic scoping
        ;----------------------------------------------------------------
        let(((woport nullport) (errport nullport))
            foreach(cell ddGetObj(lib)~>cells
                foreach(view cell~>views
                    fileObj=ddGetObj(lib cell~>name view~>name "*")
                    when(fileObj && ddMapGetFileViewType(fileObj)=="adexl"
                        when(verbose
                            printf("Checking %s/%s/%s\n" lib cell~>name 
                                view~>name)
                        )
                        references=abGetADEXLReferences(
                            lib cell~>name view~>name)
                        when(exists(lcv references car(lcv)!=lib)
                            printf("%s/%s/%s has references to %L\n"
                                lib cell~>name view~>name
                                setof(lcv references car(lcv)!=lib)
                            )
                        )
                    )
                )
            )
        )
        close(nullport)
        when(popups
            envSetVal("asimenv" "showConvertNotifyDialog" 'boolean t)
        )
        t
    )
)

Regards,

Andrew