How to show/hide multiple fields in a form?

That UI isn't actually implemented in SKILL, but the same capability is available using "progressive disclosure" widgets - in particular the hiCreateDisclosureTriangle function (there's also the similar hiCreateDisclosureButton too). An example of using these (as well as all other hi fields) can be found in this excellent article by one of my colleagues: Worked example using all available SKILL UI fields (they're on the third tab).

If these are used together with the "layout forms" (hiCreateLayoutForm etc) then the space also collapses. I threw together a simple example shown below:

/***************************************************************
*                                                              *
*                   CCFcreateExampleLayForm()                  *
*                                                              *
*               You guessed it. Creates the form               *
*                                                              *
***************************************************************/
procedure(CCFcreateExampleLayForm()
    let((field1Label field1Entry field2Label field2Entry extraParams 
        paramLabel minLabel stepLabel maxLabel
        paramEntry minEntry stepEntry maxEntry
        gridLayout)
        field1Label=hiCreateLabel(
            ?name 'field1Label
            ?labelText "First Field"
            ?justification 'right
        )
        field1Entry=hiCreateStringField(
            ?name 'field1Entry
        )
        field2Label=hiCreateLabel(
            ?name 'field2Label
            ?labelText "Second Field"
            ?justification 'right
        )
        field2Entry=hiCreateStringField(
            ?name 'field2Entry
        )
        extraParams=hiCreateDisclosureTriangle(
            ?name 'extraParams
            ?labelText "Extra Parameters"
            ?onFields 
                list(
                    'paramLabel 'minLabel 'stepLabel 'maxLabel
                    'paramEntry 'minEntry 'stepEntry 'maxEntry
                )
            )
        paramLabel=hiCreateLabel(
            ?name 'paramLabel
            ?labelText "<b>Parameter</b>"
        )
        minLabel=hiCreateLabel(
            ?name 'minLabel
            ?labelText "<b>Minimum</b>"
        )
        stepLabel=hiCreateLabel(
            ?name 'stepLabel
            ?labelText "<b>Step</b>"
        )
        maxLabel=hiCreateLabel(
            ?name 'maxLabel
            ?labelText "<b>Maximum</b>"
        )
        paramEntry=hiCreateStringField(
            ?name 'paramEntry
        )
        minEntry=hiCreateStringField(
            ?name 'minEntry
        )
        stepEntry=hiCreateStringField(
            ?name 'stepEntry
        )
        maxEntry=hiCreateStringField(
            ?name 'maxEntry
        )
        gridLayout=hiCreateGridLayout(
            'gridLayout
            ?items list(
                list(field1Label 'horiz_align 'right 'row 0 'col 0)
                list(field1Entry 'horiz_align 'right 'row 0 'col 1 'col_span -1)
                list(extraParams 'horiz_align 'left 'row 1 'col 0)
                list(paramLabel 'horiz_align 'left 'row 2 'col 0)
                list(minLabel 'horiz_align 'left 'row 2 'col 1)
                list(stepLabel 'horiz_align 'left 'row 2 'col 2)
                list(maxLabel 'horiz_align 'left 'row 2 'col 3)
                list(paramEntry 'horiz_align 'left 'row 3 'col 0)
                list(minEntry 'horiz_align 'left 'row 3 'col 1)
                list(stepEntry 'horiz_align 'left 'row 3 'col 2)
                list(maxEntry 'horiz_align 'left 'row 3 'col 3)
                list(field2Label 'horiz_align 'right 'row 4 'col 0)
                list(field2Entry 'horiz_align 'right 'row 4 'col 1 'col_span -1)
                list('col_stretch 0 1)
                list('col_stretch 1 1)
                list('col_stretch 2 1)
                list('col_stretch 3 1)
            )
        )
        hiCreateLayoutForm(
            'CCFexampleLayForm
            "Example Form"
            ;--------------------------------------------------------
            ; Surrounding vertical box layout is to have a stretchable
            ; item below the layout to absorb all the stretchiness!
            ;--------------------------------------------------------
            hiCreateVerticalBoxLayout(
                'vbox
                ?items list(
                    gridLayout
                    list('stretch_item 1)
                )
            )
        )
        CCFexampleLayForm
    )
)

/***************************************************************
*                                                              *
*                  CCFdisplayExampleLayForm()                  *
*                                                              *
*           Create (if needed) and display the form            *
*                                                              *
***************************************************************/

procedure(CCFdisplayExampleLayForm()
    unless(boundp('CCFexampleLayForm)
        CCFcreateExampleLayForm()
    )
    hiDisplayForm(CCFexampleLayForm)
)

Thanks Andrew! I will take a close look at the link you posted as well as your example above. As always, you're this forum's saviour