Form like "Add instance" in schematic

Before spending time answering two possible meanings to this question, are you asking how to create a component that works this way with the create instance/edit properties forms (i.e. how to set up the CDF appropriately), or are you asking how to create a SKILL form which has similar functionality with fields that are hidden or not depending on the value of a checkbox on the form?

I'd like to answer the question you really want the answer to rather than both...

Andrew

Andrew,

Sorry for my unclear post. My question is the second one, how to control hidden/display of the fields by a checkbox.

Regards,

Martin

Martin,

Here's an example. It shows two ways - one using a boolean button with a callback to control visibility of fields, and the more modern way of using progressive disclosure (which behaves better in my opinion):

procedure(CCFdisclosureExCreateForm()
    let((fieldA fieldB fieldC fieldD labelA labelB labelC labelD 
            showFirstSet discloseSecondSet)
        fieldA=hiCreateStringField(
            ?name 'fieldA
            ?invisible t
        )
        fieldB=hiCreateStringField(
            ?name 'fieldB
            ?invisible t
        )
        fieldC=hiCreateStringField(
            ?name 'fieldC
        )
        fieldD=hiCreateStringField(
            ?name 'fieldD
        )
        labelA=hiCreateLabel(
            ?name 'labelA
            ?labelText "Field A"
            ?justification 'right
            ?invisible t
        )
        labelB=hiCreateLabel(
            ?name 'labelB
            ?labelText "Field B"
            ?justification 'right
            ?invisible t
        )
        labelC=hiCreateLabel(
            ?name 'labelC
            ?labelText "Field C"
            ?justification 'right
        )
        labelD=hiCreateLabel(
            ?name 'labelD
            ?labelText "Field D"
            ?justification 'right
        )
        ; old school way of creating progressive disclosure - use
        ; a checkbox with a callback that controls visibility 
        ; of fields
        showFirstSet=hiCreateBooleanButton(
            ?name 'showFirstSet
            ?buttonText " "
            ?callback 
                lambda((_field scope value)
                    scope->labelA->invisible=!value
                    scope->fieldA->invisible=!value
                    scope->labelB->invisible=!value
                    scope->fieldB->invisible=!value
                )
        )
        showFirstSetLabel=hiCreateLabel(
            ?name 'showFirstSetLabel
            ?labelText "First Set"
            ?justification 'right
        )
        ; modern way of doing it - using progressive 
        ; disclosure
        disclosureSecondSet=hiCreateDisclosureTriangle(
            ?name 'disclosureSecondSet
            ?labelText "Second Set"
            ?onFields 
                list(
                    'labelC 'fieldC 'labelD 'fieldD
                )
        )
        grid=hiCreateGridLayout(
            'grid
            ?items list(
                list(showFirstSetLabel 'row 0 'col 0)
                list(showFirstSet 'row 0 'col 1)
                list(labelA 'row 1 'col 0)
                list(fieldA 'row 1 'col 1)
                list(labelB 'row 2 'col 0)
                list(fieldB 'row 2 'col 1)
                list(disclosureSecondSet 'row 3 'col 0)
                list(labelC 'row 4 'col 0)
                list(fieldC 'row 4 'col 1)
                list(labelD 'row 5 'col 0)
                list(fieldD 'row 5 'col 1)
                list('col_stretch 0 0)
                list('col_stretch 1 1)
            )
        )
        hiCreateLayoutForm(
            'CCFdisclosureExForm
            "Disclosure Example"
            hiCreateVerticalBoxLayout(
                'vbox
                ?items list(
                    grid
                    list('stretch_item 1)
                )
            )
            ; get initial size roughly right to 
            ; avoid scroll bars 
            ?initialSize 300:160
        )
    )
)

procedure(CCFdisclosureEx()
    ; avoid creating the form every time
    unless(boundp('CCFdisclosureExForm)
        CCFdisclosureExCreateForm()
    )
    ; uses inSkill so that this works if file has a .ils suffix
    hiDisplayForm(inSkill(CCFdisclosureExForm))
)

Andrew

Andrew,

Thanks a lot.

Regards,

Martin