Please tell me How can I make option window that open by F3 Key.

Hi,

You might have two way of doing this:

1.

If your mouse clicks to select objects are done using an enter function: enterPoint, enterPoints, ...

Then you just have to bind your menu using the arguments of the enter function, see bold arguments below:

(enterPoint
 [ ?prompts l_promptList ]
 [ ?points l_pointList ]
 [ ?form s_form ]
 [ ?addPointProc t_addProcName ]
 [ ?delPointProc t_delProcName ]
 [ ?initProc t_initProcName ]
 [ ?doneProc t_doneProcName ]
 [ ?formProc t_formProcName ]
 [ ?alwaysMap g_alwaysMap ]
 [ ?acceptString g_acceptString ]
 [ ?acceptNumber g_acceptNumber ]
 [ ?noInfix g_noInfix ]
 [ ?cmdName t_cmdName ]
 [ ?cursor x_cursor ]
 )

2.

If you are doing things differently, you might still be able to bind F3 to the function to display your form and re-bind it afterward

(let ((bk (hiGetBindKey "Layout" "<Key>F3")))
  (hiSetBindKey "Layout" "<Key>F3" "(display_your_form)")
  ;; Safely re-bind F3
  (unwindProtect
    (progn
      ;; Run your code
      ...
      )
    (hiSetBindKey "Layout" "<Key>F3" bk)
    ))



Note that I haven't ran this code snippet


Hope this might help,

Cheers,
Aurel

The main approach is the first one that Aurel mentioned, and it requires an enter function (e.g. enterPoint, enterBox etc) or geHiDragFig, and these being passed a form which was created with ?formType 'options to indicate that it's an "options" form (it has the right types of buttons for an options form). Here's a (cut down) example - I removed the actual bit that drew the guard ring as that was technology-specific. Unfortunately I don't have too many examples of these types of forms lying around...

/* abGuardRing.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Sep 13, 2002 
Modified   
By         

This code defines two functions and a key-binding that allows the
automatic creation of an arbitrary guard-ring structure.

Could do with a few more comments...

***************************************************

SCCS Info: @(#) abGuardRing.il 09/13/02.14:03:39 1.1

*/

hiSetBindKey("Layout" "<Key>F10" "abCreateGuardring()")

procedure(abCreateGuardring()

    unless(boundp('abCreateGuardringForm)
	abCreateGuardringOptionsForm()
	)
    enterPath(?prompts list("Enter points for guard ring")
	?doneProc "abCreateGuardringDoneProc"
	?points nil
	?addPointProc "abCreateGuardringPointTracker"
	?delPointProc "abCreateGuardringPointTracker"
	?form abCreateGuardringForm
	?alwaysMap t
	?pathWidth abCreateGuardringForm->diffWidth->value
	)
)

procedure(abCreateGuardringOptionsForm()
    let((diffWidth)
	diffWidth=hiCreateFloatField(
	    ?name 'diffWidth
	    ?value 10.0
	    ?callback "abChangeGuardringWidth()"
	    ?prompt "Diffusion Width"
	)
	hiCreateAppForm(
	    ?name 'abCreateGuardringForm
	    ?formType 'options
	    ?buttonLayout 'HideCancelDef
	    ?fields list(
		list(diffWidth 0:0 400:30 100)
		)
	)
    )
)


procedure(abChangeGuardringWidth()
    ; need this to stop recursion (not sure why)
    unless(abCreateGuardringForm->currentWidth==
	abCreateGuardringForm->diffWidth->value
	abCreateGuardringForm->currentWidth=
	    abCreateGuardringForm->diffWidth->value
	changeEnterFun(
	    'enterPath
	    ?pathWidth abCreateGuardringForm->diffWidth->value
	    ?doneProc "abCreateGuardringDoneProc"
	    ?points abCreateGuardringForm->points
	    ?addPointProc "abCreateGuardringPointTracker"
	    ?delPointProc "abCreateGuardringPointTracker"
	    ?prompts list("Enter points for guard ring")
	    ?form abCreateGuardringForm
	)
    )
)

procedure(abCreateGuardringPointTracker(win points)
    abCreateGuardringForm->points=points
)

procedure( abCreateGuardringDoneProc( win done points )
    let((
	(cv geGetEditCellView())
	)
	; now create the guard right itself - removed for simplicity
	t
    )
)

Andrew

I solved this problem using "?poins" option.

I really appreciata your kindness. 

I solved this problem using "?poins" option.

I really appreciata your kindness.혻

Hi,

I don't believe you will be able to use the preselection highlight during an enter function call

I think this is some internal code not available directly in SKILL

I guess you will have to re-implement something simillar to the "(De)Select Under Cursor" feature when the entered point is where several shapes overlap

Cheers,

Aurel

The solution is (I think) to use the geSetEnterFunctionSelectionMode() function which allows you to turn on the dynamic highlighting during an enter function. I adapted your code to use this - rather than first selecting anything, instead it prompts for two points and then the addPointProc takes care of the selection. I may have misinterpreted your needs, but I think this probably does what you want? F3 can be used to toggle the form throughout the entire operation, you see the dynamic highlighting of the potential selection, and at the end you have found two selected objects and coordinates (I changed the function names and cleaned up the code a bit to make it clearer):

procedure(CCFtestEnter()
    unless(boundp('RoutingAssistanceForm)
        RoutingAssistanceOptionForm()
    )
    ; store some properties on the form to record objects selected
    RoutingAssistanceForm.firstSelection=nil
    RoutingAssistanceForm.firstPoint=nil
    RoutingAssistanceForm.secondSelection=nil
    RoutingAssistanceForm.secondPoint=nil
    enterPoints(
        ?prompts list("First Object" "Second Object")
        ;   ?points list(0:0)
        ?form RoutingAssistanceForm
        ?alwaysMap t
        ?wantPoints 2
        ?initProc "CCFtestFun" ; init / addPoints / delPoints / done
        ?doneProc "CCFtestDone"
        ?addPointProc "CCFtestAddPointProc"
    )
) 

procedure(RoutingAssistanceOptionForm()
    let((tempIndex)
        tempIndex=hiCreateFloatField(
            ?name 'tempIndex
            ?value 10.0
            ?callback "CCFtestprint()"
            ?prompt "RoutingAssistanceOptionForm"
        ) 

        hiCreateAppForm(
            ?name 'RoutingAssistanceForm
            ?formType 'options
            ?buttonLayout 'HideCancelDef
            ?fields list(
                list(tempIndex 0:0 400:30 100)
            ) 
        )  
    ) 
) 

procedure(CCFtestFun(wid)
    geSetEnterFunctionSelectionMode(wid 4)
    t
)

procedure(CCFtestAddPointProc(wid pointList)
    let((newPt selection)
        ; probably want to record the two selections
        newPt=car(last(pointList))
        geSingleSelectPoint(wid nil newPt)
        selection=geGetSelSet()
        if(RoutingAssistanceForm.firstSelection then
            RoutingAssistanceForm.secondSelection=selection
            RoutingAssistanceForm.secondPoint=newPt
        else
            RoutingAssistanceForm.firstSelection=selection
            RoutingAssistanceForm.firstPoint=newPt
        )
    )
)

procedure(CCFtestDone(wid ok pointList)
    printf("FIRST point %L selection %L\n"
	RoutingAssistanceForm.firstSelection
	RoutingAssistanceForm.firstPoint
    )
    printf("SECOND point %L selection %L\n"
	RoutingAssistanceForm.secondSelection
	RoutingAssistanceForm.secondPoint
    )
)

Andrew