Opening, modifying, done commands on a form in a SKILL script

Most commands with forms block, so this wouldn't usually happen (unless it's truly a script rather than a program). Can you give an example of the code that has this problem and then maybe I can give some advice on how to avoid it?

Andrew

procedure( importLayoutDevices(cellName libName)
let(((area 0))
deNewCellView(libName cellName "layout" "maskLayout" nil)
deInstallApp(getCurrentWindow() "Virtuoso XL")
rep = geGetEditCellView()
lxHiReInitDesign()
hiFormDone(lxTemplateForm)
foreach(inst rep->instances
when( inst->libName == "tsmcN22"
bBox = inst->bBox
area = area + (((caadr bBox) - (caar bBox)) * ((cadadr bBox) - (cadar bBox)))
)
)
area
)
)

I call the function with this command and predefined variables for cellName and libName
importLayoutDevices(cellName libName)

It works if the layout window is already created and open and I get the popup asking if it is ok to overwrite the layout with the Generate Layout tool lxHiReInitDesign().  It does not work if the layout is not created and open, as it must take too long to create the layout, switch to XL and open the Generate Layout GUI before the script runs through the rest of the code

Actually I can't get it to consistently work, mostly it just doesn't work and I am left with the Generate Layout GUI open and an empty layout window

OK, there are two main issues here:

1. The function is using lxHiReInitDesign() which is a blocking function - it displays the generate all from source form and stops execution until the OK button or Cancel button is pressed. It doesn't get to the next line in the code until you've done that
2. It prompts you to overwrite the layout if it exists already. May not be a problem, but if you don't want that you can code around it.

In general, writing code that interacts with forms is the method of last resort - you do it if there's no dedicate procedural interface, and it's always complicated if you end up going down that route. If the form is blocking, then in general you have to use this kind of approach:

hiEnqueueCmd("hiFormDone(lxTemplateForm)")
lxHiReInitDesign()

That does work, but it's clunky. Since there's a dedicated procedural interface (lxGenerateStart/Finish) which avoids the form, why not use that instead - for example:

procedure( importLayoutDevices(cellName libName @optional (viewName "layout"))
  let(((area 0) rep connRef schCv ddId bBox)
    ; prevent the initial popup about overwriting by deleting the
    ; cellView if it exists already
    when(ddId=ddGetObj(libName cellName viewName)
      ddDeleteObj(ddId)
    )
    deNewCellView(libName cellName viewName "maskLayout" nil) 
    deInstallApp(getCurrentWindow() "Virtuoso XL")
    rep = geGetEditCellView()
    ; rather than using a blocking form command, use the procedural API 
    ; instead
    connRef = lxGetConnRef(rep)
    schCv=dbOpenCellViewByType(cadr(connRef) caddr(connRef) cadddr(connRef))
    lxGenerateStart(schCv rep)
    lxGenerateFinish(schCv rep)
    foreach(inst rep->instances
      when( inst->libName == "gpdk090"
	bBox = inst->bBox
	area = area + (((caadr bBox) - (caar bBox)) * ((cadadr bBox) - (cadar bBox)))
      )
    )
    area
  )
)

I also included the code at the beginning to delete the layout view if it exists already so that you don't get the dialog asking you to overwrite it.

Regards,

Andrew

OK, there are two main issues here:

1. The function is using lxHiReInitDesign() which is a blocking function - it displays the generate all from source form and stops execution until the OK button or Cancel button is pressed. It doesn't get to the next line in the code until you've done that
2. It prompts you to overwrite the layout if it exists already. May not be a problem, but if you don't want that you can code around it.

In general, writing code that interacts with forms is the method of last resort - you do it if there's no dedicate procedural interface, and it's always complicated if you end up going down that route. If the form is blocking, then in general you have to use this kind of approach:

hiEnqueueCmd("hiFormDone(lxTemplateForm)")
lxHiReInitDesign()

That does work, but it's clunky. Since there's a dedicated procedural interface (lxGenerateStart/Finish) which avoids the form, why not use that instead - for example:

procedure( importLayoutDevices(cellName libName @optional (viewName "layout"))
  let(((area 0) rep connRef schCv ddId bBox)
    ; prevent the initial popup about overwriting by deleting the
    ; cellView if it exists already
    when(ddId=ddGetObj(libName cellName viewName)
      ddDeleteObj(ddId)
    )
    deNewCellView(libName cellName viewName "maskLayout" nil) 
    deInstallApp(getCurrentWindow() "Virtuoso XL")
    rep = geGetEditCellView()
    ; rather than using a blocking form command, use the procedural API 
    ; instead
    connRef = lxGetConnRef(rep)
    schCv=dbOpenCellViewByType(cadr(connRef) caddr(connRef) cadddr(connRef))
    lxGenerateStart(schCv rep)
    lxGenerateFinish(schCv rep)
    foreach(inst rep->instances
      when( inst->libName == "gpdk090"
	bBox = inst->bBox
	area = area + (((caadr bBox) - (caar bBox)) * ((cadadr bBox) - (cadar bBox)))
      )
    )
    area
  )
)

I also included the code at the beginning to delete the layout view if it exists already so that you don't get the dialog asking you to overwrite it.

Regards,

Andrew