Grabbing form field values

The example in the documentation is pretty poor - I will get tech pubs to improve it (I'd not noticed how bad it was as I'd not looked at it for some time). In general:

1. Form fields do not need to be global - it's only the main form variable that must be global (this is so that an expression can be generated to reference the form from the global scope)
2. You should access the form fields via the form variable itself rather than directly through the field variable.
3. You can avoid referring to the global form variable by specifying the form callback as the function name, then it will automatically pass the form data structure to the callback. Alternatively you could have just used myformglb->strfld->value (in my updated code below) in the callback - i.e. via the form global variable

I've updated the code to use local variables for the fields (I also changed it to use camel case for the function names consistently for style reasons):

;****************************************
;Sample form and fields
;****************************************
; Create string entry for the form. 
procedure( myformDefineFields()
  let((strfld boolfld)
    strfld = hiCreateStringField(
      ?name 'strfld
      ?prompt "sample string field"    ;;; FIELD1, a string type
      ?defValue "initial string"
  ;    ?callback "my_strfld_cb()"
      ?editable t
  )
    ; Create a Boolean button for the form. 
    boolfld = hiCreateBooleanButton(
      ?name 'boolfld
      ?buttonText "sample boolean field"        ;;; FIELD2, a boolean type
      ?defValue t
  ;    ?callback "my_boolfld_cb()"
    )
    list( strfld boolfld )
  )
)
; Generate the form
procedure( myformCreateForm()
  if( !boundp(`myformglb) || (myformglb == nil)
    then
    myformglb = hiCreateAppForm(
      ?name `myformglb
      ?fields myformDefineFields()
      ?formTitle "My first Form"
      ?callback 'myformglb_cb
      ?buttonLayout `OKCancel
    )
  )
  myformglb
)

procedure(myformglb_cb(form)
  printf("Field values are: %s and %L\n" form->strfld->value form->boolfld->value)
)

; Display the form
procedure( myformDisplayForm()
  myformCreateForm()    ;;; Creation and Display are separate
  hiDisplayForm(`myformglb)
)

myformDisplayForm()

Regards,

Andrew

Hi Andrew,

That's super helpful!

Thanks!