Contextual key bindings

Hi,

I cannot guarantee it will work in your case but you could do something like that and set your default align bindkey to lay_enhanced_align instead:

(let ((bindkeys '(("<key>S" "(leCycleSnapModes)")
                  ))
      ;; My code was intended to work on a bindkeys table
      ;; so this is a little trick (working only in SKILL++)
      ;; to avoid rewritting it and make it work with
      ;; association lists instead
     (arrayref (lambda (l k) (cadr (assoc k l))))
     (setarray (lambda (l k v) (setf (cadr (assoc k l)) v)))
     )

  (defun toggle_bindkey (key @optional (tool "Layout"))
    "Properly set KEY to VAL while saving previous bindkey"
    (let ((val bindkeys[key]))
      (setf bindkeys[key] (hiGetBindKey tool key))
      (hiSetBindKey tool key val)
      ))

  (defun toggle_bindkeys (@optional (tool "Layout"))
    "Toggle all defined bindkeys"
    (foreach key (mapcar 'car bindkeys) (toggle_bindkey key tool)))

  (defglobalfun lay_enhanced_align (@rest _args)
    "Enhanced align tool, adapt bindkeys while using align"
    ;; Properly set and re-set bindkeys afterward
    (unwindProtect
      (progn (toggle_bindkeys)
             (leHiQuickAlign)
             )
      (toggle_bindkeys)))

);closure

Cheers,

Aurélien