User Defined Skill Function - Alias Waveform

A few things:

1. I'd probably avoid using the prefix "ab" as it tends to mean that people see the code and think it came from me (which it didn't here). Use your own initials or a unique prefix for your company.
2. You could potentially do this using a "sampled" pnoise analysis which inserts an ideal sampler in the output of the circuit which would cause the noise to be aliased. 
3. There were a few things that were wrong - you had some parts of the code referencing the wrong waveform, you were using sum() - which isn't a function, and there were odd mistakes here and there. Anyway, I rewrote the code in C-style (probably easier to read if you're not familiar with LISP) and corrected it. I think this is OK now...

/***************************************************************
*                                                              *
*           (abAliasSignal waveform fsample fmin fmax)         *
*                                                              *
* Given a waveform, a sampling freq, and freq range compute    *
*                     the aliased signal.                      *
*                                                              *
***************************************************************/
procedure(abAliasSignal(waveform fsample fmin fmax)
  cond(
    ;---------------------------------------------------------------------
    ; Handle ordinary waveform
    ;---------------------------------------------------------------------
    (drIsWaveform(waveform)
      let((len lastX sourceYVec xVec yVec clippedwave (result 0) resultnew
          nmax)
        ;------------------------------------------------------------------
        ; Clip the signal and alias the signal in the range specified
        ;------------------------------------------------------------------
        clippedwave=clip(waveform fmin fmax)
        xVec=drGetWaveformXVec(clippedwave)
        len=drVectorLength(xVec)
        lastX=drGetElem(xVec sub1(len))
        ; Find the maximum nyquist sideband
        nmax=floor(lastX/(fsample/2.0))
        ; Sum all of the signal of the clipped waveform into 1st nyquist
        for(n 0 nmax-1
          resultnew=
            if(oddp(n) then
              rshift(flip(clip(clippedwave n*fsample/2 (n+1)*fsample/2)) (n+1)*fsample/2)
            else
              lshift(clip(clippedwave n*fsample/2 (n+1)*fsample/2) n*fsample/2)
            )
          result=result+resultnew
        )
        ;------------------------------------------------------------------
        ; Copy units and axis name across from source waveform
        ;------------------------------------------------------------------
        sourceYVec=drGetWaveformYVec(waveform)
        yVec=drGetWaveformYVec(result)
        yVec->units=sourceYVec->units
        yVec->name=sourceYVec->name
        result
        )
      ) ; waveform
    ;---------------------------------------------------------------------
    ; Handle family
    ;---------------------------------------------------------------------
    (famIsFamily(waveform)
      famMap('abAliasSignal waveform fsample fmin fmax)
    ) ; family
    (t
      error("abAliasSignal - can't handle %L\n" waveform)
    )
  ) ; cond
)

Regards,

Andrew.

Thanks for the fixes, Andrew. I will also give the pnoise option a try.

I thought the "ab" was for your initials, but I wasn't sure - I will remove that from the code and update the file later.

--

I can follow your code and everything looks good to me, but when I click on the function in the calculator, no form appears. Did you see anything wrong in the rest of the code?

Hi Michael,

Before I look at that, which IC version are you using? There is an easier way in IC617 which means you don't have to write the form code...

Regards,

Andrew.

It's in the code that builds the form:

You need to not reference "waveform" because that's not known when the form is launched (the errors are suppressed by default - you can re-enable them using sstatus(errsetTrace t)). So I commented these four lines out and made the fmin/fmax values fixed defaults.

(procedure (abCreateAliasSignalForm)
  (let (fsample fmin fmax xVec startfreq endfreq len)
       (setq fsample (ahiCreateStringField
		    ?name 'fsample
		    ?prompt "Sampling Frequency"
		    ?value ""
		    ))
       /*
       (setq xVec (drGetWaveformXVec waveform))
       (setq len drVectorLength(xVec))
       (setq startfreq (drGetElem xVec 0))
       (setq endfreq (drGetElem xVec (sub1 len)))
       */
       (setq fmin (ahiCreateStringField
		    ?name 'fmin
		    ?prompt "Min Freq"
		    ?value "0"
		    ))
       (setq fmax (ahiCreateStringField
		    ?name 'fmax
		    ?prompt "Max Freq"
		    ?value "1G"
		    ))
       (calCreateSpecialFunctionsForm
	'abAliasSignalForm
	(list
 
	  (list fsample 0:0  180:20 90)
	  (list fmin 0:30  180:20 90)
          (list fmax 0:60  180:20 90)
	)
       )
  )
)

Regards,

Andrew.

Thanks, the function works fine now (although formatting on here was more trouble than I expected):

-------------------------------------------------

/* AliasSignal.il

Language   SKILL

Date       Feb 20, 2017

Modified   Mar 27, 2017

By         M.L.Cunningham

Performs an ideal aliasing of a signal. You specify the sampling

frequency, half of which it (effectively) folds down all the signal

into.

; register the AliasSignal() special function with the calculator

RegAliasSignalSpecialFunction()

; example of usage:

AliasSignal ((getData("out" ?result "noise")**2) 2G 1K 100G)

NOTE: It is important that the appropriate signal be passed to the function (i.e. a power quantity).

****************************************************/

/*******************************************************************************

*  DISCLAIMER: The following code is provided for Cadence customers to use at  *

*   their own risk. The code may require modification to satisfy the           *

*   requirements of any user. The code and any modifications to the code may   *

*   not be compatible with current or future versions of Cadence products.     *

*   THE CODE IS PROVIDED "AS IS" AND WITH NO WARRANTIES, INCLUDING WITHOUT     *

*   LIMITATION ANY EXPRESS WARRANTIES OR IMPLIED WARRANTIES OF MERCHANTABILITY *

*   OR FITNESS FOR A PARTICULAR USE.                                           *

*******************************************************************************/

/***************************************************************

*                                                              *

*                 (CreateAliasSignalForm)                      *

*                                                              *

*            Create the form for the aliased signal            *

*                                                              *

***************************************************************/

(procedure (CreateAliasSignalForm)

  (let (fsample fmin fmax xVec startfreq endfreq len)

       (setq fsample (ahiCreateStringField

                  ?name 'fsample

                  ?prompt "Sampling Frequency"

                  ?value ""

                  ))

       (setq fmin (ahiCreateStringField

                  ?name 'fmin

                  ?prompt "Min Freq"

                  ?value "0"

                  ))

       (setq fmax (ahiCreateStringField

                  ?name 'fmax

                  ?prompt "Max Freq"

                  ?value "1G"

                  ))

       (calCreateSpecialFunctionsForm

       'AliasSignalForm

       (list

         (list fsample 0:0  210:20 130)

         (list fmin 0:30  210:20 130)

          (list fmax 0:60  210:20 130)

       )

       )

  )

)

/********************************************************************

*                                                                   *

*                 (AliasSignalSpecialFunctionCB)                    *

*                                                                   *

*  Callback for the alias signal special function, which assembles  *

*                the expression from the form values                *

*                                                                   *

********************************************************************/

(procedure (AliasSignalSpecialFunctionCB)

  (calCreateSpecialFunction

   ?formSym 'AliasSignalForm

   ?formInitProc 'CreateAliasSignalForm

   ?formTitle "Alias Signal"

   ?formCallback "calSpecialFunctionInput( 'AliasSignal '(fsample fmin fmax))"

   ))

/***************************************************************

*                                                              *

*              (RegAliasSignalSpecialFunction)                 *

*                                                              *

*              Register the alias signal function              *

*                                                              *

***************************************************************/

(procedure (RegAliasSignalSpecialFunction)

  (calRegisterSpecialFunction

   (list "AliasSignal" 'AliasSignalSpecialFunctionCB))

  t

  )

/***************************************************************

*                                                              *

*          (AliasSignal waveform fsample fmin fmax)            *

*                                                              *

*   Given a waveform, a sampling freq, and freq range compute  *

*   the aliased signal.                                        *

*                                                              *

***************************************************************/

procedure(AliasSignal(waveform fsample fmin fmax)

 cond(

 ;---------------------------------------------------------------------

 ; Handle ordinary waveform

 ;---------------------------------------------------------------------

 (drIsWaveform(waveform)

   let((len lastX sourceYVec xVec yVec clippedwave (result 0) nyqband nmax)

 ;------------------------------------------------------------------

 ; Clip the signal and alias the signal in the range specified

 ;------------------------------------------------------------------

   clippedwave=clip(waveform fmin fmax)

   xVec=drGetWaveformXVec(clippedwave)

   len=drVectorLength(xVec)

   lastX=drGetElem(xVec sub1(len))

 ; Find the maximum nyquist sideband

   nmax=ceiling(lastX/(fsample/2.0))

 ; Sum all of the signal of the clipped waveform into 1st nyquist

   for(n 0 nmax-1

     nyqband=

   if(oddp(n) then

     rshift(flip(clip(clippedwave n*fsample/2 (n+1)*fsample/2)) (n+1)*fsample/2)

   else

     lshift(clip(clippedwave n*fsample/2 (n+1)*fsample/2) n*fsample/2)

   )

     result=result+nyqband

     result=clip(result fmin fsample/2)

   )

 ;------------------------------------------------------------------

 ; Copy units and axis name across from source waveform

 ;------------------------------------------------------------------

   sourceYVec=drGetWaveformYVec(waveform)

   yVec=drGetWaveformYVec(result)

   yVec->units=sourceYVec->units

   yVec->name=sourceYVec->name result

   )

 ) ; waveform

 ;---------------------------------------------------------------------

 ; Handle family

 ;---------------------------------------------------------------------

 (famIsFamily(waveform)

 famMap('AliasSignal waveform fsample fmin fmax) )

 ; family

 (t

 error("AliasSignal - can't handle %L\n" waveform)

 )

 ) ; cond

)