Modulo of a signal? Converting a signal to float?

This will do it. In IC617 you can easily register this with the calculator by hitting the "Fx" button above the function panel in the calculator to load the file and set up the form - or you can just type it in.

Regards,

Andrew

/* abModulo.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Jul 06, 2005 
Modified   Nov 23, 2005 
By         A.D.Beckett

Example use:

plot(abModulo(phaseDegUnwrapped(v("/Pif" ?result "pss_fd"))))

***************************************************

SCCS Info: @(#) abModulo.il 11/23/05.18:05:09 1.2

*/

/***************************************************************
*                                                              *
*          (abModulo waveform @optional (modulo 360))          *
*                                                              *
*       Take a waveform and return a modulus - strictly        *
*     positive. Useful for wrapping phase waveforms to be      *
*               between (say) 0 and 360 degrees.               *
*                                                              *
***************************************************************/

(procedure (abModulo waveform @optional (modulo 360))
  (cond
   ;---------------------------------------------------------------------
   ; Handle ordinary waveform
   ;---------------------------------------------------------------------
   ((drIsWaveform waveform)
    (let (oldyvec newyvec len newwave yval)
         (setq oldyvec (drGetWaveformYVec waveform))
         (setq len (drVectorLength oldyvec))
         (setq newyvec (drCreateVec 'double len))
         ;---------------------------------------------------------------
         ; Iterate over the points, computing the modulus of each point
         ;---------------------------------------------------------------
         (for point 0 (sub1 len)
              (setq yval (drGetElem oldyvec point))
              (setq yval 
                    (difference yval 
                                (times 
                                 (fix (quotient yval modulo))
                                 modulo)))
              (drSetElem newyvec point yval)
              )
         ;---------------------------------------------------------------
         ; Set the expression so the name of the waveform is correct
         ;---------------------------------------------------------------
         (putpropq newyvec 
                   (list 'abModulo (getq oldyvec expression) modulo) expression)
         (setq newwave
               (drCreateWaveform
                (drGetWaveformXVec waveform)
                newyvec
                ))
         ;---------------------------------------------------------------
         ; Inherit the plot style and scale
         ;---------------------------------------------------------------
         (putpropq newwave (getq waveform plotStyle) plotStyle)
         (putpropq newwave (getq waveform plotStyle) xScale)
         newwave
         )
    )
   ;---------------------------------------------------------------------
   ; Family waveforms should be handled OK
   ;---------------------------------------------------------------------
   ((famIsFamily waveform)
    (famMap 'abModulo waveform modulo)
    ) ; family
   ;---------------------------------------------------------------------
   ; And straight numbers
   ;---------------------------------------------------------------------
   ((numberp waveform)
    (difference waveform 
                (times 
                 (fix (quotient waveform modulo))
                 modulo)))
   (t
    (error "abModulo - can't handle %L\n" waveform)
    )
   )
  )