Radio button changes automatically

seongminlee said:

Can you guess the cause?

Not really, because you didn't show the code that had the error. Maybe you had ?choices 'Choices1 (i.e. were quoting the variable), which would be wrong, or maybe it was because you set the variable after you used it?

Anyway, here's the code working using the variables for the choices, plus a callback which does what you asked for in point 1.

Choices1 = '("test1" "test2" "test3" "test4" "test5")
Choices2 = '("test1" "test2" "test3")

procedure(CCFsetMenu2FromMenu1(form)
  when(member(form->radio1->value form->radio2->choices)
    form->radio2->value=form->radio1->value
  )
)

let( (radiofield1 radiofield2) 
  radiofield1 = hiCreateRadioField(
    ?name 'radio1 
    ?prompt "MENU1"
    ?value "test1"
    ?choices Choices1
    ?callback list("CCFsetMenu2FromMenu1(hiGetCurrentForm())")
  )
  radiofield2 = hiCreateRadioField(
    ?name 'radio2 
    ?prompt "MENU2"
    ?value "test1"
    ?choices Choices2
  )

  hiDisplayForm(
    hiCreateAppForm( ?name 'myform ?formTitle "Radio Button Test"
      ?fields (list radiofield1 radiofield2))
  )
)

Andrew

Thank you very much.

one more question. 

----------------------------------------------------------------------

Choices1 = '("test1" "test2" "test3" "test4" "test5")
Choices2 = '("test1" "test2" "test3")

procedure(CCFsetMenu2FromMenu1(form)
when(member(form->radio1->value form->radio2->choices)
form->radio2->value=form->radio1->value
)
)

let( (radiofield1 radiofield2 radiofield3 radiofield4 )
radiofield1 = hiCreateRadioField(
?name 'radio1
?prompt "MENU1"
?value "test1"
?choices Choices1
?callback list("CCFsetMenu2FromMenu1(hiGetCurrentForm())")
)
radiofield2 = hiCreateRadioField(
?name 'radio2
?prompt "MENU2"
?value "test1"
?choices Choices1
)
radiofield3 = hiCreateRadioField(
?name 'radio3
?prompt "MENU3"
?value "test1"
?choices Choices1
)
radiofield4 = hiCreateRadioField(
?name 'radio4
?prompt "MENU4"
?value "test1"
?choices Choices2
)

hiDisplayForm(
hiCreateAppForm( ?name 'myform ?formTitle "Radio Button Test"
?fields (list radiofield1 radiofield2 radiofield3 radiofield4))
)
)

------------------------------------------------------------------------------------

With the above code, Menu1 Menu2 Menu3 should always select the same radio value.
Menu4 has values of Menu1,2,3
test1-> test3
test2-> test3
test3-> test2
test4-> test1
test5-> test1
How do I make a selection like this?

Rather odd requirement, but this is just a matter of having the appropriate callback logic. The code below means that whenever you set a value of the MENU1/MENU2/MENU3 radio buttons, it replicates the setting to the other two within the set, and then does a mapping to set MENU4. It's really not that complicated to do this - you just need to think about the logic you're trying to implement.

Choices1 = '("test1" "test2" "test3" "test4" "test5")
Choices2 = '("test1" "test2" "test3")

procedure(CCFsetMenusFromMenuField(form field)
  let((fieldValue)
    fieldValue=get(form field)->value
    ; set the other fields to the value of the field just
    ; changed
    foreach(fieldName '(radio1 radio2 radio3)
      unless(fieldName==field
        when(member(fieldValue get(form fieldName)->choices)
          get(form fieldName)->value=fieldValue
        )
      )
    )
    ; set the final radio button with a mapping from the 
    ; chosen value using a case statement
    form->radio4->value=
      case(fieldValue
        (("test1" "test2") "test3")
        (("test3")         "test2")
        (("test4" "test5") "test1")
      )
    t
  )
)

let( (radiofield1 radiofield2 radiofield3 radiofield4 ) 
  radiofield1 = hiCreateRadioField(
    ?name 'radio1 
    ?prompt "MENU1"
    ?value "test1"
    ?choices Choices1
    ?callback list("CCFsetMenusFromMenuField(hiGetCurrentForm() 'radio1)")
  )
  radiofield2 = hiCreateRadioField(
    ?name 'radio2 
    ?prompt "MENU2"
    ?value "test1"
    ?choices Choices1
    ?callback list("CCFsetMenusFromMenuField(hiGetCurrentForm() 'radio2)")
  )
  radiofield3 = hiCreateRadioField(
    ?name 'radio3 
    ?prompt "MENU3"
    ?value "test1"
    ?choices Choices1
    ?callback list("CCFsetMenusFromMenuField(hiGetCurrentForm() 'radio3)")
  )
  radiofield4 = hiCreateRadioField(
    ?name 'radio4
    ?prompt "MENU4"
    ;?value "test1"
    ; changed default to match mapping logic
    ?value "test3"
    ?choices Choices2
  )

  hiDisplayForm(
    hiCreateAppForm( ?name 'myform ?formTitle "Radio Button Test"
      ?fields (list radiofield1 radiofield2 radiofield3 radiofield4)
    )
  )
)