Looking for a SKILL script that will snap the centers of each instance to specific X and Y snap spacing

Hi,

Here is a script to snap selected instances to the closest grid point:

(inScheme
(let nil

  (defun get_closest_snap (x x_snap)
    "Return X closest snap value according to X_SNAP"
    (round x/(1.*x_snap))*(1.*x_snap))

  (defun get_selected_instances nil
    "Return the list of currently selected instances"
    (setof obj (geGetSelectedSet) (equal "inst" obj->objType)))

  (defglobalfun snap_instances (@key (instances (get_selected_instances))
                                     (win       (hiGetCurrentWindow))
                                     (cv        (geGetWindowCellView win))
                                     (x_snap    win->xSnapSpacing)
                                     (y_snap    win->ySnapSpacing)
                                @rest _args)
    "Snap the center of INSTANCES to the closest grid point"
    (foreach inst instances
      ;; Fetch instance center coordinates
      (destructuringBind (x y) (centerBox inst->bBox)
        ;; Calculate vector from center to closest snap point
        (let ((dx (get_closest_snap x x_snap)-x)
              (dy (get_closest_snap y y_snap)-y)
              )
          ;; Move instance
          (dbMoveFig inst cv (list (list dx dy) "R0" 1))
          )))
    );def

  );closure
)

Hope this helps,

Cheers,

Aurel

Hi Aurel,

Thank you for the reply.
I tried this skill by selecting one layout instance, then pasting the script to CIW and enter.
But it didn't move the device.
Not sure if my step is correct.

Regards,
Berry

Berry,

You can paste the code once into the CIW (or put in a file and load it), but to actually use it, you'd need to type:

snap_instances()

in the CIW. That's the name of the main function that's defined which does the actual work of snapping.

Andrew

Hi Andrew & Aurel,

I finally understand how to use it.
It is working as intended.
Thank you very much for the help guys!

Berry