Stats

  • Locked Locked
  • Replies 5
  • Subscribers 143
  • Views 14092
  • Members are here 0
This discussion has been locked.
You can no longer post new replies to this discussion. If you have a question you can start a new discussion

General about skill scripting

Inas Mohammed

I'm using an if condition for gate routing positioning. The code runs without error but the gates are not placed. so please can you tell me why is this happening? you can find it highlighted in yellow

procedure(place_devices(cellView devLib devCell Length nfunit wfunit DUM1nf DUM1wf DUM2nf DUM2wf yPitch pattern)
let((params array nRows nCols Type dev name nf wf inst devCounts x y xPitch (x0 0.0) (y0 0.0))

devCounts=makeTable('DEVCOUNT 0)
array = listToVector(foreach(mapcar row reverse(pattern) listToVector(parseString(row " "))))
nRows=length(pattern)
y=y0
for(row 0 nRows-1
x=x0
nCols=length(array[row])
for(col 0 nCols-1
dev=array[row][col]
devCounts[dev]++
name=sprintf(nil "%s.%d" dev devCounts[dev])
Type=cond(
(eq('M getchar(array[row][col] 1)) 'device)
(zerop(row) && (zerop(col) || (col == nCols-1)) 'corner)
(zerop(col) && (zerop(row) || (row == nRows-1)) 'corner)
(zerop(row) || (row == nRows-1) 'topBottom)
(zerop(col) || (col == nCols-1) 'leftRight)
(t 'dummy)
)
caseq(Type
((device dummy)
nf=nfunit
wf=wfunit
)

(corner
nf=DUM1nf
wf=DUM2wf
)

(topBottom
nf=DUM2nf
wf=DUM2wf
)

(leftRight
nf=DUM1nf
wf=DUM1wf
)

(t error("type=%l\n" Type)
)
)

params = list(
list("l" "string" aelSuffixNotation(1u * Length))
list("w" "string" aelSuffixNotation(1u * wf))
list("fingers" "string" sprintf(nil "%d" nf))
if(oddp(row)
then
list("routePolydir" "string" "Bottom")
list("polyContacts" "string" "True")
else
list("routePolydir" "string" "Top")
list("polyContacts" "string" "True")
)
) ; params

when(zerop(col)
; Device is on left edge. Add detached bodytie.
params = xcons(params
list("bodytie_type" "string" "Detached"))
)

when(col == nCols-1
; Device is on right edge. Add detached bodytie.
params = xcons(params
list("bodytie_typeR" "string" "Detached"))
)

inst=dbCreateParamInstByMasterName(cellView devLib devCell "layout" name x:y "R0" 1 params)
xPitch = (nf * Length) + (nf * 0.2)

;; TODO: Replace numbers with space/extension params
;; Or, use rodGetObj and/or M1 geometry of the
;; inst->master cellView to calculate the xPitch
;; of the instantiated device

;; Calculate x coordinate for next device
x = x + xPitch

)
y = y + yPitch
)
dbSave(geGetEditCellView())

)) ; let ; procedure

place_devices(
geGetEditCellView() ; cellView
"tsmcN65" ; devLib
"pch" ; devCell
0.2 ; Length (um)
4 ; nfunit
3.0 ; wfunit (um)
4 ; DUM1nf
3.0 ; DUM1wf (um)
4 ; DUM2nf
3.0 ; DUM2wf (um)
3.78 ; yPitch (um)
list(
"Du Du Du Du Du"
"Du M1 M2 M1 Du"
"Du M2 M1 M2 Du"
"Du Du Du Du Du"
); pattern (rows)
)

Thanks

Regards

Parents

  • Note it's very hard to debug code (which I can't run, because I don't have any of the data) if it is so poorly formatted - there is no indentation in the code which makes it very hard to read.

    When you say "the gates are not placed" - do you mean that the poly isn't routed on the devices? That's what I'd expect from the code you've posted. In the list of parameters, the if(oddp(row)... part will only return the final list in each of the then and else parts, and so you'd never have routePolyDir set at all. This is the kind of thing where printing out the value of params as a debug statement after setting it would have revealed the problem - a basic debugging technique in any language.

    I'd probably write it this way:

    params = list(
      list("l" "string" aelSuffixNotation(1u * Length))
      list("w" "string" aelSuffixNotation(1u * wf))
      list("fingers" "string" sprintf(nil "%d" nf))
      list("routePolydir" "string" if(oddp(row) "Bottom" "Top"))
      list("polyContacts" "string" "True")
    ) ; params

    I've no idea whether there's anything else wrong in the code - I just focused on the highlighted part (since you highlighted it).

    Regards,

    Andrew.

Reply

  • Note it's very hard to debug code (which I can't run, because I don't have any of the data) if it is so poorly formatted - there is no indentation in the code which makes it very hard to read.

    When you say "the gates are not placed" - do you mean that the poly isn't routed on the devices? That's what I'd expect from the code you've posted. In the list of parameters, the if(oddp(row)... part will only return the final list in each of the then and else parts, and so you'd never have routePolyDir set at all. This is the kind of thing where printing out the value of params as a debug statement after setting it would have revealed the problem - a basic debugging technique in any language.

    I'd probably write it this way:

    params = list(
      list("l" "string" aelSuffixNotation(1u * Length))
      list("w" "string" aelSuffixNotation(1u * wf))
      list("fingers" "string" sprintf(nil "%d" nf))
      list("routePolydir" "string" if(oddp(row) "Bottom" "Top"))
      list("polyContacts" "string" "True")
    ) ; params

    I've no idea whether there's anything else wrong in the code - I just focused on the highlighted part (since you highlighted it).

    Regards,

    Andrew.

Children
No Data

Community Guidelines

The Cadence Design Communities support Cadence users and technologists interacting to exchange ideas, news, technical information, and best practices to solve problems and get the most from Cadence technology. The community is open to everyone, and to provide the most value, we require participants to follow our Community Guidelines that facilitate a quality exchange of ideas and information. By accessing, contributing, using or downloading any materials from the site, you agree to be bound by the full Community Guidelines.