How to remove double quotes from start and end of a string and add double quote inside at the same time

Mvij,

string1=strcat("list" " \"" "Connection1" "\" " "100" " " "'center" " " "'string" " " "t")

which produces:

"list \"Connection1\" 100 'center 'string t"

Now, to get to the question in your post's title. There are no double quotes at the beginning and the end of this string, nor are the backslashes in the string either. What you are seeing is the print representation of the string - i.e. what is displayed to you in the CIW when you look at a variable or the return value of a function. For strings, this is the same as the input syntax of the string - so you can directly take the print representation and use it to create a new literal string.

This is clear if you print the string using printf:

printf("%s\n" string1)

which outputs:

list "Connection1" 100 'center 'string t

which is what you want. 

I will ask a follow-on question though. You appear to be trying to generate a string that looks like SKILL code in some sort of fashion. What are you going to do with this string? It looks to me as if you might be approaching some problem in a rather indirect or inefficient way, but this is mere guesswork on my part.

Regards,

Andrew

Thank you Andrew.
I am trying to generate a dynamic header list for hiCreateReportField and not looking at printing it.

It doesn't matter whether you're printing it or not, the string still doesn't contain the outer quotation marks nor the backslash.

Why don't you just create a list rather than creating a string that looks like a SKILL function (without the parentheses)? In other words, why not do:

list("Connection" 100 'centre 'string t)

I don't really understand why you would want to create a string first.

Andrew

Thank you Andrew.
This is what I am trying to do.
I have  a list of strings
list1=("Connection1" "Connection2")
I intend to use this list as header in hiCreateReportField to make this dynamic.
hiCreateReportfield(
                             list("Connection1" 100 'centre 'string t)
                             list("Connection2" 100 'centre 'string t)
                             )

In order to do the above, I need the create each header command first and then pass it as list to hiCreateReportField.
Mvij

list1=("Connection1" "Connection2")
headers=foreach(mapcar headerName list1
  list(headerName 100 'center 'string t)
)

hiCreateReportField(
 ...
 ?headers headers
)

The foreach mapcar will transform the input list into a list of lists, which is what you want, I believe.

Andrew

True.
But using list will take away ' from center and string and it would appear unbound variable in hiCreateReportField.
Plus we would need list to appear as function so we would need to modify a bit list(concat(strcat("list")) headerName 100 ....)

mvij said:

But using list will take away ' from center and string and it would appear unbound variable in hiCreateReportField.
Plus we would need list to appear as function so we would need to modify a bit list(concat(strcat("list")) headerName 100 ....)

What are you on about? This is complete nonsense (sorry if that's a bit harsh).

Using list will not "take away ' from center". Why would you need to do list(concat(strcat("list")) ?

You seem to be making some rather strange assumptions about how programming in SKILL works. Please try this complete example to see that it actually works:

list1=list("Connection1" "Connection2")
data=list(list("some" "value") list("other" "data"))

headers=foreach(mapcar headerName list1
  list(headerName 100 'center 'string t)
)

hiCreateLayoutForm(
  'ExampleForm
  "Example Form"
  hiCreateFormLayout(
    'layout
    ?items list(
      hiCreateReportField(
	?name 'generatedField
	?headers headers
	?choices data
      )
    )
  )
)
hiDisplayForm(ExampleForm)

Andrew

Thank you Andrew.