Add Toolbar in CIW window?

Inside a file (I call mine ciw.il) put:

test = hiCreateMenuItem(
        ?name   'assignments
        ?itemText       "assignments"
        ?callback       "load(\"/proj/projects/workarea/skill_work/assignment.il\")"
        )

hiCreatePulldownMenu(
       'ciw1
        "MyStuff" list( assignments )
        ""
        )

hiInsertBannerMenu(hiGetCIWindow() ciw1 7)

in your cdsinit (or where you put things to automatically load) add:

load("/proj/projects/workarea/skill_work/ciw.il")

When start cadence you should have a MyStuff menu at the 7th position.  The 7th position is my default last spot on the CIW before help menu, yours may vary.

Alternatively, you can just assign a bindkey and load it with that:

hiSetBindKey("Layout" "<Key>F6" "load(\"/proj/projects/workarea/skill_work/assignment.il\")")

Hope this helps,

Dan

How about this (to show how to create toolbars - this is a very simple example)?

Regards,

Andrew

/* CCFloadFile.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Apr 27, 2016 
Modified   
By         

Example of creating a toolbar in the CIW.

Call:

CCFplaceLoadFileToolbar()

to add it to the top of the CIW.

***************************************************

SCCS Info: @(#) CCFloadFile.il 04/27/16.11:33:18 1.1

*/

procedure(CCFcreateLoadFileToolbar()
  let((fileName load)
    fileName=hiCreateToolbarTypein(
      ?name 'fileName
      ?prompt "File"
      ?width 400
      ; doesn't seem to work if just hit return...
      ?CBOnEnter "CCFloadFileFromToolbar()"
    )
    load=hiCreateAction(
      ?name 'load
      ?iconText "Load"
      ?callback "CCFloadFileFromToolbar()"
    )
    CCFloadToolbar=hiCreateToolbar(
      ?name 'CCFloadToolbar
      ?title "Load SKILL"
      ?items list(fileName load)
    )
  )
)

procedure(CCFloadFileFromToolbar()
  loadi(CCFloadToolbar->fileName->value)
)

procedure(CCFplaceLoadFileToolbar(@optional (win hiGetCIWindow()))
  unless(boundp('CCFloadToolbar)
    CCFcreateLoadFileToolbar()
  )
  hiPlaceToolbar(win CCFloadToolbar 'top)
)