how to sort a list alphanumerically with bus names in descending order using skill

maybe something like the following?

procedure( myLesspCompare( str1 str2 )

  let( (l_chars1 l_chars2)

    l_chars1 = parseString(str1 "[]")

    l_chars2 = parseString(str2 "[]")

    if( length(l_chars1)==1 && length(l_chars2)==1 then

      alphalessp(str1 str2)

    else

      if( length(l_chars1)==1 && length(l_chars2)>1 then

        t

       else

          if( length(l_chars1)>1 && length(l_chars2)==1 then

            nil

         else

            if( car(l_chars1)!=car(l_chars2) then

              alphalessp(car(l_chars1) car(l_chars2))

            else

               greaterp(atoi(cadr(l_chars1)) atoi(cadr(l_chars2)))

            );ifelse

          );ifelse

        );ifelse

     );ifelse

 );let

);procedure

mylist = sort( mylist 'myLesspCompare)

Thanks a lot, Daniel. Your solution works for my original list, but let's take another example

mylist=list("VDD" "GND" "dd_b[0]" "dd_b[1]" "bb_a[0]" "bb_a[1]" "dd_abc" "bb_rst")

the results after running your code will be ==> ("GND" "VDD" "bb_rst" "dd_abc" "bb_a[1]" "bb_a[0]" "dd_b[1]" "dd_b[0]")

I want mylist become ("GND" "VDD" "bb_a[1]" "bb_a[0]" "bb_rst" "dd_abc" "dd_b[1]" "dd_b[0]").

The elements of the list are sorted alphanumerically, and the name with bus quotation are sorted in descending order instead.

Could you take a look again ...

Best regards,

Use this comparison function:

procedure(MySortCompare(a b)
  let((aSplit bSplit)
    aSplit=car(parseString(a "["))
    bSplit=car(parseString(b "["))
    cond(
      (alphalessp(aSplit bSplit) t)
      (aSplit==bSplit plusp(alphaNumCmp(a b)))
    )
  )
)

Essentially if it matches before the [ then it uses alphaNumCmp to do the comparison - which by using plusp is going to give you the result in descending order of the bit that follows the [. For anything else, it's using alphalessp as normal.

Regards,

Andrew.

Thanks a lot,Andrew. It works like a charm.

Here a bit of plagiarism of Andrews work may also work

mylist = sort(mylist lambda((a b) minusp(alphaNumCmp(a b))))

psill000 said:

mylist = sort(mylist lambda((a b) minusp(alphaNumCmp(a b))))

The complication with the original question was that numerical parts needed to be in descending order, with the alphabetic parts in ascending order. Your (much more compact) solution sorts them both in ascending order - which is of course fine if that's what you want!

Regards,

Andrew.