Set Library source to ddHiCreateCellComboField.

Hi Ivick,

The trick is to use ddHiLinkFields. See this little example I just put together:

/* abLibCellViewComboExample.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Jan 12, 2019 
Modified   
By         

Example of using the enhanced lib/cell/view combo fields that support
type-in completion.

Simply call abLibCellViewComboExample() to create and display the form.

***************************************************

SCCS Info: @(#) abLibCellViewComboExample.il 01/12/19.09:31:51 1.2

*/

procedure(abLibCellViewComboExample()
    let((grid lib cell view libLabel cellLabel viewLabel 
            browse form)
        libLabel=hiCreateLabel(
            ?name 'libLabel ?labelText "Library"
            ?justification 'right
        )
        cellLabel=hiCreateLabel( 
            ?name 'cellLabel ?labelText "Cell"
            ?justification 'right
        )
        viewLabel=hiCreateLabel(
            ?name 'viewLabel ?labelText "View"
            ?justification 'right
        )
        lib=ddHiCreateLibraryComboField( 
            ?name 'lib ?callback "(ddsUpdateSyncWithForm)"
        )
        cell=ddHiCreateCellComboField( 
            ?name 'cell ?callback "(ddsUpdateSyncWithForm)"
        )
        view=ddHiCreateViewComboField( 
            ?name 'view ?callback "(ddsUpdateSyncWithForm)"
        )
        browse=hiCreateFormButton(
            ?name 'browse
            ?buttonText "Browse..."
            ?callback "(ddsSyncWithForm (hiGetCurrentForm) 'browse 'lib 'cell 'view)"
        )
        grid=hiCreateGridLayout(
            'grid
            ?items list(
                list( libLabel 'row 0 'col 0)
                list( cellLabel 'row 1 'col 0)
                list( viewLabel 'row 2 'col 0)
                list( lib 'row 0 'col 1)
                list( cell 'row 1 'col 1)
                list( view 'row 2 'col 1)
                list( browse 'row 0 'col 2)
                list( 'col_stretch 0 0)
                list( 'col_stretch 1 1)
                list( 'col_stretch 2 0)
            )
        )
        form=hiCreateLayoutForm(
            'abImportParasiticsForm
            "Lib Cell View Example"
            grid
            ?sizePolicy 'horizontalExpanding
        )
        ;----------------------------------------------------------------
        ; Need to both instantiate the form and link the fields so that
        ; the combo-boxes use the other fields to inform the choices
        ;----------------------------------------------------------------
        hiInstantiateForm(form)
        ddHiLinkFields(
            form->lib
            form->cell
            form->view
        )
        hiDisplayForm(form)
    )
)

Regards,

Andrew.

[Note: there is a newer version of this code in this post which is a more flexible general lib/cell/view browser but shows embedding of the grid layout in a vertical box layout)

Hi Andrew,

Until now I had the opportunity to apply your suggestion and it worked! 

Thanks and regards,

Ivick Guerra.