Can someone please help with the syntax for a Navigator specific bindkey

Hi,

You should have a look at the following support article:

How to get currently selected object like net and instance in Navigator assistant, net in Annotation browser using SKILL?

I believe you are looking for the following function hsmGetSelectedSet

I don't think you can set bindkeys directly to the "Navigator" as this is not a registered application

What you could do is write a generic function that will call your previously defined bindkeys depending on the context

Here is a little example:


(inScheme

  ;; We are in SKILL++ (Scheme) so the following
  ;; variables are available in all the
  ;; fonctions defined in the letseq
  (letseq ((cmd              "Alt<Key>C")
           (prev_sch_bindkey (hiGetBindKey "Schematics" cmd))
           (prev_lay_bindkey (hiGetBindKey "Layout"     cmd))
           )

    (defun call_bindkey_string (str)
      "Call bindkey string if it is properly defined"
      (when (stringp str)
        ;; Avoid infinite loop in case this code
        ;; is executed twice and our custom
        ;; function is stored as a previously
        ;; registered bindkey
        (unless (equal str "(my_custom_navigator_bindkeys)")
          ;; Call our bindkey string in an error-safe environment
          (errsetstring str t)
          )))

    (defglobalfun my_custom_navigator_bindkeys (@rest _args)
      "Call the right bindkeys according on the context"
      (let ((cv            (geGetEditCellView))
            (nav_selection (hsmGetSelectedSet))
            )
      (cond
        (nav_selection
          ;; Something is selected
          ;;
          ;; Place here the code you want to do
          ;; according to your navigator selection
          nil
          )
        (t
          ;; Nothing is selected in the navigator,
          ;; call previously defined bindkey
          ;; according to current cellViewType
          (case cv->cellViewType
            ("schematic"  (call_bindkey_string prev_sch_bindkey))
            ("maskLayout" (call_bindkey_string prev_lay_bindkey))
            ))
        )));def

    ;; Register the
    (hiSetBindKey "Schematics" cmd "(my_custom_navigator_bindkeys)")
    (hiSetBindKey "Layout"     cmd "(my_custom_navigator_bindkeys)")

    );letseq
  );inScheme

Cheers,

Aurélien