Need to reduce the height of a particular text layer inside all layout views of a standard cell library

Not sure if you really meant to do this recursively, but if you wanted to do this for every cell in the library, something like this will do (no need for it to be recursive then):

procedure(CCFfixText(libName layerName purpose newHeight @optional (saveAndClose t))
  let((lib master cv textLPP)
    lib=ddGetObj(libName)
    foreach(cell lib~>cells
      foreach(view cell~>views
        ; Check if the view is a layout viewType
        master=ddGetObj(libName cell~>name view~>name "*")
        when(master && ddMapGetFileViewType(master)=="maskLayout"
          printf("Updating %s %s %s\n" libName cell~>name view~>name)
          cv=dbOpenCellViewByType(libName cell~>name view~>name "" "a")
          ; find the layer purpose in this view and then fix
          ; the height of any labels
          textLPP=car(exists(lpp cv~>lpps lpp~>layerName==layerName && lpp~>purpose==purpose))
          foreach(shape textLPP~>shapes
            when(shape~>objType=="label"
              shape~>height=newHeight
            )
          )
          when(saveAndClose
            dbSave(cv)
            dbClose(cv)
          )
        )
      )
    )
    t
  )
)

To use it, you'd then do:

CCFfixText("std_cell" "ALPHA" "audit" 0.01)

Regards,

Andrew.

Hi Andrew,

You're using a combination of car() and exists() to test the existence of the specified layer in the layout.

To me, this looks a bit complicated, it is possible to just use a when() and member() combination. Something like:

lppList = list( '("ME1" "drawing") '("text" "drawing") '("ME2" "drawing") )
(("ME1" "drawing") 
    ("text" "drawing") 
    ("ME2" "drawing")
)
lpp_lay = "text"
"text"
lpp_pur = "drawing"
"drawing"
when( member( list(lpp_lay "text") lppList ) printf("found\n") )
nil
when( member( list(lpp_lay lpp_pur) lppList ) printf("found\n") )
found
t

Is there a particular reason why you use the car() and exists() combination?

Thanks in advance.

Sjoerd

Hi Sjoerd,

I'm not just determining whether a specified layer purpose is present or not; I'm finding the layer-purpose object so that I can then find just the shapes on that LPP. The assumption is that you might have an enormous number of shapes in the layout, but relatively few on a specific layer, and so searching to find the layer-purpose object and then narrowing down the shapes on that LPP is more efficient than searching through every shape in the cellView which might be a label and on that LPP.

The exists function (like member) returns the remainder of the list of LPP objects in the cellView (so it's not a list of sub-lists containing the layerName and purposeName), and will find the remainder from the point of the first match (there will only be one match since I'm checking the layer name and purpose name on that object); since I'm only interested in the first, I'm using the car.

So I can't use the approach you suggest, because that wouldn't work...

Regards,

Andrew.

Thanks, Andrew-

  This is just what I needed. Thanks again!

Cheers!

Hi Andrew,

Sorry, I should have elaborated the example code a bit more. This is what I meant:

;;; first find out whether or not the lpp is used in the layout...
when( member( list( layerName purpose ) cv~>lpps )
  ;;; Now go through all shapes that are labels and are in the right layer and purpose...
  foreach( shape setof(shapes cv~>shapes and( shapes~>objType == "label" shapes~>layerName == layerName shapes~>purpose == purpose )
    ;;; Adjust the height...
    shape~>height = newHeight
  ) ;;; end of foreach shape
) ;;; end of when

Or is your solution quicker or "easier on the memory" than my solution?

Thanks.

Sjoerd

ps: haven't tested the code, more an indication of how I would do it...

Hi Sjoerd,

Other than the code not working because cv~>lpps is a list of dbObjects not a list of lists (of layer and purpose names), the pattern of first finding a list of all shapes which match the given layerName and purpose and objType will be slower and more memory consuming, unless there are a very small number of shapes in the cellView (even then I suspect it would not be quicker).

The reasons are:

1. Doing cv~>shapes has to build a list of objects for every shape in the design (whilst the database has all these shapes, the list construction takes time and memory)
2. You then have to visit every single shape and then construct a new list (the setof) with just those which are labels on the right layer purpose
3. Then you foreach over that reduced list (it would have been better to just do a foreach over all shapes and then have a when() instead of the setof to do something when the condition matched

In my case, I traverse the layer-purpose objects (of which there are typically relatively few), and I only search until I find a match (so that means on average half the LPP objects). From there I directly get just the shapes that are on that layer-purpose pair - I don't need to visit all the shapes on layer-purposes that I don't care about - so no big list was generated with lots of things in it that don't matter.

So my approach would be generally faster, take less memory, and produce less garbage to be collected. I think the code is actually simpler too!

Regards,

Andrew.

Thanks Andrew,

I understand your reasoning. I'm in the middle of writing code to the migration of a full chip design from one foundry to an other, and things like this will happen a lot in the code I'm writing. So thank you for taking the time to explain to me why you do what you do.

Kind regards,

Sjoerd