Break out of a loop early

Your question was a bit confusion because there's no loop to be exited early from. The problem is that your code is recursive, and you don't do anything with the return when you recursively call insName2CellName from within the code. So it never gets passed back up through the hierarchy. Whilst there is a way (using prog) of returning across function calls, to do so is extremely bad practice (and very hard to follow) so instead I just slightly changed your program and it now works:

procedure( insName2CellName(start cvid path)
  prog( (newinst newcv newpath)  
    instpath = parseString(path "/")
    printf("Starting with L = %L for %L\n",length(instpath) path)
    istelem = car(instpath) 
    instpath = remove(istelem instpath)
    newpath = buildString(instpath "/")

    if(length(instpath) > 1 then 
      newinst=dbFindAnyInstByName(cvid istelem)
      start = strcat(start "/" newinst~>cellName)
      newcv = dbGetAnyInstSwitchMaster(newinst "schematic")
      when(newcv
        start=insName2CellName(start newcv newpath) 
      )
    else
      newinst=dbFindAnyInstByName(cvid istelem)
      start = strcat(start "/" newinst~>cellName)
      printf("Final --> %L\n" start)
    ) 
    return(start) 
  ) 
)

;; insName2CellName("top" geGetEditCellView() "I42/I59/I3")

I've highlighted in red the lines I changed. As you can see, I assign start to be the return value from the lower level insName2CellName call, and moved the return statement outside of the if, so that it always returns the value of start as it ascends back through the hierarchy. So in other words, as you descend the hierarchy, it concatenates start with the name at this level and finally the leaf, and then returns it back as you ascend.

BTW, I don't think the if in the code is correct. I think it should be >0 rather than >1, because otherwise it misses out the final leaf instance (not sure whether that's what you wanted or not).

You can also write this code more simply (and without the remove, which is a poor way of removing the first entry in the list - in fact it will be incorrect if the same instance name is used at more than one level of hierarchy - so that's another bug):

procedure( insName2CellName(start cvid path)
  prog( (newinst newcv instpath instelem )  
    ; cope with argument being a list of paths or a single string
    ; convert to a list and then keep as a list
    instpath = if(stringp(path) then parseString(path "/") else path)
    instelem = car(instpath) 
    instpath = cdr(instpath)

    newinst=dbFindAnyInstByName(cvid instelem)
    start = strcat(start "/" newinst~>cellName)
    when(instpath ; would be cdr(instpath) if you want to omit the leaf
      newcv = dbGetAnyInstSwitchMaster(newinst "schematic")
      when(newcv
        start=insName2CellName(start newcv instpath) 
      )
    )
    return(start) 
  ) 
)

Note that in this version I avoided keeping converting back and forth between strings and lists and only do that once, and also declared some missing local variables. The common code is also outside of the if as it is done in both branches before.

Hope that helps,

Andrew

Thank you very much for this insight. I've learned something new 

Thank you very much for this insight. I've learned something new