Skill languag(beginner level)

Something like this would be a good basis of your code. The Technology label handling is just a suggestion to show what it might look like if you have labels such as "& Technology MyTech180":

procedure(CCFupdateLabels(@key (cvId geGetEditCellView()) (layer "IP") 
        (purpose "drawing"))
    let((lpp Date_Time Technology currentTime)
        currentTime=timeToTm(stringToTime(getCurrentTime()))
        ;----------------------------------------------------------------
        ; Define any regular expressions needed to identify the labels
        ;----------------------------------------------------------------
        Date_Time=pcreCompile("^& Date_Time")
        Technology=pcreCompile("^& Technology")
        ;----------------------------------------------------------------
        ; Find the right layer purpose
        ;----------------------------------------------------------------
        lpp=car(
            exists(LP cvId~>lpps LP~>layerName==layer && 
                LP~>purpose==purpose)
        )
        foreach(shape lpp~>shapes
            when(shape~>objType=="label"
                cond(
                    ;----------------------------------------------------
                    ; Look for date labels - update to current time
                    ;----------------------------------------------------
                    (pcreExecute(Date_Time shape~>theLabel)
                        shape~>theLabel=
                            sprintf(nil "& Date_Time %04d%02d%02d"
                                currentTime->tm_year+1900
                                currentTime->tm_mon+1
                                currentTime->tm_mday
                            )
                    )
                    ;----------------------------------------------------
                    ; Look for technology labels - update to current
                    ; tech lib name
                    ;----------------------------------------------------
                    (pcreExecute(Technology shape~>theLabel)
                        shape~>theLabel=
                            sprintf(nil "& Technology %s"
                                techGetTechFile(cvId)~>libName
                            )
                    )
                    ;----------------------------------------------------
                    ; Add other condition branches here
                    ;----------------------------------------------------
                )
            )
        )
        t
    )
)
 

Hi Andrew,

Thank you so much for the help but I am facing difficulties in understanding the code. Could you please provide me your Gmail Id and we can communicate better there. Also can you provide me a test bench for the above code since I am not able to execute it.

No, I'm not going to provide my "gmail" id (or even my Cadence email address) in a public forum. I thought you had some data to run this on yourself? I simply created a bunch of labels on the right layer like this:

The white labels (in my case) where on layer text/drawing and the blue label on Metal1/drawing (because I didn't have an IP layer in my PDK). I can then put the code above into a file (say  CCFupdateLabels.il) and then do (once):

load("CCFupdateLabels.il") in the CIW

After loading, I just do:

CCFupdateLabels(?layer "text")  ; you could just run CCFupdateLabels() since the layer would be the right layer. 

Then the white & Technology and & Date_Time labels will get updated. The others are left alone.

Andrew.

Thank you so much Andrew for the code, it is working perfectly fine. Ok, I will try to understand the code by myself then.

Regards,

Ayushi.

Hi Ayushi,

I thought the comments in the code were clear enough, but let me describe in pseudo-code how it works:

Date_Time=CompiledPattern("& Date_Time")
Technology=CompiledPattern("& Technology")
lpp=searchForLayerPurpose(layer purpose) # find lpp object for the layer-purpose you want
foreach shape shapes_on_lpp
  when shape is a label
    if(patternMatch(Date_Time theLabel) then
      theLabel=updateDateTimeLabel()
    else if (patternMatch(Technology theLabel) then
      theLabel=updateTechnologyLabel()

The cond function is a convenient way of doing if-then-else-if-else-if-else branches. If you're not sure about any of the functions used here, I suggest (if using IC617 or later) you can search in cdsFinder for the function and then press "More Info" to see the full documentation.

Regards,

Andrew.

Hi Andrew,

Thank you so much for above explanation. Yes, sure I will take help from cdsFinder for more information. 

Regards,

Ayushi.