Creat blockage from polygon?

I threw together a few lines of SKILL to do this:

/* CCFcreateBlockageFromSelection.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Jul 24, 2017 
Modified   
By         

***************************************************

SCCS Info: @(#) CCFcreateBlockageFromSelection.il 07/24/17.17:04:59 1.1

*/

/***************************************************************
*                                                              *
*         CCFcreateBlockageFromSelection(["routing"])          *
*                                                              *
*      Create routing blockages from the selected objects      *
*                                                              *
*                                                              *
***************************************************************/
procedure(CCFcreateBlockageFromSelection(@optional (type "routing"))
  let((points temp)
    foreach(obj geGetSelSet()
      when(obj~>isShape 
        ;----------------------------------------------------------------
        ; Generate points for different source types. For paths
        ; and pathSegs, easiest to copy, convert to polygon and
        ; then use the point list.
        ;----------------------------------------------------------------
        points=
          case(obj~>objType
            ("polygon" obj~>points)
            ("rect"
              destructuringBind(((llx lly) (urx ury)) obj~>bBox
                list(llx:lly urx:lly urx:ury llx:ury)
              ))
            ("path"
              temp=dbCopyFig(obj obj~>cellView)
              temp=dbConvertPathToPolygon(temp)
              prog1(
                temp~>points
                dbDeleteObject(temp)
              )
            )
            ("pathSeg"
              temp=dbCopyFig(obj obj~>cellView)
              temp=dbConvertPathSegToPolygon(temp)
              prog1(
                temp~>points
                dbDeleteObject(temp)
              )
            )
          )
        dbCreateLayerBlockage(
          obj~>cellView
          obj~>layerName
          type
          points
        )
      )
    )
    t
  )
)

Ramakrishnan,

I'm using prog1 (not prog) because I want the return value of each branch in the case function to be the list of points (you'll see the return value is stored in the variable points). Because I need to retrieve the list of points from the temporary object and then delete it, I use prog1 - prog1 executes all the statements in order but the return value is the first statement executed (as opposed to the usual convention of the last thing executed). So here the prog1 returns the list of points and then deletes the object from which it had retrieved the list of points. It avoids needing to use another variable - of course, I could have moved all the points= assignments inside the case statement but I'd already written the part which handled rect and polygon and then thought I probably should add path and pathSeg for completeness.

Regards,

Andrew.

Thanks Andrew. I learnt something here today.

-Ramakrishnan

Thanks Andrew,. for the answer..

Could you please let me know how to use the same proc for creating blockage of type 'placement'  ?

I need to do it in my script..

- Vish

Vish,

In the code above, replace:

        dbCreateLayerBlockage(
          obj~>cellView
          obj~>layerName
          type
          points
        )

with:

        dbCreateAreaBlockage(
          obj~>cellView
          points
        )

Note, I did not test this - it's just from reading the manual!

Regards,

Andrew.