Hooks in to ADE-XL spec summary and datasheet creation

Hi, Dan Mcmahill

Below is a procedure I made to get the Corner Setup in the ADE-XL.

I hope it would be helpful to you.

The code in red, is used to check whether the model file is selected/enabled in the corner.

;*********************************************************************
; PROCEDURE NAME:  printTestCorInfo
;
; ABSTRACT :
;   print the enabled corner info of the corresponding test, except the norminal corner
;
; AGURMENTS :
;   myFileID                output file ID
;   testSession             session object of the corresponding test
;   sdbh                    adexl session database handle
;   enCor                   enabled corner for the corresponding test                   
;
; RETURN VALUE :
;   none
;
; UPDATES :
;   date:   July 27 2015    Prepared: Yi WANG
;*********************************************************************
procedure(printTestCorInfo(myFileID testSession sdbh enCor test)
let(
(
    cornerHd    ;handle of the corner
    cVarList    ;list of variables used in corner
    cVarVal        ;value of the variable
    modelList    ;list of the used model
    enVarList    ;list of enabled variable
    tVarList    ;list of test variables
    gVarList    ;list of global variables
    gVarHd        ;handle of global variable
    tVarName    ;name of the test variable
    modelHd    ;handle of the model
    modelSecList    ;list of sections for the model
    modelSel    ;change to "t", if one model file has been selected
)
    ;get the corner handle, base on the corner name
    cornerHd = axlGetCorner(sdbh enCor)
    ;get the model list which is used in the corner
    modelList = cadr(axlGetModels(cornerHd))
    ;get the variables which are used in the corner
    cVarList = cadr(axlGetVars(cornerHd))
    ;set the initial value of the list which contains the used variable.
    enVarList = nil
    ;set the initial value of the marker to be nil, which indicate there is no model has been used in the corner.
    modelSel = nil

    ;check whether one of the model file has been selected
    foreach(modelFile modelList
        modelHd = axlGetModel(cornerHd modelFile)
        modelSel = or(modelSel axlGetEnabled(modelHd))
    );foreach

    
    if(modelSel then ; if one of the model file has been used in the corner, then print then enalbed one
        foreach(modelFile modelList ;travel through the model file list
            modelHd = axlGetModel(cornerHd modelFile)        
            when(axlGetEnabled(modelHd)  ;when the model file is specified in the corner setup
                modelSecList = parseString(axlGetModelSection(modelHd) "\"") ;get and parse the model section list.
                fprintf(myFileID "\t Model path:   \t%L (C)\n" axlGetModelFile(modelHd)); print out the model file
                fprintf(myFileID "\t Model sections:    \t")
                foreach(modelSec modelSecList
                    fprintf(myFileID "%s " modelSec); print out the model file section.
                );foreach
                fprintf(myFileID "\n")
            );when
        );foreach
    else ; if none of the model file has been selected in the corner, print the setup in the ADEL.
        modelList = asiGetModelLibSelectionList( testSession ); get the model file used in the design
        foreach(modelFile modelList ;travel through the model list.
            modelSecList = cdr(modelFile)   ;get the model section list
            fprintf(myFileID "\t Model path:   \t%L (L)\n" car(modelFile)); print out the model file
            when(car(modelSecList)!= "" ; if there is model section has been defined.
                fprintf(myFileID "\t Model sections are \t")
                foreach(modelSec modelSecList
                    fprintf(myFileID "%s \n" modelSec); print out the model file
                );foreach
            );when           
        );foreach
    );if


    ;print the variable defined in corners
    foreach(cVar cVarList   ;travel the corner variable list
        gVarHd = axlGetVar(cornerHd cVar)   ;get the handle of the variable by name
        cVarVal = axlGetVarValue(gVarHd)    ;get the value of the variable.
        when(cVar == "temperature" cVar="temp")     ;change "temperature" to "temp"
        fprintf(myFileID "\t %s:\t\t%s\t(C)\n" cVar cVarVal); print out the enabled test varirable
        enVarList =cons(cVar enVarList) ;add the variable to the "enVarList"
    );foreach
    ;print the extra variable defined in globale variables
    gVarList = cadr(axlGetVars(sdbh))   ;get the global variable list
    unless(axlGetAllVarsDisabled(sdbh)  ;if global variables are enabled.
        foreach(gVar gVarList   ;travel through the global list
            gVarHd = axlGetVar(sdbh gVar)   ;get the handle
            when(axlGetEnabled(gVarHd) && !member(gVar enVarList) && axlGetEnabledGlobalVarPerTest(sdbh gVar test);when the variable is enabled and enabled for the test, and has not been defined in the corner.
                fprintf(myFileID "\t %s:\t\t%s\t(G)\n" gVar axlGetVarValue(gVarHd)); print out the enabled global variable
                enVarList = cons(gVar enVarList)    ;add the variable into the "enVarList"
            );when
        );forearch
    );unless        
    ;print the extra extra variable defined in test    
    tVarList = asiGetDesignVarList(testSession) ;get the variable list defined in the design
    foreach(tVar tVarList ;travel through the design variable list.
        tVarName = car(tVar)    ; the design variable list always contain varialbe pairs (name value)
        unless(member(tVarName enVarList)    ;when the variable is not defined in the corner and global.
            fprintf(myFileID "\t %s:\t\t%s\t(L)\n" tVarName cadr(tVar)); print out the enabled test varirable
        );unless
    );foreach    

);let
);procedure printTestCorInfo

Best Regards

Yi