Is there any SKILL command to find the MIN and MAX value in a list/array (containing numbers) ?

Providing the list doesn't have more than about 260,000 elements, you can just do:

apply('max theList)
apply('min theList)

Otherwise you could just do:

procedure(CCFmin(lst)
  let((theMin)
    theMin=car(lst)
    foreach(elem cdr(lst)
      theMin=min(theMin elem)
    )
    theMin
  )
)

procedure(CCFmax(lst)
  let((theMax)
    theMax=car(lst)
    foreach(elem cdr(lst)
      theMax=max(theMax elem)
    )
    theMax
  )
)

Then just use CCFmin(myList) or CCFmax(myList). These have no upper limit to the length of the list.

Regards,

Andrew.

Thanks a lot.

Can you tell how to find the index of the max or min  element in the list. 

You can use the lindex function to do this. Find the min or max using the methods I described earlier, and then pass the value found as the second argument to the lindex function, with the list being searched as the first. The index starts from 1, so you'd use nthelem rather than nth to find it again. Or you could write a function similar to CCFmin or CCFmax above which kept a count and returned the index instead.

That said, needing to find the index suggests to me that you might be using the wrong data structure. In general any time you're accessing a list element via its index suggests that you are treating it as a random-access rather than a sequential data structure (you might want to watch my video Writing Good SKILL Code)

Regards,

Andrew.

Thanks Andrew. Sure, I will watch your video.

Kind Regards,

Dear Andrew,

Is there a way to find the max/min value in an array A[6][8]  (created by using abMultiDimArray.il).

I want to find the min/max of A[0] [] (0th row)  and min/max of A[][0] (0th column).

I could probably come up with a complicated macro or function to generalise this, but don't have time right now. So assuming it's a simple two-dimensional array, something like:

procedure(CCFfindMinMaxForRow(array func row)
  let((current)
    current=array[row][0]
    for(ind 1 length(array[row])-1
      current=funcall(func current array[row][ind])
    )
    current
 )
)

procedure(CCFfindMinMaxForCol(array func col)
  let((current)
    current=array[0][col]
    for(ind 1 length(array)-1
      current=funcall(func current array[ind][col])
    )
    current
 )
)

Then use CCFfindMinMaxForRow(A 'min 0) or CCFfindMinMaxForCol(A 'max 0) for example. You can even use the same functions to add up all the entries in a column or row by passing 'plus instead of 'min or 'max

Andrew.