How to store values for the form fields

Hi Yankun,

I updated the code (with comments) to show how to achieve the three questions you had. See below. The key changes are:

1. Check to see if the form already exists - that means it will remember current settings on the form rather than creating fresh each time
2. Change to use hiCreateAppForm as this has more options - such as the ability to set the buttonLayout and the initialSize
3. Move the action into the doneProc and give an example of that. It seems that enterBox does not honour the "repeat commands" in the layout editor, so I have emulated it in the doneProc.

Andrew

procedure(testDoneProc(wid done box)
  ;----------------------------------------------------------------------
  ; don't do anything if cancelled
  ;----------------------------------------------------------------------
  when(done
    printf("%L\n" box)
    if(optionsForm->Type->value == "type1" then printf("%L\n" car(box)))
    if(optionsForm->Type->value == "type2" then printf("%L\n" cadr(box)))
    ;--------------------------------------------------------------------
    ; enterBox doesn't seem to honour modalCommands itself ("Repeat Commands"
    ; on the Editor Options form) so achieve the same thing
    ; by enqueuing the original command again
    ;--------------------------------------------------------------------
    when(envGetVal("layout" "modalCommands")
      hiEnqueueCmd("test()")
    )
  )
)
procedure(test()
  let((optionsForm box)
    cv=geGetEditCellView()
    ;--------------------------------------------------------------------
    ; Only create the form if it doesn't exist already; always
    ; stored in a global variable, so make sure the name is unique
    ;--------------------------------------------------------------------
    unless(boundp('CCFuniqueOptionsForm)
      ;------------------------------------------------------------------
      ; hiCreateAppForm has more control than hiCreateOptionsForm
      ;------------------------------------------------------------------
      hiCreateAppForm(
        ?name 'CCFuniqueOptionsForm
        ?formTitle "Options"
        ?formType 'options
        ?fields list(
          hiCreateRadioField(
            ?name 'Type
            ?prompt "Type"
            ?choices list("type1" "type2")
          );end Type 
        );end list
        ;----------------------------------------------------------------
        ; Control buttons and initial form size
        ;----------------------------------------------------------------
        ?buttonLayout 'HideCancelDef
        ?initialSize 300:60
      );end optionsForm
    )
    optionsForm=CCFuniqueOptionsForm

    ;--------------------------------------------------------------------
    ; Moved the processing into the doneProc
    ;--------------------------------------------------------------------
    box = enterBox(
      ?form eval(optionsForm)
      ?doneProc "testDoneProc"
    )
  );end let
);end procedure

hiSetBindKey("Layout" "<Key>z" "test()")

Thank you Andrew,

That is exactly what i need.

Thank you very much.

Best regards,

Yankun